cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall -Wno-unused-result"
  13 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  14 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  15 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  16 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  17 CFG_CFLAGS+=" -I/usr/include/freetype2"
  18 CFG_CFLAGS+=" -I/usr/include/OpenEXR"
  19
  20 AC_DEFUN([CHECK_WITH], [
  21 AC_ARG_WITH([$1],
  22   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  23   [WANT_$3=$withval], [WANT_$3='$4'])
  24 AC_SUBST([WANT_$3])
  25 ])
  26
  27 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  28 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  29 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  30 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  31 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  32 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  33 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  34 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  35 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  36 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  37
  38 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  39   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  40   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  41   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  42   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  43   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  44   sinstall=dinstall
  45   suninstall=duninstall
  46 else
  47   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  48     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  49     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  50     echo "$dir"`
  51   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  52     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  53     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  54     echo "$dir"`
  55   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  56     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  57     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  58     echo "$dir"`
  59   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  60        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  61   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  62     usrlib+="64"
  63   WANT_LOCALE_DIR="$lcldir"
  64   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  65   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  66   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  67   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  68   sinstall=cinstall
  69   suninstall=cuninstall
  70 fi
  71 AC_SUBST(sinstall)
  72 AC_SUBST(suninstall)
  73
  74 if test "x$WANT_JOBS" = "xauto"; then
  75   CPUS=`grep -c "^proc" /proc/cpuinfo`
  76   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  77 fi
  78
  79 AC_DEFUN([PKG_DEF],[
  80 STATIC_PKGS+=" [$1]"
  81 ver_$1="$2"
  82 lib_$1="$3"
  83 inc_$1="$4"
  84 ])
  85
  86 AC_DEFUN([PKG_3RD],[
  87 AC_ARG_ENABLE([$1],
  88   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  89   [PKG_$1=$enableval], [PKG_$1=$2])
  90 PKG_DEF([$1],[$3],[$4],[$5])
  91 ])
  92
  93 # thirdparty builds
  94
  95 PKG_3RD([a52dec],[yes],
  96   [a52dec-0.7.4],
  97   [ liba52/.libs/liba52.a ],
  98   [ include ])
  99
 100 PKG_3RD([djbfft],[yes],
 101   [djbfft-0.76],
 102   [ libdjbfft.a ],
 103   [ . ])
 104
 105 PKG_3RD([audiofile],[no],
 106   [audiofile-0.3.6],
 107   [ libaudiofile/.libs/libaudiofile.a \
 108     libaudiofile/modules/.libs/libmodules.a \
 109     libaudiofile/alac/.libs/libalac.a ],
 110   [ libaudiofile ])
 111
 112 PKG_3RD([encore],[no],
 113   [encore-5.0],
 114   [ \$(OBJDIR)/libencore.a ],
 115   [ . ])
 116
 117 PKG_3RD([esound],[no],
 118   [esound-0.2.41],
 119   [ .libs/libesd.a \
 120     .libs/libesddsp.a ],
 121   [ . ])
 122
 123 PKG_3RD([fdk],[auto],
 124   [fdk-aac-0.1.5],
 125   [ .libs/libfdk-aac.a ],
 126   [ libAACdec/include libAACenc/include libSYS/include ])
 127
 128 PKG_3RD([ffmpeg],[yes],
 129   [ffmpeg-3.3.2],
 130   [ libavutil/libavutil.a \
 131     libavcodec/libavcodec.a \
 132     libpostproc/libpostproc.a \
 133     libavdevice/libavdevice.a \
 134     libavformat/libavformat.a \
 135     libswscale/libswscale.a \
 136     libavfilter/libavfilter.a \
 137     libswresample/libswresample.a ],
 138   [ . ])
 139
 140 PKG_3RD([fftw],[auto],
 141   [fftw-3.3.6-pl2],
 142   [ .libs/libfftw3.a \
 143     libbench2/libbench2.a \
 144     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 145     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 146     rdft/scalar/.libs/librdft_scalar.a \
 147     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 148     rdft/.libs/librdft.a \
 149     api/.libs/libapi.a \
 150     reodft/.libs/libreodft.a \
 151     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 152     dft/scalar/.libs/libdft_scalar.a \
 153     dft/.libs/libdft.a \
 154     kernel/.libs/libkernel.a \
 155     simd-support/.libs/libsimd_support.a \
 156     simd-support/.libs/libsimd_sse2_nonportable.a ],
 157   [ api ])
 158
 159 PKG_3RD([flac],[auto],
 160   [flac-1.3.2],
 161   [ src/libFLAC/.libs/libFLAC.a \
 162     src/libFLAC++/.libs/libFLAC++.a \
 163     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 164     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 165     src/share/grabbag/.libs/libgrabbag.a \
 166     src/share/utf8/.libs/libutf8.a \
 167     src/test_libs_common/.libs/libtest_libs_common.a ],
 168   [ include ])
 169
 170 PKG_3RD([giflib],[yes],
 171   [giflib-5.1.4],
 172   [ lib/.libs/libgif.a \
 173     util/libgetarg.a ],
 174   [ lib ])
 175
 176 PKG_3RD([ilmbase],[auto],
 177   [ilmbase-2.2.0],
 178   [ Iex/.libs/libIex.a \
 179     IexMath/.libs/libIexMath.a \
 180     Half/.libs/libHalf.a \
 181     Imath/.libs/libImath.a \
 182     IlmThread/.libs/libIlmThread.a ],
 183   [ Iex Half Imath config IlmThread ])
 184
 185 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 186
 187 PKG_3RD([lame],[auto],
 188   [lame-3.99.5],
 189   [ libmp3lame/.libs/libmp3lame.a \
 190     mpglib/.libs/libmpgdecoder.a ],
 191   [ include ])
 192
 193 PKG_3RD([libavc1394],[auto],
 194   [libavc1394-0.5.4],
 195   [ libavc1394/.libs/libavc1394.a \
 196     librom1394/.libs/librom1394.a \
 197     common/.libs/libraw1394util.a ],
 198   [ . ])
 199
 200 PKG_3RD([libraw1394],[auto],
 201   [libraw1394-2.1.2],
 202   [ src/.libs/libraw1394.a ],
 203   [ . ])
 204
 205 PKG_3RD([libiec61883],[auto],
 206   [libiec61883-1.2.0],
 207   [ src/.libs/libiec61883.a ],
 208   [ src ])
 209
 210 PKG_3RD([libdv],[auto],
 211   [libdv-1.0.0],
 212   [ libdv/.libs/libdv.a ],
 213   [ . ])
 214
 215 PKG_3RD([libjpeg],[auto],
 216   [libjpeg-turbo-1.5.1],
 217   [ .libs/libjpeg.a \
 218     .libs/libturbojpeg.a \
 219     simd/.libs/libsimd.a ],
 220   [ . ])
 221
 222 PKG_3RD([openjpeg],[auto],
 223   [openjpeg-2.1.0-20160221],
 224   [ bin/libopenjp2.a ],
 225   [ src/lib/openjp2 ])
 226
 227 PKG_3RD([libogg],[auto],
 228   [libogg-1.3.2],
 229   [ src/.libs/libogg.a ],
 230   [ include ])
 231
 232 PKG_3RD([libsndfile],[auto],
 233   [libsndfile-1.0.28],
 234   [ src/.libs/libsndfile.a \
 235     src/.libs/libcommon.a \
 236     src/G72x/.libs/libg72x.a \
 237     src/GSM610/.libs/libgsm.a ],
 238   [ . ])
 239
 240 PKG_3RD([libtheora],[auto],
 241   [libtheora-1.1.1],
 242   [ lib/.libs/libtheora.a \
 243     lib/.libs/libtheoradec.a \
 244     lib/.libs/libtheoraenc.a ],
 245   [ . ])
 246
 247 PKG_3RD([libuuid],[yes],
 248   [libuuid-1.0.3],
 249   [ .libs/libuuid.a ],
 250   [ . ])
 251
 252 PKG_3RD([libvorbis],[auto],
 253   [libvorbis-1.3.5],
 254   [ lib/.libs/libvorbis.a \
 255     lib/.libs/libvorbisenc.a \
 256     lib/.libs/libvorbisfile.a ],
 257   [ include . ])
 258
 259 PKG_3RD([mjpegtools],[yes],
 260   [mjpegtools-2.1.0],
 261   [ utils/mmxsse/.libs/libmmxsse.a \
 262     utils/.libs/libmjpegutils.a \
 263     lavtools/.libs/liblavfile.a \
 264     lavtools/.libs/liblavjpeg.a \
 265     mplex/.libs/libmplex2.a \
 266     yuvfilters/.libs/libyuvfilters.a \
 267     mpeg2enc/.libs/libmpeg2encpp.a ],
 268   [ .  lavtools utils ])
 269
 270 PKG_3RD([openexr],[auto],
 271   [openexr-2.2.0],
 272   [ IlmImf/.libs/libIlmImf.a \
 273     IlmImfUtil/.libs/libIlmImfUtil.a ],
 274   [ IlmImf config ])
 275
 276 #PKG_3RD([festival],[no],
 277 #  [festival],
 278 #  [],
 279 #  [])
 280 #PKG_3RD(speech_tools,[no],
 281 #  [speech_tools],
 282 #  [],
 283 #  [])
 284 #
 285 PKG_3RD([tiff],[auto],
 286   [tiff-4.0.6],
 287   [ libtiff/.libs/libtiff.a \
 288     libtiff/.libs/libtiffxx.a \
 289     port/.libs/libport.a ],[
 290    . ])
 291
 292 PKG_3RD([twolame],[auto],
 293   [twolame-0.3.13],
 294   [ libtwolame/.libs/libtwolame.a ],
 295   [  libtwolame ])
 296
 297 PKG_3RD([x264],[auto],
 298   [x264-snapshot-20170426-2245],
 299   [ libx264.a ],
 300   [ . ])
 301
 302 PKG_3RD([x265],[auto],
 303   [x265_2.4],
 304   [ libx265.a ],
 305   [ . source ])
 306
 307 PKG_3RD([libvpx],[auto],
 308   [libvpx-1.6.1],
 309   [ libvpx.a ],
 310   [ . ])
 311
 312 AC_SUBST(STATIC_PKGS)
 313
 314 AC_DEFUN([CHECK_ENABLE], [
 315 AC_ARG_ENABLE([$1],
 316   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 317   [WANT_$2=$enableval], [WANT_$2=[$4]])
 318 ])
 319
 320 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 321 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 322 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10/12bit], [no])
 323
 324 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 325
 326 AC_DEFUN([CHECK_PROG], [
 327  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 328 ])
 329 AC_DEFUN([REQUIRE_PROG], [
 330  CHECK_PROG([$1],[$2])
 331  if test "x$PROG_$1" = "xno"; then
 332    AC_MSG_WARN([$2 is missing and required.])
 333    FATAL_ERROR=1
 334  fi
 335 ])
 336
 337 # Checks for programs.
 338
 339 REQUIRE_PROG(NASM, [nasm])
 340 REQUIRE_PROG(YASM, [yasm])
 341 REQUIRE_PROG(OBJCOPY, [objcopy])
 342 if test "x$FATAL_ERROR" != "x"; then
 343  AC_MSG_ERROR("fatal eror.")
 344 fi
 345 CHECK_PROG(PACTL, [pactl])
 346 WANT_PACTL=$PROG_PACTL
 347
 348 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 349 if test "$no_utf" = "yes"; then
 350   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 351 fi
 352
 353 # Checks for headers/libraries.
 354
 355 AC_DEFUN([CHECK_HEADERS], [
 356 if test "x$HAVE_$1" != "xno"; then
 357  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 358   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 359 ]])])
 360  AC_SUBST([HAVE_$1])
 361  AC_MSG_CHECKING([$2])
 362  AC_MSG_RESULT([$HAVE_$1])
 363  if test "x$HAVE_$1" = "xno"; then
 364   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 365  fi
 366 fi
 367 ])
 368
 369 AC_DEFUN([CHECK_LIB], [
 370 if test "x$HAVE_$1" != "xno"; then
 371  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 372   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 373   AC_SUBST([HAVE_$1])
 374   if test "x$HAVE_$1" = "xyes"; then
 375    if test "x$PKG_$1" = "x"; then
 376     SYSTEM_LIBS+=" -l[$2]"
 377     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 378    else
 379     SHARED_$1+=" -l[$2]"
 380     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 381    fi
 382   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 383  fi
 384 fi
 385 ])
 386
 387 CHECK_LIB([X11], [X11], [XOpenDisplay])
 388 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 389 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 390 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 391 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 392 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 393 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 394 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 395 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 396 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 397 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 398 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 399 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 400 CHECK_LIB([PNG], [png], [png_read_png])
 401 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 402 CHECK_LIB([Z], [z], [gzopen])
 403 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 404 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 405 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 406 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 407 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 408 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 409 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 410 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 411 CHECK_LIB([lame], [mp3lame], [lame_init])
 412 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 413 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 414 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 415 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 416 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 417 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 418 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 419 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 420 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 421 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 422 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 423 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 424 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 425 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 426 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 427 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 428 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 429 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 430 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 431 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 432 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 433 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 434 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 435 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 436 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 437 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 438 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 439 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 440 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 441 CHECK_LIB([a52dec], [a52], [a52_init])
 442 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 443 CHECK_LIB([encore], [encore], [encore])
 444 CHECK_HEADERS([encore], [encore headers], [encore.h])
 445 CHECK_LIB([giflib], [gif], [DGifOpen])
 446 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 447 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 448 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 449 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 450 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 451
 452 #if test "x$HAVE_mjpegtools" = "xyes"; then
 453 #CFG_CFLAGS+=" -I/usr/include/mjpegtools"
 454 #fi
 455
 456 AC_DEFUN([CHECK_WANT], [
 457 RESULT=yes
 458 AC_ARG_WITH(m4_tolower([$1]),
 459  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 460   [WANT_$1=$withval],[WANT_$1=$2])
 461 # WANT_$1
 462 if test "x$WANT_$1" != "xno" ; then
 463  m4_quote($4)
 464  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 465   echo "=== want $1 Failed."
 466   WANT_$1=no
 467  else
 468   WANT_$1=yes
 469  fi
 470 fi
 471 CFG_WANTS+=" $1"
 472 AC_SUBST([WANT_$1])
 473 ])
 474
 475 CHECK_WANT([GL], [auto], [use opengl], [
 476  CHECK_LIB([GL], [GL], [glUseProgram])
 477  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 478  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 479
 480 CHECK_WANT([OSS], [auto], [use OSS audio], [
 481  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 482
 483 CHECK_WANT([XFT], [auto], [use libXft], [
 484  CHECK_LIB([XFT], [Xft], [XftInit])
 485  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 486
 487 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 488  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 489  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 490
 491 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 492  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 493  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 494  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 495  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 496  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 497  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 498  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 499  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 500
 501 CHECK_WANT([DV], [auto], [use dv], [
 502  CHECK_LIB([libdv], [dv], [dv_init])
 503  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 504
 505 CHECK_WANT([DVB], [auto], [use dvb], [
 506  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 507
 508 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 509  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 510
 511 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 512  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 513
 514 CHECK_WANT([ESOUND], [no], [use esd], [
 515  CHECK_LIB([esound], [esd], [esd_open_sound])
 516  CHECK_HEADERS([esound], [esound headers], [esd.h])
 517  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 518  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 519
 520 CHECK_WANT([DL], [auto], [system has libdl], [
 521  CHECK_LIB([DL], [dl], [dlopen])])
 522
 523 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 524  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 525
 526
 527 AC_MSG_CHECKING([for openexr available])
 528 saved_LIBS="$LIBS"
 529 saved_CXXFLAGS="$CXXFLAGS"
 530 # ilmbase libs
 531 LIBS=" -lIlmImf -lIlmThread -lIex"
 532 CXXFLAGS="-I/usr/include/OpenEXR"
 533 AC_LANG_PUSH(C++)
 534 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 535 #include "ImfChannelList.h"
 536 #include "ImfChromaticities.h"
 537 #include "ImfCompression.h"
 538 #include "ImfIO.h"
 539 #include "ImfInputFile.h"
 540 #include "ImfOutputFile.h"
 541 #include "ImfPixelType.h"
 542 #include "ImfRgbaFile.h"
 543 #include "ImfRgbaYca.h"
 544 #include "ImfVersion.h"
 545 class EXRIStream : public Imf::IStream { public:
 546 EXRIStream() : Imf::IStream("mypath") {} };
 547 class EXROStream : public Imf::OStream { public:
 548 EXROStream() : Imf::OStream("mypath") {} };
 549 ]])], [HAVE_openexr=yes], [HAVE_openexr=no])
 550 if test "x$HAVE_openexr" = "xyes"; then
 551   SHARED_openexr="$LIBS"
 552 fi
 553 LIBS="$saved_LIBS"
 554 CXXFLAGS="$saved_CXXFLAGS"
 555 AC_LANG_POP(C++)
 556 AC_MSG_RESULT([$HAVE_openexr])
 557 AC_SUBST([HAVE_openexr])
 558
 559 # build global_config
 560 OBJDIR=`uname -m`
 561 AC_SUBST(OBJDIR)
 562
 563 echo "AC_HELP_STRING([Reason],[Package])"
 564 echo "AC_HELP_STRING([------],[-------])"
 565
 566 AC_DEFUN([PKG_DISABLED],[
 567   BUILD_$1=0
 568   AC_SUBST(BUILD_$1)
 569   echo "AC_HELP_STRING([disabled],[$1])"
 570 ])
 571 AC_DEFUN([PKG_SHARED],[
 572  BUILD_$1=0
 573  AC_SUBST(BUILD_$1)
 574  SHARED_LIBS+="$SHARED_$1"
 575  echo "AC_HELP_STRING([shared],[$1])"
 576 ])
 577 AC_DEFUN([PKG_STATIC],[
 578  BUILD_$1=1
 579  AC_SUBST(BUILD_$1)
 580  STATIC_BLDS+=" [$1]"
 581  echo "AC_HELP_STRING([$2],[$1])"
 582 ])
 583 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 584
 585 # order matters
 586 for dep in \
 587         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 588         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 ffmpeg/fdk \
 589         libiec61883/libraw1394 libavc1394/librom1394 \
 590         openexr/ilmbase ilmbase/libogg \
 591         libtheora/libogg libtheora/libvorbis ; do
 592   lib=`dirname $dep`;  needs=`basename $dep`
 593   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 594   if test "x$pkg_lib" != "xno"; then
 595     eval "PKG_$needs=yes"
 596   fi
 597 done
 598
 599 AC_DEFUN([PKG_PROVIDE],[
 600 if test "x$BUILD_$1" = "x" ; then
 601  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 602   PKG_DISABLED([$1])
 603  elif test "x$PKG_$1" = "xyes"; then
 604   PKG_FORCED([$1])
 605  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 606   PKG_STATIC([$1],[static])
 607  elif test "x$HAVE_$1" = "xyes"; then
 608   PKG_SHARED([$1])
 609  else
 610   PKG_STATIC([$1],[needed])
 611  fi
 612 fi
 613 ])
 614
 615 PKG_PROVIDE([a52dec])
 616 PKG_PROVIDE([djbfft])
 617 PKG_PROVIDE([encore])
 618 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 619 PKG_PROVIDE([esound],[$WANT_ESOUND])
 620 PKG_PROVIDE([fdk])
 621 PKG_PROVIDE([ffmpeg])
 622 PKG_PROVIDE([fftw])
 623 PKG_PROVIDE([flac])
 624 PKG_PROVIDE([giflib])
 625 PKG_PROVIDE([ilmbase])
 626 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 627 PKG_PROVIDE([lame])
 628 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 629 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 630 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 631 PKG_PROVIDE([libdv],[$WANT_DV])
 632 PKG_PROVIDE([libjpeg])
 633 PKG_PROVIDE([libogg])
 634 PKG_PROVIDE([libsndfile])
 635 PKG_PROVIDE([libtheora])
 636 PKG_PROVIDE([libuuid])
 637 PKG_PROVIDE([libvorbis])
 638 PKG_PROVIDE([mjpegtools])
 639 PKG_PROVIDE([openexr])
 640 PKG_PROVIDE([openjpeg])
 641 PKG_PROVIDE([tiff])
 642 PKG_PROVIDE([twolame])
 643 PKG_PROVIDE([x264])
 644 PKG_PROVIDE([x265])
 645 PKG_PROVIDE([libvpx])
 646
 647 AC_SUBST(STATIC_BLDS)
 648 AC_SUBST(SHARED_LIBS)
 649
 650 for f in $SYSTEM_LIBS; do
 651   echo "AC_HELP_STRING([system],[$f])"
 652 done
 653 AC_SUBST(SYSTEM_LIBS)
 654
 655 echo ""
 656 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 657          VIDEO4LINUX2 ESOUND PACTL; do
 658   eval vv="\$WANT_$v"
 659   if test "x$vv" != "xno"; then
 660     CFG_CFLAGS+=" -DHAVE_$v"
 661     vv=with
 662   else
 663     vv=without
 664   fi
 665   v=`echo "$v" | tr "A-Z" "a-z"`
 666   echo "  using: $vv-$v"
 667 done
 668
 669 echo "  using: with-jobs = $WANT_JOBS"
 670 echo "  using: exec-name = $WANT_CIN"
 671 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 672 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 673 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 674 echo "  using: with-browser = $WANT_CIN_BROWSER"
 675 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 676 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 677 echo ""
 678 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 679 echo "  using: static-build = $WANT_STATIC_BUILD"
 680 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 681 echo ""
 682
 683 # build extras
 684 if test "x$HAVE_tiff" = "xyes"; then
 685   if test "x$HAVE_jbig" = "xyes"; then
 686     EXTRA_LIBS+=' -ljbig'
 687   fi
 688 fi
 689 if test "x$HAVE_NUMA" = "xyes"; then
 690   EXTRA_LIBS+=' -lnuma'
 691 fi
 692 if test "x$HAVE_DL" = "xyes"; then
 693   EXTRA_LIBS+=' -ldl'
 694   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 695 fi
 696 AC_SUBST(EXTRA_LIBS)
 697 AC_SUBST(FFMPEG_EXTRA_CFG)
 698 AC_SUBST(WANT_X264_HIDEPTH)
 699 AC_SUBST(WANT_X265_HIDEPTH)
 700
 701 AC_SUBST(CFG_CFLAGS)
 702 AC_SUBST(CFG_CXXFLAGS)
 703
 704 AC_CONFIG_FILES([Makefile])
 705 AC_OUTPUT
 706
 707 exec > global_config
 708
 709 echo "SHELL := /bin/bash"
 710 echo "export SHELL"
 711 echo "WANT_JOBS := $WANT_JOBS"
 712 echo ""
 713 echo "OBJDIR := $OBJDIR"
 714 echo "BINDIR := \$(TOPDIR)/bin"
 715 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 716 echo "GUICAST := \$(TOPDIR)/guicast"
 717 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 718 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 719 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 720 echo "PLUGINS := \$(TOPDIR)/plugins"
 721 echo "TDB := \$(TOPDIR)/db"
 722 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 723 echo "EXTRA_LIBS := $EXTRA_LIBS"
 724 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 725 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 726 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 727 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 728 echo ""
 729
 730 echo "WANT_CIN := $WANT_CIN"
 731 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 732 echo ""
 733
 734 echo "ifndef CFLAGS_"
 735 echo "ifdef CFLAGS"
 736 echo "CFLAGS_ := \$(CFLAGS)"
 737 echo "else"
 738 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 739 echo "endif"
 740 echo "endif"
 741
 742 echo "CFLAGS := \$(CFLAGS_)"
 743 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 744 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 745 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 746 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 747 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 748 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 749 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 750 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 751 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 752 echo ""
 753 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 754 echo ""
 755
 756 if test  $WANT_X264_HIDEPTH = "yes" ; then
 757   echo "x264.cfg_params := --enable-static --bit-depth=10"
 758 fi
 759 if test  $WANT_X265_HIDEPTH = "yes" ; then
 760   echo "x265.cfg_params := -DENABLE_SHARED=no -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
 761 fi
 762
 763 for pkg in $STATIC_PKGS; do echo "static_pkgs += $pkg"; done
 764 echo ""
 765 for pkg in $STATIC_BLDS; do
 766   echo "static_blds += $pkg"
 767   ver_pkg=ver_$pkg
 768   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 769   inc_pkg=inc_$pkg
 770   echo "$inc_pkg := \\"
 771   for inc in ${!inc_pkg}; do
 772     echo "  -I\$($ver_pkg)/$inc \\"
 773   done
 774   echo ""
 775   echo "static_incs += \$(inc_$pkg)"
 776   lib_pkg=lib_$pkg
 777   echo "$lib_pkg := \\"
 778   for lib in ${!lib_pkg}; do
 779     echo "  \$($ver_pkg)/$lib \\"
 780   done
 781   echo ""
 782   echo "static_libs += \$($lib_pkg)"
 783   echo ""
 784 done
 785 echo ""
 786
 787 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 788 echo ""
 789 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 790 echo "export static_pkgs static_blds shared_libs system_libs"
 791 echo ""
 792
 793 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 794 echo "libraries += -Wl,--start-group"
 795 echo "libraries += \$(thirdparty_libraries)"
 796 echo "libraries += \$(system_libs)"
 797 echo "libraries += \$(EXTRA_LIBS)"
 798 echo "libraries += -Wl,--end-group"
 799 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 800 echo "libraries += \$(thirdparty_libraries)"
 801 echo "libraries += \$(system_libs)"
 802 echo "libraries += \$(EXTRA_LIBS)"
 803 echo ""
 804 echo "export thirdparty_libraries libraries"
 805 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 806 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
 807
 808 if test "x$HAVE_tiff" = "xyes"; then
 809   if test "x$HAVE_jbig" != "xyes"; then
 810     echo "tiff.cfg_params+= --disable-jbig"
 811   fi
 812 fi
 813