cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall -Wno-unused-result"
  13 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  14 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  15 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  16 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  17 CFG_CFLAGS+=" -I/usr/include/freetype2"
  18
  19 AC_DEFUN([CHECK_WITH], [
  20 AC_ARG_WITH([$1],
  21   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  22   [WANT_$3=$withval], [WANT_$3='$4'])
  23 AC_SUBST([WANT_$3])
  24 ])
  25
  26 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  27 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  28 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  29 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  30 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  31 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  32 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  33 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  34 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  35 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  36
  37 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  38   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  39   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  40   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  41   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  42   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  43   sinstall=dinstall
  44   suninstall=duninstall
  45 else
  46   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  47     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  48     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  49     echo "$dir"`
  50   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  51     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  52     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  53     echo "$dir"`
  54   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  55     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  56     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  57     echo "$dir"`
  58   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  59        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  60   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  61     usrlib+="64"
  62   WANT_LOCALE_DIR="$lcldir"
  63   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  64   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  65   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  66   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  67   sinstall=cinstall
  68   suninstall=cuninstall
  69 fi
  70 AC_SUBST(sinstall)
  71 AC_SUBST(suninstall)
  72
  73 if test "x$WANT_JOBS" = "xauto"; then
  74   CPUS=`grep -c "^proc" /proc/cpuinfo`
  75   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  76 fi
  77
  78 AC_DEFUN([PKG_DEF],[
  79 STATIC_PKGS+=" [$1]"
  80 ver_$1="$2"
  81 lib_$1="$3"
  82 inc_$1="$4"
  83 ])
  84
  85 AC_DEFUN([PKG_3RD],[
  86 AC_ARG_ENABLE([$1],
  87   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  88   [PKG_$1=$enableval], [PKG_$1=$2])
  89 PKG_DEF([$1],[$3],[$4],[$5])
  90 ])
  91
  92 # thirdparty builds
  93
  94 PKG_3RD([a52dec],[yes],
  95   [a52dec-0.7.4],
  96   [ liba52/.libs/liba52.a ],
  97   [ include ])
  98
  99 PKG_3RD([djbfft],[yes],
 100   [djbfft-0.76],
 101   [ libdjbfft.a ],
 102   [ . ])
 103
 104 PKG_3RD([audiofile],[no],
 105   [audiofile-0.3.6],
 106   [ libaudiofile/.libs/libaudiofile.a \
 107     libaudiofile/modules/.libs/libmodules.a \
 108     libaudiofile/alac/.libs/libalac.a ],
 109   [ libaudiofile ])
 110
 111 PKG_3RD([encore],[no],
 112   [encore-5.0],
 113   [ \$(OBJDIR)/libencore.a ],
 114   [ . ])
 115
 116 PKG_3RD([esound],[no],
 117   [esound-0.2.41],
 118   [ .libs/libesd.a \
 119     .libs/libesddsp.a ],
 120   [ . ])
 121
 122 PKG_3RD([fdk],[auto],
 123   [fdk-aac-0.1.5],
 124   [ .libs/libfdk-aac.a ],
 125   [ libAACdec/include libAACenc/include libSYS/include ])
 126
 127 PKG_3RD([ffmpeg],[yes],
 128   [ffmpeg-3.3.2],
 129   [ libavutil/libavutil.a \
 130     libavcodec/libavcodec.a \
 131     libpostproc/libpostproc.a \
 132     libavdevice/libavdevice.a \
 133     libavformat/libavformat.a \
 134     libswscale/libswscale.a \
 135     libavfilter/libavfilter.a \
 136     libswresample/libswresample.a ],
 137   [ . ])
 138
 139 PKG_3RD([fftw],[auto],
 140   [fftw-3.3.6-pl2],
 141   [ .libs/libfftw3.a \
 142     libbench2/libbench2.a \
 143     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 144     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 145     rdft/scalar/.libs/librdft_scalar.a \
 146     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 147     rdft/.libs/librdft.a \
 148     api/.libs/libapi.a \
 149     reodft/.libs/libreodft.a \
 150     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 151     dft/scalar/.libs/libdft_scalar.a \
 152     dft/.libs/libdft.a \
 153     kernel/.libs/libkernel.a \
 154     simd-support/.libs/libsimd_support.a \
 155     simd-support/.libs/libsimd_sse2_nonportable.a ],
 156   [ api ])
 157
 158 PKG_3RD([flac],[auto],
 159   [flac-1.3.2],
 160   [ src/libFLAC/.libs/libFLAC.a \
 161     src/libFLAC++/.libs/libFLAC++.a \
 162     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 163     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 164     src/share/grabbag/.libs/libgrabbag.a \
 165     src/share/utf8/.libs/libutf8.a \
 166     src/test_libs_common/.libs/libtest_libs_common.a ],
 167   [ include ])
 168
 169 PKG_3RD([giflib],[yes],
 170   [giflib-5.1.4],
 171   [ lib/.libs/libgif.a \
 172     util/libgetarg.a ],
 173   [ lib ])
 174
 175 PKG_3RD([ilmbase],[auto],
 176   [ilmbase-2.2.0],
 177   [ Iex/.libs/libIex.a \
 178     IexMath/.libs/libIexMath.a \
 179     Half/.libs/libHalf.a \
 180     Imath/.libs/libImath.a \
 181     IlmThread/.libs/libIlmThread.a ],
 182   [ Iex Half Imath config IlmThread ])
 183
 184 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 185
 186 PKG_3RD([lame],[auto],
 187   [lame-3.99.5],
 188   [ libmp3lame/.libs/libmp3lame.a \
 189     mpglib/.libs/libmpgdecoder.a ],
 190   [ include ])
 191
 192 PKG_3RD([libavc1394],[auto],
 193   [libavc1394-0.5.4],
 194   [ libavc1394/.libs/libavc1394.a \
 195     librom1394/.libs/librom1394.a \
 196     common/.libs/libraw1394util.a ],
 197   [ . ])
 198
 199 PKG_3RD([libraw1394],[auto],
 200   [libraw1394-2.1.2],
 201   [ src/.libs/libraw1394.a ],
 202   [ . ])
 203
 204 PKG_3RD([libiec61883],[auto],
 205   [libiec61883-1.2.0],
 206   [ src/.libs/libiec61883.a ],
 207   [ src ])
 208
 209 PKG_3RD([libdv],[auto],
 210   [libdv-1.0.0],
 211   [ libdv/.libs/libdv.a ],
 212   [ . ])
 213
 214 PKG_3RD([libjpeg],[auto],
 215   [libjpeg-turbo-1.5.1],
 216   [ .libs/libjpeg.a \
 217     .libs/libturbojpeg.a \
 218     simd/.libs/libsimd.a ],
 219   [ . ])
 220
 221 PKG_3RD([openjpeg],[auto],
 222   [openjpeg-2.1.0-20160221],
 223   [ bin/libopenjp2.a ],
 224   [ src/lib/openjp2 ])
 225
 226 PKG_3RD([libogg],[auto],
 227   [libogg-1.3.2],
 228   [ src/.libs/libogg.a ],
 229   [ include ])
 230
 231 PKG_3RD([libsndfile],[auto],
 232   [libsndfile-1.0.28],
 233   [ src/.libs/libsndfile.a \
 234     src/.libs/libcommon.a \
 235     src/G72x/.libs/libg72x.a \
 236     src/GSM610/.libs/libgsm.a ],
 237   [ . ])
 238
 239 PKG_3RD([libtheora],[auto],
 240   [libtheora-1.1.1],
 241   [ lib/.libs/libtheora.a \
 242     lib/.libs/libtheoradec.a \
 243     lib/.libs/libtheoraenc.a ],
 244   [ . ])
 245
 246 PKG_3RD([libuuid],[yes],
 247   [libuuid-1.0.3],
 248   [ .libs/libuuid.a ],
 249   [ . ])
 250
 251 PKG_3RD([libvorbis],[auto],
 252   [libvorbis-1.3.5],
 253   [ lib/.libs/libvorbis.a \
 254     lib/.libs/libvorbisenc.a \
 255     lib/.libs/libvorbisfile.a ],
 256   [ include . ])
 257
 258 PKG_3RD([mjpegtools],[yes],
 259   [mjpegtools-2.1.0],
 260   [ utils/mmxsse/.libs/libmmxsse.a \
 261     utils/.libs/libmjpegutils.a \
 262     lavtools/.libs/liblavfile.a \
 263     lavtools/.libs/liblavjpeg.a \
 264     mplex/.libs/libmplex2.a \
 265     yuvfilters/.libs/libyuvfilters.a \
 266     mpeg2enc/.libs/libmpeg2encpp.a ],
 267   [ .  lavtools utils ])
 268
 269 PKG_3RD([openexr],[auto],
 270   [openexr-2.2.0],
 271   [ IlmImf/.libs/libIlmImf.a \
 272     IlmImfUtil/.libs/libIlmImfUtil.a ],
 273   [ IlmImf config ])
 274
 275 #PKG_3RD([festival],[no],
 276 #  [festival],
 277 #  [],
 278 #  [])
 279 #PKG_3RD(speech_tools,[no],
 280 #  [speech_tools],
 281 #  [],
 282 #  [])
 283 #
 284 PKG_3RD([tiff],[auto],
 285   [tiff-4.0.6],
 286   [ libtiff/.libs/libtiff.a \
 287     libtiff/.libs/libtiffxx.a \
 288     port/.libs/libport.a ],[
 289    . ])
 290
 291 PKG_3RD([twolame],[auto],
 292   [twolame-0.3.13],
 293   [ libtwolame/.libs/libtwolame.a ],
 294   [  libtwolame ])
 295
 296 PKG_3RD([x264],[auto],
 297   [x264-snapshot-20170426-2245],
 298   [ libx264.a ],
 299   [ . ])
 300
 301 PKG_3RD([x265],[auto],
 302   [x265_2.4],
 303   [ libx265.a ],
 304   [ . source ])
 305
 306 PKG_3RD([libvpx],[auto],
 307   [libvpx-1.6.1],
 308   [ libvpx.a ],
 309   [ . ])
 310
 311 AC_SUBST(STATIC_PKGS)
 312
 313 AC_DEFUN([CHECK_ENABLE], [
 314 AC_ARG_ENABLE([$1],
 315   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 316   [WANT_$2=$enableval], [WANT_$2=[$4]])
 317 ])
 318
 319 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 320 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 321 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10/12bit], [no])
 322
 323 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 324
 325 AC_DEFUN([CHECK_PROG], [
 326  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 327 ])
 328 AC_DEFUN([REQUIRE_PROG], [
 329  CHECK_PROG([$1],[$2])
 330  if test "x$PROG_$1" = "xno"; then
 331    AC_MSG_WARN([$2 is missing and required.])
 332    FATAL_ERROR=1
 333  fi
 334 ])
 335
 336 # Checks for programs.
 337
 338 REQUIRE_PROG(NASM, [nasm])
 339 REQUIRE_PROG(YASM, [yasm])
 340 REQUIRE_PROG(OBJCOPY, [objcopy])
 341 if test "x$FATAL_ERROR" != "x"; then
 342  AC_MSG_ERROR("fatal eror.")
 343 fi
 344 CHECK_PROG(PACTL, [pactl])
 345 WANT_PACTL=$PROG_PACTL
 346
 347 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 348 if test "$no_utf" = "yes"; then
 349   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 350 fi
 351
 352 # Checks for headers/libraries.
 353
 354 AC_DEFUN([CHECK_HEADERS], [
 355 if test "x$HAVE_$1" != "xno"; then
 356  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 357   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 358 ]])])
 359  AC_SUBST([HAVE_$1])
 360  AC_MSG_CHECKING([$2])
 361  AC_MSG_RESULT([$HAVE_$1])
 362  if test "x$HAVE_$1" = "xno"; then
 363   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 364  fi
 365 fi
 366 ])
 367
 368 AC_DEFUN([CHECK_LIB], [
 369 if test "x$HAVE_$1" != "xno"; then
 370  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 371   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 372   AC_SUBST([HAVE_$1])
 373   if test "x$HAVE_$1" = "xyes"; then
 374    if test "x$PKG_$1" = "x"; then
 375     SYSTEM_LIBS+=" -l[$2]"
 376     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 377    else
 378     SHARED_$1+=" -l[$2]"
 379     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 380    fi
 381   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 382  fi
 383 fi
 384 ])
 385
 386 CHECK_LIB([X11], [X11], [XOpenDisplay])
 387 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 388 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 389 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 390 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 391 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 392 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 393 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 394 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 395 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 396 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 397 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 398 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 399 CHECK_LIB([PNG], [png], [png_read_png])
 400 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 401 CHECK_LIB([Z], [z], [gzopen])
 402 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 403 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 404 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 405 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 406 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 407 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 408 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 409 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 410 CHECK_LIB([lame], [mp3lame], [lame_init])
 411 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 412 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 413 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 414 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 415 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 416 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 417 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 418 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 419 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 420 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 421 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 422 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 423 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 424 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 425 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 426 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 427 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 428 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 429 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 430 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 431 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 432 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 433 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 434 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 435 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 436 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 437 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 438 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 439 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 440 CHECK_LIB([a52dec], [a52], [a52_init])
 441 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 442 CHECK_LIB([encore], [encore], [encore])
 443 CHECK_HEADERS([encore], [encore headers], [encore.h])
 444 CHECK_LIB([giflib], [gif], [DGifOpen])
 445 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 446 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 447 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 448 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 449 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 450
 451 #if test "x$HAVE_mjpegtools" = "xyes"; then
 452 #CFG_CFLAGS+=" -I/usr/include/mjpegtools"
 453 #fi
 454
 455 AC_DEFUN([CHECK_WANT], [
 456 RESULT=yes
 457 AC_ARG_WITH(m4_tolower([$1]),
 458  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 459   [WANT_$1=$withval],[WANT_$1=$2])
 460 # WANT_$1
 461 if test "x$WANT_$1" != "xno" ; then
 462  m4_quote($4)
 463  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 464   echo "=== want $1 Failed."
 465   WANT_$1=no
 466  else
 467   WANT_$1=yes
 468  fi
 469 fi
 470 CFG_WANTS+=" $1"
 471 AC_SUBST([WANT_$1])
 472 ])
 473
 474 CHECK_WANT([GL], [auto], [use opengl], [
 475  CHECK_LIB([GL], [GL], [glUseProgram])
 476  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 477  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 478
 479 CHECK_WANT([OSS], [auto], [use OSS audio], [
 480  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 481
 482 CHECK_WANT([XFT], [auto], [use libXft], [
 483  CHECK_LIB([XFT], [Xft], [XftInit])
 484  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 485
 486 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 487  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 488  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 489
 490 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 491  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 492  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 493  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 494  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 495  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 496  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 497  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 498  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 499
 500 CHECK_WANT([DV], [auto], [use dv], [
 501  CHECK_LIB([libdv], [dv], [dv_init])
 502  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 503
 504 CHECK_WANT([DVB], [auto], [use dvb], [
 505  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 506
 507 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 508  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 509
 510 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 511  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 512
 513 CHECK_WANT([ESOUND], [no], [use esd], [
 514  CHECK_LIB([esound], [esd], [esd_open_sound])
 515  CHECK_HEADERS([esound], [esound headers], [esd.h])
 516  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 517  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 518
 519 CHECK_WANT([DL], [auto], [system has libdl], [
 520  CHECK_LIB([DL], [dl], [dlopen])])
 521
 522 CHECK_WANT([EXR], [auto], [use exr], [])
 523
 524 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 525  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 526
 527 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 528  AC_MSG_CHECKING([for openexr available])
 529  saved_LIBS="$LIBS"
 530  saved_CXXFLAGS="$CXXFLAGS"
 531  # ilmbase libs
 532  LIBS=" -lIlmImf -lIlmThread -lIex"
 533  CXXFLAGS="-I/usr/include/OpenEXR"
 534  AC_LANG_PUSH(C++)
 535  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 536 #include "ImfChannelList.h"
 537 #include "ImfChromaticities.h"
 538 #include "ImfCompression.h"
 539 #include "ImfIO.h"
 540 #include "ImfInputFile.h"
 541 #include "ImfOutputFile.h"
 542 #include "ImfPixelType.h"
 543 #include "ImfRgbaFile.h"
 544 #include "ImfRgbaYca.h"
 545 #include "ImfVersion.h"
 546 class EXRIStream : public Imf::IStream { public:
 547 EXRIStream() : Imf::IStream("mypath") {} };
 548 class EXROStream : public Imf::OStream { public:
 549 EXROStream() : Imf::OStream("mypath") {} };
 550 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 551  RESULT="$HAVE_OPENEXR"
 552  if test "x$RESULT" = "xyes"; then
 553    SHARED_openexr="$LIBS"
 554    CFG_CFLAGS+=" -I/usr/include/OpenEXR"
 555  fi
 556  LIBS="$saved_LIBS"
 557  CXXFLAGS="$saved_CXXFLAGS"
 558  AC_LANG_POP(C++)
 559  AC_MSG_RESULT([$HAVE_OPENEXR])
 560 ])
 561 AC_SUBST([HAVE_OPENEXR])
 562
 563 # build global_config
 564 OBJDIR=`uname -m`
 565 AC_SUBST(OBJDIR)
 566
 567 echo "AC_HELP_STRING([Reason],[Package])"
 568 echo "AC_HELP_STRING([------],[-------])"
 569
 570 AC_DEFUN([PKG_DISABLED],[
 571  PKG_$1="no"
 572  BUILD_$1=0
 573  AC_SUBST(BUILD_$1)
 574  echo "AC_HELP_STRING([disabled],[$1])"
 575 ])
 576 AC_DEFUN([PKG_SHARED],[
 577  BUILD_$1=0
 578  AC_SUBST(BUILD_$1)
 579  SHARED_LIBS+="$SHARED_$1"
 580  echo "AC_HELP_STRING([shared],[$1])"
 581 ])
 582 AC_DEFUN([PKG_STATIC],[
 583  PKG_$1="yes"
 584  BUILD_$1=1
 585  AC_SUBST(BUILD_$1)
 586  STATIC_BLDS+=" [$1]"
 587  echo "AC_HELP_STRING([$2],[$1])"
 588 ])
 589 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 590
 591 # order matters
 592 for dep in \
 593         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 594         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 ffmpeg/fdk \
 595         libiec61883/libraw1394 libavc1394/librom1394 \
 596         openexr/ilmbase ilmbase/libogg \
 597         libtheora/libogg libtheora/libvorbis ; do
 598   lib=`dirname $dep`;  needs=`basename $dep`
 599   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 600   if test "x$pkg_lib" != "xno"; then
 601     eval "PKG_$needs=yes"
 602   fi
 603 done
 604
 605 AC_DEFUN([PKG_PROVIDE],[
 606 if test "x$BUILD_$1" = "x" ; then
 607  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 608   PKG_DISABLED([$1])
 609  elif test "x$PKG_$1" = "xyes"; then
 610   PKG_FORCED([$1])
 611  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 612   PKG_STATIC([$1],[static])
 613  elif test "x$HAVE_$1" = "xyes"; then
 614   PKG_SHARED([$1])
 615  else
 616   PKG_STATIC([$1],[needed])
 617  fi
 618 fi
 619 ])
 620
 621 PKG_PROVIDE([a52dec])
 622 PKG_PROVIDE([djbfft])
 623 PKG_PROVIDE([encore])
 624 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 625 PKG_PROVIDE([esound],[$WANT_ESOUND])
 626 PKG_PROVIDE([fdk])
 627 PKG_PROVIDE([ffmpeg])
 628 PKG_PROVIDE([fftw])
 629 PKG_PROVIDE([flac])
 630 PKG_PROVIDE([giflib])
 631 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 632 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 633 PKG_PROVIDE([lame])
 634 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 635 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 636 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 637 PKG_PROVIDE([libdv],[$WANT_DV])
 638 PKG_PROVIDE([libjpeg])
 639 PKG_PROVIDE([libogg])
 640 PKG_PROVIDE([libsndfile])
 641 PKG_PROVIDE([libtheora])
 642 PKG_PROVIDE([libuuid])
 643 PKG_PROVIDE([libvorbis])
 644 PKG_PROVIDE([mjpegtools])
 645 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 646 PKG_PROVIDE([openjpeg])
 647 PKG_PROVIDE([tiff])
 648 PKG_PROVIDE([twolame])
 649 PKG_PROVIDE([x264])
 650 PKG_PROVIDE([x265])
 651 PKG_PROVIDE([libvpx])
 652
 653 AC_SUBST(STATIC_BLDS)
 654 AC_SUBST(SHARED_LIBS)
 655
 656 for f in $SYSTEM_LIBS; do
 657   echo "AC_HELP_STRING([system],[$f])"
 658 done
 659 AC_SUBST(SYSTEM_LIBS)
 660
 661 echo ""
 662 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 663          VIDEO4LINUX2 ESOUND PACTL OPENEXR; do
 664   eval vv="\$WANT_$v"
 665   if test "x$vv" != "xno"; then
 666     CFG_CFLAGS+=" -DHAVE_$v"
 667     vv=with
 668   else
 669     vv=without
 670   fi
 671   v=`echo "$v" | tr "A-Z" "a-z"`
 672   echo "  using: $vv-$v"
 673 done
 674
 675 echo "  using: with-jobs = $WANT_JOBS"
 676 echo "  using: exec-name = $WANT_CIN"
 677 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 678 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 679 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 680 echo "  using: with-browser = $WANT_CIN_BROWSER"
 681 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 682 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 683 echo ""
 684 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 685 echo "  using: static-build = $WANT_STATIC_BUILD"
 686 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 687 echo ""
 688
 689 # build extras
 690 if test "x$HAVE_tiff" = "xyes"; then
 691   if test "x$HAVE_jbig" = "xyes"; then
 692     EXTRA_LIBS+=' -ljbig'
 693   fi
 694 fi
 695 if test "x$HAVE_NUMA" = "xyes"; then
 696   EXTRA_LIBS+=' -lnuma'
 697 fi
 698 if test "x$HAVE_DL" = "xyes"; then
 699   EXTRA_LIBS+=' -ldl'
 700   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 701 fi
 702 AC_SUBST(EXTRA_LIBS)
 703 AC_SUBST(FFMPEG_EXTRA_CFG)
 704 AC_SUBST(WANT_X264_HIDEPTH)
 705 AC_SUBST(WANT_X265_HIDEPTH)
 706
 707 AC_SUBST(CFG_CFLAGS)
 708 AC_SUBST(CFG_CXXFLAGS)
 709
 710 AC_CONFIG_FILES([Makefile])
 711 AC_OUTPUT
 712
 713 exec > global_config
 714
 715 echo "SHELL := /bin/bash"
 716 echo "export SHELL"
 717 echo "WANT_JOBS := $WANT_JOBS"
 718 echo ""
 719 echo "OBJDIR := $OBJDIR"
 720 echo "BINDIR := \$(TOPDIR)/bin"
 721 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 722 echo "GUICAST := \$(TOPDIR)/guicast"
 723 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 724 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 725 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 726 echo "PLUGINS := \$(TOPDIR)/plugins"
 727 echo "TDB := \$(TOPDIR)/db"
 728 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 729 echo "EXTRA_LIBS := $EXTRA_LIBS"
 730 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 731 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 732 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 733 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 734 echo ""
 735
 736 echo "WANT_CIN := $WANT_CIN"
 737 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 738 echo ""
 739
 740 echo "ifndef CFLAGS_"
 741 echo "ifdef CFLAGS"
 742 echo "CFLAGS_ := \$(CFLAGS)"
 743 echo "else"
 744 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 745 echo "endif"
 746 echo "endif"
 747
 748 echo "CFLAGS := \$(CFLAGS_)"
 749 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 750 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 751 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 752 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 753 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 754 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 755 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 756 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 757 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 758 echo ""
 759 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 760 echo ""
 761
 762 if test  $WANT_X264_HIDEPTH = "yes" ; then
 763   echo "x264.cfg_params := --enable-static --bit-depth=10"
 764 fi
 765 if test  $WANT_X265_HIDEPTH = "yes" ; then
 766   echo "x265.cfg_params := -DENABLE_SHARED=no -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
 767 fi
 768
 769 for pkg in $STATIC_PKGS; do
 770   eval pkg_lib="\$PKG_$pkg"
 771   if test "x$pkg_lib" = "xno"; then continue; fi;
 772   echo "static_pkgs += $pkg"
 773 done
 774 echo ""
 775
 776 for pkg in $STATIC_BLDS; do
 777   echo "static_blds += $pkg"
 778   ver_pkg=ver_$pkg
 779   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 780   inc_pkg=inc_$pkg
 781   echo "$inc_pkg := \\"
 782   for inc in ${!inc_pkg}; do
 783     echo "  -I\$($ver_pkg)/$inc \\"
 784   done
 785   echo ""
 786   echo "static_incs += \$(inc_$pkg)"
 787   lib_pkg=lib_$pkg
 788   echo "$lib_pkg := \\"
 789   for lib in ${!lib_pkg}; do
 790     echo "  \$($ver_pkg)/$lib \\"
 791   done
 792   echo ""
 793   echo "static_libs += \$($lib_pkg)"
 794   echo ""
 795 done
 796 echo ""
 797
 798 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 799 echo ""
 800 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 801 echo "export static_pkgs static_blds shared_libs system_libs"
 802 echo ""
 803
 804 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 805 echo "libraries += -Wl,--start-group"
 806 echo "libraries += \$(thirdparty_libraries)"
 807 echo "libraries += \$(system_libs)"
 808 echo "libraries += \$(EXTRA_LIBS)"
 809 echo "libraries += -Wl,--end-group"
 810 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 811 echo "libraries += \$(thirdparty_libraries)"
 812 echo "libraries += \$(system_libs)"
 813 echo "libraries += \$(EXTRA_LIBS)"
 814 echo ""
 815 echo "export thirdparty_libraries libraries"
 816 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 817 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
 818
 819 if test "x$HAVE_tiff" = "xyes"; then
 820   if test "x$HAVE_jbig" != "xyes"; then
 821     echo "tiff.cfg_params+= --disable-jbig"
 822   fi
 823 fi
 824