cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall -Wno-unused-result -Wno-format-truncation"
  13 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  14 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  15 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  16 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  17 CFG_CFLAGS+=" -I/usr/include/freetype2"
  18
  19 AC_DEFUN([CHECK_WITH], [
  20 AC_ARG_WITH([$1],
  21   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  22   [WANT_$3=$withval], [WANT_$3='$4'])
  23 AC_SUBST([WANT_$3])
  24 ])
  25
  26 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  27 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  28 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  29 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  30 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  31 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  32 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  33 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  34 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  35 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  36 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  37
  38 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  39   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  40   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  41   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  42   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  43   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  44   sinstall=dinstall
  45   suninstall=duninstall
  46 else
  47   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  48     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  49     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  50     echo "$dir"`
  51   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  52     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  53     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  54     echo "$dir"`
  55   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  56     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  57     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  58     echo "$dir"`
  59   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  60        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  61   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  62     usrlib+="64"
  63   WANT_LOCALE_DIR="$lcldir"
  64   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  65   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  66   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  67   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  68   sinstall=cinstall
  69   suninstall=cuninstall
  70 fi
  71 AC_SUBST(sinstall)
  72 AC_SUBST(suninstall)
  73
  74 if test "x$WANT_JOBS" = "xauto"; then
  75   CPUS=`grep -c "^proc" /proc/cpuinfo`
  76   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  77 fi
  78
  79 AC_DEFUN([PKG_DEF],[
  80 STATIC_PKGS+=" [$1]"
  81 ver_$1="$2"
  82 lib_$1="$3"
  83 inc_$1="$4"
  84 ])
  85
  86 AC_DEFUN([PKG_3RD],[
  87 AC_ARG_ENABLE([$1],
  88   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  89   [PKG_$1=$enableval], [PKG_$1=$2])
  90 PKG_DEF([$1],[$3],[$4],[$5])
  91 ])
  92
  93 # thirdparty builds
  94
  95 PKG_3RD([a52dec],[yes],
  96   [a52dec-0.7.4],
  97   [ liba52/.libs/liba52.a ],
  98   [ include ])
  99
 100 PKG_3RD([djbfft],[yes],
 101   [djbfft-0.76],
 102   [ libdjbfft.a ],
 103   [ . ])
 104
 105 PKG_3RD([audiofile],[no],
 106   [audiofile-0.3.6],
 107   [ libaudiofile/.libs/libaudiofile.a \
 108     libaudiofile/modules/.libs/libmodules.a \
 109     libaudiofile/alac/.libs/libalac.a ],
 110   [ libaudiofile ])
 111
 112 PKG_3RD([encore],[no],
 113   [encore-5.0],
 114   [ \$(OBJDIR)/libencore.a ],
 115   [ . ])
 116
 117 PKG_3RD([esound],[no],
 118   [esound-0.2.41],
 119   [ .libs/libesd.a \
 120     .libs/libesddsp.a ],
 121   [ . ])
 122
 123 PKG_3RD([fdk],[auto],
 124   [fdk-aac-0.1.5],
 125   [ .libs/libfdk-aac.a ],
 126   [ libAACdec/include libAACenc/include libSYS/include ])
 127
 128 PKG_3RD([ffmpeg],[yes],
 129   [ffmpeg-3.3.4],
 130   [ libavutil/libavutil.a \
 131     libavcodec/libavcodec.a \
 132     libpostproc/libpostproc.a \
 133     libavdevice/libavdevice.a \
 134     libavformat/libavformat.a \
 135     libswscale/libswscale.a \
 136     libavfilter/libavfilter.a \
 137     libswresample/libswresample.a ],
 138   [ . ])
 139
 140 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 141   ver_ffmpeg="ffmpeg.git"
 142 fi
 143
 144 PKG_3RD([fftw],[auto],
 145   [fftw-3.3.6-pl2],
 146   [ .libs/libfftw3.a \
 147     libbench2/libbench2.a \
 148     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 149     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 150     rdft/scalar/.libs/librdft_scalar.a \
 151     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 152     rdft/.libs/librdft.a \
 153     api/.libs/libapi.a \
 154     reodft/.libs/libreodft.a \
 155     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 156     dft/scalar/.libs/libdft_scalar.a \
 157     dft/.libs/libdft.a \
 158     kernel/.libs/libkernel.a \
 159     simd-support/.libs/libsimd_support.a \
 160     simd-support/.libs/libsimd_sse2_nonportable.a ],
 161   [ api ])
 162
 163 PKG_3RD([flac],[auto],
 164   [flac-1.3.2],
 165   [ src/libFLAC/.libs/libFLAC.a \
 166     src/libFLAC++/.libs/libFLAC++.a \
 167     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 168     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 169     src/share/grabbag/.libs/libgrabbag.a \
 170     src/share/utf8/.libs/libutf8.a \
 171     src/test_libs_common/.libs/libtest_libs_common.a ],
 172   [ include ])
 173
 174 PKG_3RD([giflib],[yes],
 175   [giflib-5.1.4],
 176   [ lib/.libs/libgif.a \
 177     util/libgetarg.a ],
 178   [ lib ])
 179
 180 PKG_3RD([ilmbase],[auto],
 181   [ilmbase-2.2.0],
 182   [ Iex/.libs/libIex.a \
 183     IexMath/.libs/libIexMath.a \
 184     Half/.libs/libHalf.a \
 185     Imath/.libs/libImath.a \
 186     IlmThread/.libs/libIlmThread.a ],
 187   [ Iex Half Imath config IlmThread ])
 188
 189 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 190
 191 PKG_3RD([lame],[auto],
 192   [lame-3.99.5],
 193   [ libmp3lame/.libs/libmp3lame.a \
 194     mpglib/.libs/libmpgdecoder.a ],
 195   [ include ])
 196
 197 PKG_3RD([libavc1394],[auto],
 198   [libavc1394-0.5.4],
 199   [ libavc1394/.libs/libavc1394.a \
 200     librom1394/.libs/librom1394.a \
 201     common/.libs/libraw1394util.a ],
 202   [ . ])
 203
 204 PKG_3RD([libraw1394],[auto],
 205   [libraw1394-2.1.2],
 206   [ src/.libs/libraw1394.a ],
 207   [ . ])
 208
 209 PKG_3RD([libiec61883],[auto],
 210   [libiec61883-1.2.0],
 211   [ src/.libs/libiec61883.a ],
 212   [ src ])
 213
 214 PKG_3RD([libdv],[auto],
 215   [libdv-1.0.0],
 216   [ libdv/.libs/libdv.a ],
 217   [ . ])
 218
 219 PKG_3RD([libjpeg],[auto],
 220   [libjpeg-turbo-1.5.1],
 221   [ .libs/libjpeg.a \
 222     .libs/libturbojpeg.a \
 223     simd/.libs/libsimd.a ],
 224   [ . ])
 225
 226 PKG_3RD([openjpeg],[auto],
 227   [openjpeg-2.1.0-20160221],
 228   [ bin/libopenjp2.a ],
 229   [ src/lib/openjp2 ])
 230
 231 PKG_3RD([libogg],[auto],
 232   [libogg-1.3.2],
 233   [ src/.libs/libogg.a ],
 234   [ include ])
 235
 236 PKG_3RD([libsndfile],[auto],
 237   [libsndfile-1.0.28],
 238   [ src/.libs/libsndfile.a \
 239     src/.libs/libcommon.a \
 240     src/G72x/.libs/libg72x.a \
 241     src/GSM610/.libs/libgsm.a ],
 242   [ . ])
 243
 244 PKG_3RD([libtheora],[auto],
 245   [libtheora-1.1.1],
 246   [ lib/.libs/libtheora.a \
 247     lib/.libs/libtheoradec.a \
 248     lib/.libs/libtheoraenc.a ],
 249   [ . ])
 250
 251 PKG_3RD([libuuid],[yes],
 252   [libuuid-1.0.3],
 253   [ .libs/libuuid.a ],
 254   [ . ])
 255
 256 PKG_3RD([libvorbis],[auto],
 257   [libvorbis-1.3.5],
 258   [ lib/.libs/libvorbis.a \
 259     lib/.libs/libvorbisenc.a \
 260     lib/.libs/libvorbisfile.a ],
 261   [ include . ])
 262
 263 PKG_3RD([mjpegtools],[yes],
 264   [mjpegtools-2.1.0],
 265   [ utils/mmxsse/.libs/libmmxsse.a \
 266     utils/.libs/libmjpegutils.a \
 267     lavtools/.libs/liblavfile.a \
 268     lavtools/.libs/liblavjpeg.a \
 269     mplex/.libs/libmplex2.a \
 270     yuvfilters/.libs/libyuvfilters.a \
 271     mpeg2enc/.libs/libmpeg2encpp.a ],
 272   [ .  lavtools utils ])
 273
 274 PKG_3RD([openexr],[auto],
 275   [openexr-2.2.0],
 276   [ IlmImf/.libs/libIlmImf.a \
 277     IlmImfUtil/.libs/libIlmImfUtil.a ],
 278   [ IlmImf config ])
 279
 280 #PKG_3RD([festival],[no],
 281 #  [festival],
 282 #  [],
 283 #  [])
 284 #PKG_3RD(speech_tools,[no],
 285 #  [speech_tools],
 286 #  [],
 287 #  [])
 288 #
 289 PKG_3RD([tiff],[auto],
 290   [tiff-4.0.6],
 291   [ libtiff/.libs/libtiff.a \
 292     libtiff/.libs/libtiffxx.a \
 293     port/.libs/libport.a ],[
 294    . ])
 295
 296 PKG_3RD([twolame],[auto],
 297   [twolame-0.3.13],
 298   [ libtwolame/.libs/libtwolame.a ],
 299   [  libtwolame ])
 300
 301 PKG_3RD([x264],[auto],
 302   [x264-snapshot-20170426-2245],
 303   [ libx264.a ],
 304   [ . ])
 305
 306 PKG_3RD([x265],[auto],
 307   [x265_2.5],
 308   [ libx265.a ],
 309   [ . source ])
 310
 311 PKG_3RD([libvpx],[auto],
 312   [libvpx-1.6.1],
 313   [ libvpx.a ],
 314   [ . ])
 315
 316 AC_SUBST(STATIC_PKGS)
 317
 318 AC_DEFUN([CHECK_ENABLE], [
 319 AC_ARG_ENABLE([$1],
 320   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 321   [WANT_$2=$enableval], [WANT_$2=[$4]])
 322 ])
 323
 324 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 325 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 326 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10/12bit], [no])
 327
 328 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 329
 330 AC_DEFUN([CHECK_PROG], [
 331  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 332 ])
 333 AC_DEFUN([REQUIRE_PROG], [
 334  CHECK_PROG([$1],[$2])
 335  if test "x$PROG_$1" = "xno"; then
 336    AC_MSG_WARN([$2 is missing and required.])
 337    FATAL_ERROR=1
 338  fi
 339 ])
 340
 341 # Checks for programs.
 342
 343 REQUIRE_PROG(NASM, [nasm])
 344 REQUIRE_PROG(YASM, [yasm])
 345 REQUIRE_PROG(OBJCOPY, [objcopy])
 346 if test "x$FATAL_ERROR" != "x"; then
 347  AC_MSG_ERROR("fatal eror.")
 348 fi
 349 CHECK_PROG(PACTL, [pactl])
 350 WANT_PACTL=$PROG_PACTL
 351
 352 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 353 if test "$no_utf" = "yes"; then
 354   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 355 fi
 356
 357 # Checks for headers/libraries.
 358
 359 AC_DEFUN([CHECK_HEADERS], [
 360 if test "x$HAVE_$1" != "xno"; then
 361  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 362   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 363 ]])])
 364  AC_SUBST([HAVE_$1])
 365  AC_MSG_CHECKING([$2])
 366  AC_MSG_RESULT([$HAVE_$1])
 367  if test "x$HAVE_$1" = "xno"; then
 368   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 369  fi
 370 fi
 371 ])
 372
 373 AC_DEFUN([CHECK_LIB], [
 374 if test "x$HAVE_$1" != "xno"; then
 375  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 376   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 377   AC_SUBST([HAVE_$1])
 378   if test "x$HAVE_$1" = "xyes"; then
 379    if test "x$PKG_$1" = "x"; then
 380     SYSTEM_LIBS+=" -l[$2]"
 381     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 382    else
 383     SHARED_$1+=" -l[$2]"
 384     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 385    fi
 386   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 387  fi
 388 fi
 389 ])
 390
 391 CHECK_LIB([X11], [X11], [XOpenDisplay])
 392 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 393 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 394 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 395 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 396 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 397 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 398 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 399 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 400 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 401 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 402 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 403 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 404 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 405 CHECK_LIB([PNG], [png], [png_read_png])
 406 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 407 CHECK_LIB([Z], [z], [gzopen])
 408 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 409 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 410 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 411 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 412 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 413 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 414 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 415 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 416 CHECK_LIB([lame], [mp3lame], [lame_init])
 417 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 418 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 419 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 420 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 421 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 422 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 423 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 424 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 425 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 426 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 427 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 428 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 429 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 430 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 431 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 432 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 433 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 434 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 435 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 436 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 437 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 438 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 439 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 440 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 441 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 442 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 443 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 444 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 445 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 446 CHECK_LIB([a52dec], [a52], [a52_init])
 447 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 448 CHECK_LIB([encore], [encore], [encore])
 449 CHECK_HEADERS([encore], [encore headers], [encore.h])
 450 CHECK_LIB([giflib], [gif], [DGifOpen])
 451 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 452 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 453 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 454 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 455 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 456 CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 457 CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])
 458
 459 #if test "x$HAVE_mjpegtools" = "xyes"; then
 460 #CFG_CFLAGS+=" -I/usr/include/mjpegtools"
 461 #fi
 462
 463 AC_DEFUN([CHECK_WANT], [
 464 RESULT=yes
 465 AC_ARG_WITH(m4_tolower([$1]),
 466  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 467   [WANT_$1=$withval],[WANT_$1=$2])
 468 # WANT_$1
 469 if test "x$WANT_$1" != "xno" ; then
 470  m4_quote($4)
 471  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 472   echo "=== want $1 Failed."
 473   WANT_$1=no
 474  elif test "x$WANT_$1" = "xauto" ; then
 475   WANT_$1=yes
 476  fi
 477 fi
 478 CFG_WANTS+=" $1"
 479 AC_SUBST([WANT_$1])
 480 ])
 481
 482 CHECK_WANT([GL], [auto], [use opengl], [
 483  CHECK_LIB([GL], [GL], [glUseProgram])
 484  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 485  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 486
 487 CHECK_WANT([OSS], [auto], [use OSS audio], [
 488  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 489
 490 CHECK_WANT([XFT], [auto], [use libXft], [
 491  CHECK_LIB([XFT], [Xft], [XftInit])
 492  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 493
 494 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 495  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 496  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 497
 498 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 499  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 500  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 501  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 502  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 503  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 504  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 505  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 506  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 507
 508 CHECK_WANT([DV], [auto], [use dv], [
 509  CHECK_LIB([libdv], [dv], [dv_init])
 510  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 511
 512 CHECK_WANT([DVB], [auto], [use dvb], [
 513  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 514
 515 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 516  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 517
 518 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 519  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 520
 521 CHECK_WANT([ESOUND], [no], [use esd], [
 522  CHECK_LIB([esound], [esd], [esd_open_sound])
 523  CHECK_HEADERS([esound], [esound headers], [esd.h])
 524  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 525  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 526
 527 CHECK_WANT([DL], [auto], [system has libdl], [
 528  CHECK_LIB([DL], [dl], [dlopen])])
 529
 530 CHECK_WANT([EXR], [auto], [use exr], [])
 531 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 532  WANT_OPENCV="$withval"
 533 ])
 534
 535 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 536  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 537
 538 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 539  AC_MSG_CHECKING([for openexr available])
 540  saved_LIBS="$LIBS"
 541  saved_CXXFLAGS="$CXXFLAGS"
 542  # ilmbase libs
 543  LIBS=" -lIlmImf -lIlmThread -lIex"
 544  CXXFLAGS="-I/usr/include/OpenEXR"
 545  AC_LANG_PUSH(C++)
 546  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 547 #include "ImfChannelList.h"
 548 #include "ImfChromaticities.h"
 549 #include "ImfCompression.h"
 550 #include "ImfIO.h"
 551 #include "ImfInputFile.h"
 552 #include "ImfOutputFile.h"
 553 #include "ImfPixelType.h"
 554 #include "ImfRgbaFile.h"
 555 #include "ImfRgbaYca.h"
 556 #include "ImfVersion.h"
 557 class EXRIStream : public Imf::IStream { public:
 558 EXRIStream() : Imf::IStream("mypath") {} };
 559 class EXROStream : public Imf::OStream { public:
 560 EXROStream() : Imf::OStream("mypath") {} };
 561 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 562  RESULT="$HAVE_OPENEXR"
 563  if test "x$RESULT" = "xyes"; then
 564    SHARED_openexr="$LIBS"
 565    CFG_CFLAGS+=" -I/usr/include/OpenEXR"
 566  fi
 567  LIBS="$saved_LIBS"
 568  CXXFLAGS="$saved_CXXFLAGS"
 569  AC_LANG_POP(C++)
 570  AC_MSG_RESULT([$HAVE_OPENEXR])
 571 ])
 572 AC_SUBST([HAVE_OPENEXR])
 573
 574 # build global_config
 575 OBJDIR=`uname -m`
 576 AC_SUBST(OBJDIR)
 577
 578 echo "AC_HELP_STRING([Reason],[Package])"
 579 echo "AC_HELP_STRING([------],[-------])"
 580
 581 AC_DEFUN([PKG_DISABLED],[
 582  PKG_$1="no"
 583  BUILD_$1=0
 584  AC_SUBST(BUILD_$1)
 585  echo "AC_HELP_STRING([disabled],[$1])"
 586 ])
 587 AC_DEFUN([PKG_SHARED],[
 588  BUILD_$1=0
 589  AC_SUBST(BUILD_$1)
 590  SHARED_LIBS+="$SHARED_$1"
 591  echo "AC_HELP_STRING([shared],[$1])"
 592 ])
 593 AC_DEFUN([PKG_STATIC],[
 594  PKG_$1="yes"
 595  BUILD_$1=1
 596  AC_SUBST(BUILD_$1)
 597  STATIC_BLDS+=" [$1]"
 598  echo "AC_HELP_STRING([$2],[$1])"
 599 ])
 600 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 601
 602 # order matters
 603 for dep in \
 604         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 605         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 ffmpeg/fdk \
 606         libiec61883/libraw1394 libavc1394/librom1394 \
 607         openexr/ilmbase ilmbase/libogg \
 608         libtheora/libogg libtheora/libvorbis ; do
 609   lib=`dirname $dep`;  needs=`basename $dep`
 610   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 611   if test "x$pkg_lib" != "xno"; then
 612     eval "PKG_$needs=yes"
 613   fi
 614 done
 615
 616 AC_DEFUN([PKG_PROVIDE],[
 617 if test "x$BUILD_$1" = "x" ; then
 618  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 619   PKG_DISABLED([$1])
 620  elif test "x$PKG_$1" = "xyes"; then
 621   PKG_FORCED([$1])
 622  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 623   PKG_STATIC([$1],[static])
 624  elif test "x$HAVE_$1" = "xyes"; then
 625   PKG_SHARED([$1])
 626  else
 627   PKG_STATIC([$1],[needed])
 628  fi
 629 fi
 630 ])
 631
 632 PKG_PROVIDE([a52dec])
 633 PKG_PROVIDE([djbfft])
 634 PKG_PROVIDE([encore])
 635 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 636 PKG_PROVIDE([esound],[$WANT_ESOUND])
 637 PKG_PROVIDE([fdk])
 638 PKG_PROVIDE([ffmpeg])
 639 PKG_PROVIDE([fftw])
 640 PKG_PROVIDE([flac])
 641 PKG_PROVIDE([giflib])
 642 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 643 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 644 PKG_PROVIDE([lame])
 645 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 646 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 647 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 648 PKG_PROVIDE([libdv],[$WANT_DV])
 649 PKG_PROVIDE([libjpeg])
 650 PKG_PROVIDE([libogg])
 651 PKG_PROVIDE([libsndfile])
 652 PKG_PROVIDE([libtheora])
 653 PKG_PROVIDE([libuuid])
 654 PKG_PROVIDE([libvorbis])
 655 PKG_PROVIDE([mjpegtools])
 656 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 657 PKG_PROVIDE([openjpeg])
 658 PKG_PROVIDE([tiff])
 659 PKG_PROVIDE([twolame])
 660 PKG_PROVIDE([x264])
 661 PKG_PROVIDE([x265])
 662 PKG_PROVIDE([libvpx])
 663
 664 AC_SUBST(STATIC_BLDS)
 665 AC_SUBST(SHARED_LIBS)
 666
 667 for f in $SYSTEM_LIBS; do
 668   echo "AC_HELP_STRING([system],[$f])"
 669 done
 670 AC_SUBST(SYSTEM_LIBS)
 671
 672 echo ""
 673 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 674          VIDEO4LINUX2 ESOUND PACTL OPENEXR; do
 675   eval vv="\$WANT_$v"
 676   if test "x$vv" != "xno"; then
 677     CFG_CFLAGS+=" -DHAVE_$v"
 678     vv=with
 679   else
 680     vv=without
 681   fi
 682   v=`echo "$v" | tr "A-Z" "a-z"`
 683   echo "  using: $vv-$v"
 684 done
 685
 686 echo "  using: with-jobs = $WANT_JOBS"
 687 echo "  using: exec-name = $WANT_CIN"
 688 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 689 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 690 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 691 echo "  using: with-browser = $WANT_CIN_BROWSER"
 692 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 693 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 694 echo "  using: with-opencv = $WANT_OPENCV"
 695 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 696 echo ""
 697 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 698 echo "  using: static-build = $WANT_STATIC_BUILD"
 699 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 700 echo ""
 701
 702 # build extras
 703 if test "x$HAVE_tiff" = "xyes"; then
 704   if test "x$HAVE_jbig" = "xyes"; then
 705     EXTRA_LIBS+=' -ljbig'
 706   fi
 707 fi
 708 if test "x$HAVE_NUMA" = "xyes"; then
 709   EXTRA_LIBS+=' -lnuma'
 710 fi
 711 if test "x$HAVE_DL" = "xyes"; then
 712   EXTRA_LIBS+=' -ldl'
 713   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 714 fi
 715 if test "x$HAVE_opus" = "xyes"; then
 716   EXTRA_LIBS+=' -lopus'
 717   CFG_CFLAGS+=' -I/usr/include/opus'
 718   FFMPEG_EXTRA_CFG+=' --enable-libopus'
 719 fi
 720
 721 AC_SUBST(EXTRA_LIBS)
 722 AC_SUBST(FFMPEG_EXTRA_CFG)
 723 AC_SUBST(WANT_X264_HIDEPTH)
 724 AC_SUBST(WANT_X265_HIDEPTH)
 725
 726 AC_SUBST(CFG_CFLAGS)
 727 AC_SUBST(CFG_CXXFLAGS)
 728
 729 AC_CONFIG_FILES([Makefile])
 730 AC_OUTPUT
 731
 732 exec > global_config
 733
 734 echo "SHELL := /bin/bash"
 735 echo "export SHELL"
 736 echo "WANT_JOBS := $WANT_JOBS"
 737 echo ""
 738 echo "OBJDIR := $OBJDIR"
 739 echo "BINDIR := \$(TOPDIR)/bin"
 740 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 741 echo "GUICAST := \$(TOPDIR)/guicast"
 742 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 743 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 744 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 745 echo "PLUGINS := \$(TOPDIR)/plugins"
 746 echo "TDB := \$(TOPDIR)/db"
 747 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 748 echo "EXTRA_LIBS := $EXTRA_LIBS"
 749 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 750 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 751 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 752 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 753 echo ""
 754
 755 echo "WANT_CIN := $WANT_CIN"
 756 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 757 echo ""
 758
 759 echo "ifndef CFLAGS_"
 760 echo "ifdef CFLAGS"
 761 echo "CFLAGS_ := \$(CFLAGS)"
 762 echo "else"
 763 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 764 echo "endif"
 765 echo "endif"
 766
 767 echo "CFLAGS := \$(CFLAGS_)"
 768 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 769 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 770 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 771 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 772 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 773 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 774 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 775 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 776 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 777 echo ""
 778 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 779 echo ""
 780
 781 if test  $WANT_X264_HIDEPTH = "yes" ; then
 782   echo "x264.cfg_params := --enable-static --bit-depth=10"
 783 fi
 784 if test  $WANT_X265_HIDEPTH = "yes" ; then
 785   echo "x265.cfg_params := -DENABLE_SHARED=no -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
 786 fi
 787
 788 for pkg in $STATIC_PKGS; do
 789   eval pkg_lib="\$PKG_$pkg"
 790   if test "x$pkg_lib" = "xno"; then continue; fi;
 791   echo "static_pkgs += $pkg"
 792 done
 793 echo ""
 794
 795 for pkg in $STATIC_BLDS; do
 796   echo "static_blds += $pkg"
 797   ver_pkg=ver_$pkg
 798   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 799   inc_pkg=inc_$pkg
 800   echo "$inc_pkg := \\"
 801   for inc in ${!inc_pkg}; do
 802     echo "  -I\$($ver_pkg)/$inc \\"
 803   done
 804   echo ""
 805   echo "static_incs += \$(inc_$pkg)"
 806   lib_pkg=lib_$pkg
 807   echo "$lib_pkg := \\"
 808   for lib in ${!lib_pkg}; do
 809     echo "  \$($ver_pkg)/$lib \\"
 810   done
 811   echo ""
 812   echo "static_libs += \$($lib_pkg)"
 813   echo ""
 814 done
 815 echo ""
 816
 817 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 818 echo ""
 819 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 820 echo "export static_pkgs static_blds shared_libs system_libs"
 821 echo ""
 822
 823 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 824 echo "libraries += -Wl,--start-group"
 825 echo "libraries += \$(thirdparty_libraries)"
 826 echo "libraries += \$(system_libs)"
 827 echo "libraries += \$(EXTRA_LIBS)"
 828 echo "libraries += -Wl,--end-group"
 829 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 830 echo "libraries += \$(thirdparty_libraries)"
 831 echo "libraries += \$(system_libs)"
 832 echo "libraries += \$(EXTRA_LIBS)"
 833 echo ""
 834 echo "export thirdparty_libraries libraries"
 835 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 836 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
 837
 838 if test "x$HAVE_tiff" = "xyes"; then
 839   if test "x$HAVE_jbig" != "xyes"; then
 840     echo "tiff.cfg_params+= --disable-jbig"
 841   fi
 842 fi
 843
 844 if test "x$WANT_GIT_FFMPEG" != "xno"; then
 845 echo "ffmpeg.git := $WANT_GIT_FFMPEG"
 846 fi
 847 if test "x$HAVE_opus" = "xyes"; then
 848 echo 'ffmpeg.cflags+=" -I/usr/include/opus"'
 849 fi