cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 CFG_CFLAGS+=" -Wno-unused-result"
  15 CFG_CFLAGS+=" -Wno-stringop-truncation"
  16 CFG_CFLAGS+=" -Wno-stringop-overflow"
  17 CFG_CFLAGS+=" -Wno-format-truncation"
  18 CFG_CFLAGS+=" -Wno-format-overflow"
  19 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  20 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  21 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  22 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  23 CFG_CFLAGS+=" -I/usr/include/freetype2"
  24
  25 AC_DEFUN([CHECK_WITH], [
  26 AC_ARG_WITH([$1],
  27   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  28   [WANT_$3=$withval], [WANT_$3='$4'])
  29 AC_SUBST([WANT_$3])
  30 ])
  31
  32 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  33 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  34 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  35 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  36 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  37 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  38 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  39 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  40 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  41 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  42 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  43
  44 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  45   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  46   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  47   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  48   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  49   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  50   sinstall=dinstall
  51   suninstall=duninstall
  52 else
  53   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  54     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  55     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  56     echo "$dir"`
  57   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  58     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  59     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  60     echo "$dir"`
  61   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  62     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  63     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  64     echo "$dir"`
  65   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  66        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  67   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  68     usrlib+="64"
  69   WANT_LOCALE_DIR="$lcldir"
  70   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  71   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  72   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  73   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  74   sinstall=cinstall
  75   suninstall=cuninstall
  76 fi
  77 AC_SUBST(sinstall)
  78 AC_SUBST(suninstall)
  79
  80 if test "x$WANT_JOBS" = "xauto"; then
  81   CPUS=`grep -c "^proc" /proc/cpuinfo`
  82   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  83 fi
  84
  85 AC_DEFUN([PKG_DEF],[
  86 STATIC_PKGS+=" [$1]"
  87 ver_$1="$2"
  88 lib_$1="$3"
  89 inc_$1="$4"
  90 ])
  91
  92 AC_DEFUN([PKG_3RD],[
  93 AC_ARG_ENABLE([$1],
  94   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  95   [PKG_$1=$enableval], [PKG_$1=$2])
  96 PKG_DEF([$1],[$3],[$4],[$5])
  97 ])
  98
  99 # thirdparty builds
 100
 101 PKG_3RD([a52dec],[yes],
 102   [a52dec-0.7.4],
 103   [ liba52/.libs/liba52.a ],
 104   [ include ])
 105
 106 PKG_3RD([djbfft],[yes],
 107   [djbfft-0.76],
 108   [ libdjbfft.a ],
 109   [ . ])
 110
 111 PKG_3RD([audiofile],[no],
 112   [audiofile-0.3.6],
 113   [ libaudiofile/.libs/libaudiofile.a \
 114     libaudiofile/modules/.libs/libmodules.a \
 115     libaudiofile/alac/.libs/libalac.a ],
 116   [ libaudiofile ])
 117
 118 PKG_3RD([encore],[no],
 119   [encore-5.0],
 120   [ \$(OBJDIR)/libencore.a ],
 121   [ . ])
 122
 123 PKG_3RD([esound],[no],
 124   [esound-0.2.41],
 125   [ .libs/libesd.a \
 126     .libs/libesddsp.a ],
 127   [ . ])
 128
 129 PKG_3RD([fdk],[auto],
 130   [fdk-aac-0.1.5],
 131   [ .libs/libfdk-aac.a ],
 132   [ libAACdec/include libAACenc/include libSYS/include ])
 133
 134 PKG_3RD([ffmpeg],[yes],
 135   [ffmpeg-3.4.1],
 136   [ libavutil/libavutil.a \
 137     libavcodec/libavcodec.a \
 138     libpostproc/libpostproc.a \
 139     libavdevice/libavdevice.a \
 140     libavformat/libavformat.a \
 141     libswscale/libswscale.a \
 142     libavfilter/libavfilter.a \
 143     libswresample/libswresample.a ],
 144   [ . ])
 145
 146 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 147   ver_ffmpeg="ffmpeg.git"
 148 fi
 149
 150 PKG_3RD([fftw],[auto],
 151   [fftw-3.3.6-pl2],
 152   [ .libs/libfftw3.a \
 153     libbench2/libbench2.a \
 154     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 155     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 156     rdft/scalar/.libs/librdft_scalar.a \
 157     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 158     rdft/.libs/librdft.a \
 159     api/.libs/libapi.a \
 160     reodft/.libs/libreodft.a \
 161     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 162     dft/scalar/.libs/libdft_scalar.a \
 163     dft/.libs/libdft.a \
 164     kernel/.libs/libkernel.a \
 165     simd-support/.libs/libsimd_support.a \
 166     simd-support/.libs/libsimd_sse2_nonportable.a ],
 167   [ api ])
 168
 169 PKG_3RD([flac],[auto],
 170   [flac-1.3.2],
 171   [ src/libFLAC/.libs/libFLAC.a \
 172     src/libFLAC++/.libs/libFLAC++.a \
 173     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 174     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 175     src/share/grabbag/.libs/libgrabbag.a \
 176     src/share/utf8/.libs/libutf8.a \
 177     src/test_libs_common/.libs/libtest_libs_common.a ],
 178   [ include ])
 179
 180 PKG_3RD([giflib],[yes],
 181   [giflib-5.1.4],
 182   [ lib/.libs/libgif.a \
 183     util/libgetarg.a ],
 184   [ lib ])
 185
 186 PKG_3RD([ilmbase],[auto],
 187   [ilmbase-2.2.0],
 188   [ Iex/.libs/libIex.a \
 189     IexMath/.libs/libIexMath.a \
 190     Half/.libs/libHalf.a \
 191     Imath/.libs/libImath.a \
 192     IlmThread/.libs/libIlmThread.a ],
 193   [ Iex Half Imath config IlmThread ])
 194
 195 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 196
 197 PKG_3RD([lame],[auto],
 198   [lame-3.99.5],
 199   [ libmp3lame/.libs/libmp3lame.a \
 200     mpglib/.libs/libmpgdecoder.a ],
 201   [ include ])
 202
 203 PKG_3RD([libavc1394],[auto],
 204   [libavc1394-0.5.4],
 205   [ libavc1394/.libs/libavc1394.a \
 206     librom1394/.libs/librom1394.a \
 207     common/.libs/libraw1394util.a ],
 208   [ . ])
 209
 210 PKG_3RD([libraw1394],[auto],
 211   [libraw1394-2.1.2],
 212   [ src/.libs/libraw1394.a ],
 213   [ . ])
 214
 215 PKG_3RD([libiec61883],[auto],
 216   [libiec61883-1.2.0],
 217   [ src/.libs/libiec61883.a ],
 218   [ src ])
 219
 220 PKG_3RD([libdv],[auto],
 221   [libdv-1.0.0],
 222   [ libdv/.libs/libdv.a ],
 223   [ . ])
 224
 225 PKG_3RD([libjpeg],[auto],
 226   [libjpeg-turbo-1.5.1],
 227   [ .libs/libjpeg.a \
 228     .libs/libturbojpeg.a \
 229     simd/.libs/libsimd.a ],
 230   [ . ])
 231
 232 PKG_3RD([opus],[auto],
 233   [opus-1.2.1],
 234   [ .libs/libopus.a ],
 235   [ include ])
 236
 237 PKG_3RD([openjpeg],[auto],
 238   [openjpeg-2.1.0-20160221],
 239   [ bin/libopenjp2.a ],
 240   [ src/lib/openjp2 ])
 241
 242 PKG_3RD([libogg],[auto],
 243   [libogg-1.3.2],
 244   [ src/.libs/libogg.a ],
 245   [ include ])
 246
 247 PKG_3RD([libsndfile],[auto],
 248   [libsndfile-1.0.28],
 249   [ src/.libs/libsndfile.a \
 250     src/.libs/libcommon.a \
 251     src/G72x/.libs/libg72x.a \
 252     src/GSM610/.libs/libgsm.a ],
 253   [ . ])
 254
 255 PKG_3RD([libtheora],[auto],
 256   [libtheora-1.1.1],
 257   [ lib/.libs/libtheora.a \
 258     lib/.libs/libtheoradec.a \
 259     lib/.libs/libtheoraenc.a ],
 260   [ . ])
 261
 262 PKG_3RD([libuuid],[yes],
 263   [libuuid-1.0.3],
 264   [ .libs/libuuid.a ],
 265   [ . ])
 266
 267 PKG_3RD([libvorbis],[auto],
 268   [libvorbis-1.3.5],
 269   [ lib/.libs/libvorbis.a \
 270     lib/.libs/libvorbisenc.a \
 271     lib/.libs/libvorbisfile.a ],
 272   [ include . ])
 273
 274 PKG_3RD([mjpegtools],[yes],
 275   [mjpegtools-2.1.0],
 276   [ utils/mmxsse/.libs/libmmxsse.a \
 277     utils/.libs/libmjpegutils.a \
 278     lavtools/.libs/liblavfile.a \
 279     lavtools/.libs/liblavjpeg.a \
 280     mplex/.libs/libmplex2.a \
 281     yuvfilters/.libs/libyuvfilters.a \
 282     mpeg2enc/.libs/libmpeg2encpp.a ],
 283   [ .  lavtools utils ])
 284
 285 PKG_3RD([openexr],[auto],
 286   [openexr-2.2.0],
 287   [ IlmImf/.libs/libIlmImf.a \
 288     IlmImfUtil/.libs/libIlmImfUtil.a ],
 289   [ IlmImf config ])
 290
 291 #PKG_3RD([festival],[no],
 292 #  [festival],
 293 #  [],
 294 #  [])
 295 #PKG_3RD(speech_tools,[no],
 296 #  [speech_tools],
 297 #  [],
 298 #  [])
 299 #
 300 PKG_3RD([tiff],[auto],
 301   [tiff-4.0.6],
 302   [ libtiff/.libs/libtiff.a \
 303     libtiff/.libs/libtiffxx.a \
 304     port/.libs/libport.a ],[
 305    . ])
 306
 307 PKG_3RD([twolame],[auto],
 308   [twolame-0.3.13],
 309   [ libtwolame/.libs/libtwolame.a ],
 310   [  libtwolame ])
 311
 312 PKG_3RD([x264],[auto],
 313   [x264-snapshot-20170426-2245],
 314   [ libx264.a ],
 315   [ . ])
 316
 317 PKG_3RD([x265],[auto],
 318   [x265_2.5],
 319   [ libx265.a ],
 320   [ . source ])
 321
 322 PKG_3RD([libvpx],[auto],
 323   [libvpx-1.6.1],
 324   [ libvpx.a ],
 325   [ . ])
 326
 327 AC_SUBST(STATIC_PKGS)
 328
 329 AC_DEFUN([CHECK_ENABLE], [
 330 AC_ARG_ENABLE([$1],
 331   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 332   [WANT_$2=$enableval], [WANT_$2=[$4]])
 333 ])
 334
 335 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 336 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 337 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10/12bit], [no])
 338
 339 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 340
 341 AC_DEFUN([CHECK_PROG], [
 342  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 343 ])
 344 AC_DEFUN([REQUIRE_PROG], [
 345  CHECK_PROG([$1],[$2])
 346  if test "x$PROG_$1" = "xno"; then
 347    AC_MSG_WARN([$2 is missing and required.])
 348    FATAL_ERROR=1
 349  fi
 350 ])
 351
 352 # Checks for programs.
 353
 354 REQUIRE_PROG(NASM, [nasm])
 355 REQUIRE_PROG(YASM, [yasm])
 356 REQUIRE_PROG(OBJCOPY, [objcopy])
 357 if test "x$FATAL_ERROR" != "x"; then
 358  AC_MSG_ERROR("fatal eror.")
 359 fi
 360 CHECK_PROG(PACTL, [pactl])
 361 WANT_PACTL=$PROG_PACTL
 362
 363 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 364 if test "$no_utf" = "yes"; then
 365   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 366 fi
 367
 368 # Checks for headers/libraries.
 369
 370 AC_DEFUN([CHECK_HEADERS], [
 371 if test "x$HAVE_$1" != "xno"; then
 372  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 373   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 374 ]])])
 375  AC_SUBST([HAVE_$1])
 376  AC_MSG_CHECKING([$2])
 377  AC_MSG_RESULT([$HAVE_$1])
 378  if test "x$HAVE_$1" = "xno"; then
 379   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 380  fi
 381 fi
 382 ])
 383
 384 AC_DEFUN([CHECK_LIB], [
 385 if test "x$HAVE_$1" != "xno"; then
 386  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 387   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 388   AC_SUBST([HAVE_$1])
 389   if test "x$HAVE_$1" = "xyes"; then
 390    if test "x$PKG_$1" = "x"; then
 391     SYSTEM_LIBS+=" -l[$2]"
 392     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 393    else
 394     SHARED_$1+=" -l[$2]"
 395     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 396    fi
 397   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 398  fi
 399 fi
 400 ])
 401
 402 CHECK_LIB([X11], [X11], [XOpenDisplay])
 403 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 404 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 405 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 406 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 407 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 408 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 409 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 410 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 411 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 412 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 413 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 414 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 415 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 416 CHECK_LIB([PNG], [png], [png_read_png])
 417 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 418 CHECK_LIB([Z], [z], [gzopen])
 419 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 420 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 421 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 422 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 423 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 424 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 425 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 426 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 427 CHECK_LIB([lame], [mp3lame], [lame_init])
 428 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 429 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 430 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 431 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 432 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 433 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 434 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 435 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 436 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 437 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 438 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 439 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 440 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 441 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 442 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 443 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 444 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 445 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 446 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 447 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 448 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 449 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 450 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 451 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 452 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 453 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 454 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 455 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 456 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 457 CHECK_LIB([a52dec], [a52], [a52_init])
 458 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 459 CHECK_LIB([encore], [encore], [encore])
 460 CHECK_HEADERS([encore], [encore headers], [encore.h])
 461 CHECK_LIB([giflib], [gif], [DGifOpen])
 462 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 463 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 464 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 465 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 466 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 467
 468 #if test "x$HAVE_mjpegtools" = "xyes"; then
 469 #CFG_CFLAGS+=" -I/usr/include/mjpegtools"
 470 #fi
 471
 472 AC_DEFUN([CHECK_WANT], [
 473 RESULT=yes
 474 AC_ARG_WITH(m4_tolower([$1]),
 475  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 476   [WANT_$1=$withval],[WANT_$1=$2])
 477 # WANT_$1
 478 if test "x$WANT_$1" != "xno" ; then
 479  m4_quote($4)
 480  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 481   echo "=== want $1 Failed."
 482   WANT_$1=no
 483  elif test "x$WANT_$1" = "xauto" ; then
 484   WANT_$1=yes
 485  fi
 486 fi
 487 CFG_WANTS+=" $1"
 488 AC_SUBST([WANT_$1])
 489 ])
 490
 491 CHECK_WANT([GL], [auto], [use opengl], [
 492  CHECK_LIB([GL], [GL], [glUseProgram])
 493  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 494  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 495
 496 CHECK_WANT([OSS], [auto], [use OSS audio], [
 497  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 498
 499 CHECK_WANT([XFT], [auto], [use libXft], [
 500  CHECK_LIB([XFT], [Xft], [XftInit])
 501  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 502
 503 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 504  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 505  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 506
 507 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 508  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 509  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 510  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 511  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 512  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 513  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 514  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 515  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 516
 517 CHECK_WANT([DV], [auto], [use dv], [
 518  CHECK_LIB([libdv], [dv], [dv_init])
 519  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 520
 521 CHECK_WANT([DVB], [auto], [use dvb], [
 522  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 523
 524 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 525  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 526
 527 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 528  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 529
 530 CHECK_WANT([ESOUND], [no], [use esd], [
 531  CHECK_LIB([esound], [esd], [esd_open_sound])
 532  CHECK_HEADERS([esound], [esound headers], [esd.h])
 533  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 534  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 535
 536 CHECK_WANT([LIBOPUS], [auto], [use libopus], [
 537  CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 538  CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])])
 539
 540 CHECK_WANT([DL], [auto], [system has libdl], [
 541  CHECK_LIB([DL], [dl], [dlopen])])
 542
 543 CHECK_WANT([EXR], [auto], [use exr], [])
 544 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 545  WANT_OPENCV="$withval"
 546 ])
 547
 548 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 549  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 550
 551 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 552  AC_MSG_CHECKING([for openexr available])
 553  saved_LIBS="$LIBS"
 554  saved_CXXFLAGS="$CXXFLAGS"
 555  # ilmbase libs
 556  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 557  CXXFLAGS="-I/usr/include/OpenEXR"
 558  AC_LANG_PUSH(C++)
 559  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 560 #include "ImfChannelList.h"
 561 #include "ImfChromaticities.h"
 562 #include "ImfCompression.h"
 563 #include "ImfIO.h"
 564 #include "ImfInputFile.h"
 565 #include "ImfOutputFile.h"
 566 #include "ImfPixelType.h"
 567 #include "ImfRgbaFile.h"
 568 #include "ImfRgbaYca.h"
 569 #include "ImfVersion.h"
 570 class EXRIStream : public Imf::IStream { public:
 571 EXRIStream() : Imf::IStream("mypath") {} };
 572 class EXROStream : public Imf::OStream { public:
 573 EXROStream() : Imf::OStream("mypath") {} };
 574 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 575  RESULT="$HAVE_OPENEXR"
 576  if test "x$RESULT" = "xyes"; then
 577    SHARED_openexr="$LIBS"
 578    CFG_CFLAGS+=" -I/usr/include/OpenEXR"
 579  fi
 580  LIBS="$saved_LIBS"
 581  CXXFLAGS="$saved_CXXFLAGS"
 582  AC_LANG_POP(C++)
 583  AC_MSG_RESULT([$HAVE_OPENEXR])
 584 ])
 585 AC_SUBST([HAVE_OPENEXR])
 586
 587 # build global_config
 588 OBJDIR=`uname -m`
 589 AC_SUBST(OBJDIR)
 590
 591 echo "AC_HELP_STRING([Reason],[Package])"
 592 echo "AC_HELP_STRING([------],[-------])"
 593
 594 AC_DEFUN([PKG_DISABLED],[
 595  PKG_$1="no"
 596  BUILD_$1=0
 597  AC_SUBST(BUILD_$1)
 598  echo "AC_HELP_STRING([disabled],[$1])"
 599 ])
 600 AC_DEFUN([PKG_SHARED],[
 601  BUILD_$1=0
 602  AC_SUBST(BUILD_$1)
 603  SHARED_LIBS+="$SHARED_$1"
 604  echo "AC_HELP_STRING([shared],[$1])"
 605 ])
 606 AC_DEFUN([PKG_STATIC],[
 607  PKG_$1="yes"
 608  BUILD_$1=1
 609  AC_SUBST(BUILD_$1)
 610  STATIC_BLDS+=" [$1]"
 611  echo "AC_HELP_STRING([$2],[$1])"
 612 ])
 613 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 614
 615 # order matters
 616 for dep in \
 617         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 618         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 ffmpeg/fdk \
 619         libiec61883/libraw1394 libavc1394/librom1394 \
 620         openexr/ilmbase ilmbase/libogg \
 621         libtheora/libogg libtheora/libvorbis ; do
 622   lib=`dirname $dep`;  needs=`basename $dep`
 623   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 624   if test "x$pkg_lib" != "xno"; then
 625     eval "PKG_$needs=yes"
 626   fi
 627 done
 628
 629 AC_DEFUN([PKG_PROVIDE],[
 630 if test "x$BUILD_$1" = "x" ; then
 631  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 632   PKG_DISABLED([$1])
 633  elif test "x$PKG_$1" = "xyes"; then
 634   PKG_FORCED([$1])
 635  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 636   PKG_STATIC([$1],[static])
 637  elif test "x$HAVE_$1" = "xyes"; then
 638   PKG_SHARED([$1])
 639  else
 640   PKG_STATIC([$1],[needed])
 641  fi
 642 fi
 643 ])
 644
 645 PKG_PROVIDE([a52dec])
 646 PKG_PROVIDE([djbfft])
 647 PKG_PROVIDE([encore])
 648 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 649 PKG_PROVIDE([esound],[$WANT_ESOUND])
 650 PKG_PROVIDE([fdk])
 651 PKG_PROVIDE([ffmpeg])
 652 PKG_PROVIDE([fftw])
 653 PKG_PROVIDE([flac])
 654 PKG_PROVIDE([giflib])
 655 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 656 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 657 PKG_PROVIDE([lame])
 658 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 659 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 660 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 661 PKG_PROVIDE([libdv],[$WANT_DV])
 662 PKG_PROVIDE([libjpeg])
 663 PKG_PROVIDE([libogg])
 664 PKG_PROVIDE([libsndfile])
 665 PKG_PROVIDE([libtheora])
 666 PKG_PROVIDE([libuuid])
 667 PKG_PROVIDE([libvorbis])
 668 PKG_PROVIDE([mjpegtools])
 669 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 670 PKG_PROVIDE([openjpeg])
 671 PKG_PROVIDE([tiff])
 672 PKG_PROVIDE([twolame])
 673 PKG_PROVIDE([x264])
 674 PKG_PROVIDE([x265])
 675 PKG_PROVIDE([libvpx])
 676 PKG_PROVIDE([opus], [$WANT_OPUS])
 677
 678 AC_SUBST(STATIC_BLDS)
 679 AC_SUBST(SHARED_LIBS)
 680
 681 for f in $SYSTEM_LIBS; do
 682   echo "AC_HELP_STRING([system],[$f])"
 683 done
 684 AC_SUBST(SYSTEM_LIBS)
 685
 686 echo ""
 687 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 688          VIDEO4LINUX2 ESOUND PACTL OPENEXR; do
 689   eval vv="\$WANT_$v"
 690   if test "x$vv" != "xno"; then
 691     CFG_CFLAGS+=" -DHAVE_$v"
 692     vv=with
 693   else
 694     vv=without
 695   fi
 696   v=`echo "$v" | tr "A-Z" "a-z"`
 697   echo "  using: $vv-$v"
 698 done
 699
 700 echo "  using: with-jobs = $WANT_JOBS"
 701 echo "  using: exec-name = $WANT_CIN"
 702 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 703 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 704 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 705 echo "  using: with-browser = $WANT_CIN_BROWSER"
 706 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 707 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 708 echo "  using: with-opencv = $WANT_OPENCV"
 709 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 710 echo ""
 711 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 712 echo "  using: static-build = $WANT_STATIC_BUILD"
 713 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 714 echo ""
 715
 716 # build extras
 717 if test "x$HAVE_tiff" = "xyes"; then
 718   if test "x$HAVE_jbig" = "xyes"; then
 719     EXTRA_LIBS+=' -ljbig'
 720   fi
 721 fi
 722 if test "x$HAVE_NUMA" = "xyes"; then
 723   EXTRA_LIBS+=' -lnuma'
 724 fi
 725 if test "x$HAVE_DL" = "xyes"; then
 726   EXTRA_LIBS+=' -ldl'
 727   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 728 fi
 729 if test "x$HAVE_opus" = "xyes"; then
 730   EXTRA_LIBS+=' -lopus'
 731   CFG_CFLAGS+=' -I/usr/include/opus'
 732   FFMPEG_EXTRA_CFG+=' --enable-libopus'
 733 fi
 734
 735 AC_SUBST(EXTRA_LIBS)
 736 AC_SUBST(FFMPEG_EXTRA_CFG)
 737 AC_SUBST(WANT_X264_HIDEPTH)
 738 AC_SUBST(WANT_X265_HIDEPTH)
 739
 740 AC_SUBST(CFG_CFLAGS)
 741 AC_SUBST(CFG_CXXFLAGS)
 742
 743 AC_CONFIG_FILES([Makefile])
 744 AC_OUTPUT
 745
 746 exec > global_config
 747
 748 echo "SHELL := /bin/bash"
 749 echo "export SHELL"
 750 echo "WANT_JOBS := $WANT_JOBS"
 751 echo ""
 752 echo "OBJDIR := $OBJDIR"
 753 echo "BINDIR := \$(TOPDIR)/bin"
 754 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 755 echo "GUICAST := \$(TOPDIR)/guicast"
 756 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 757 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 758 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 759 echo "PLUGINS := \$(TOPDIR)/plugins"
 760 echo "TDB := \$(TOPDIR)/db"
 761 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 762 echo "EXTRA_LIBS := $EXTRA_LIBS"
 763 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 764 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 765 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 766 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 767 echo ""
 768
 769 echo "WANT_CIN := $WANT_CIN"
 770 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 771 echo ""
 772
 773 echo "ifndef CFLAGS_"
 774 echo "ifdef CFLAGS"
 775 echo "CFLAGS_ := \$(CFLAGS)"
 776 echo "else"
 777 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 778 echo "endif"
 779 echo "endif"
 780
 781 echo "CFLAGS := \$(CFLAGS_)"
 782 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 783 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 784 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 785 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 786 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 787 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 788 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 789 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 790 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 791 echo ""
 792 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 793 echo ""
 794
 795 if test  $WANT_X264_HIDEPTH = "yes" ; then
 796   echo "x264.cfg_params := --enable-static --bit-depth=10"
 797 fi
 798 if test  $WANT_X265_HIDEPTH = "yes" ; then
 799   echo "x265.cfg_params := -DENABLE_SHARED=no -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
 800 fi
 801
 802 for pkg in $STATIC_PKGS; do
 803   eval pkg_lib="\$PKG_$pkg"
 804   if test "x$pkg_lib" = "xno"; then continue; fi;
 805   echo "static_pkgs += $pkg"
 806 done
 807 echo ""
 808
 809 for pkg in $STATIC_BLDS; do
 810   echo "static_blds += $pkg"
 811   ver_pkg=ver_$pkg
 812   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 813   inc_pkg=inc_$pkg
 814   echo "$inc_pkg := \\"
 815   for inc in ${!inc_pkg}; do
 816     echo "  -I\$($ver_pkg)/$inc \\"
 817   done
 818   echo ""
 819   echo "static_incs += \$(inc_$pkg)"
 820   lib_pkg=lib_$pkg
 821   echo "$lib_pkg := \\"
 822   for lib in ${!lib_pkg}; do
 823     echo "  \$($ver_pkg)/$lib \\"
 824   done
 825   echo ""
 826   echo "static_libs += \$($lib_pkg)"
 827   echo ""
 828 done
 829 echo ""
 830
 831 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 832 echo ""
 833 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 834 echo "export static_pkgs static_blds shared_libs system_libs"
 835 echo ""
 836
 837 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 838 echo "libraries += -Wl,--start-group"
 839 echo "libraries += \$(thirdparty_libraries)"
 840 echo "libraries += \$(system_libs)"
 841 echo "libraries += \$(EXTRA_LIBS)"
 842 echo "libraries += -Wl,--end-group"
 843 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 844 echo "libraries += \$(thirdparty_libraries)"
 845 echo "libraries += \$(system_libs)"
 846 echo "libraries += \$(EXTRA_LIBS)"
 847 echo ""
 848 echo "export thirdparty_libraries libraries"
 849 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 850 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
 851
 852 if test "x$HAVE_tiff" = "xyes"; then
 853   if test "x$HAVE_jbig" != "xyes"; then
 854     echo "tiff.cfg_params+= --disable-jbig"
 855   fi
 856 fi
 857
 858 if test "x$WANT_GIT_FFMPEG" != "xno"; then
 859 echo "ffmpeg.git := $WANT_GIT_FFMPEG"
 860 fi
 861 if test "x$HAVE_opus" = "xyes"; then
 862 echo 'ffmpeg.cflags+=" -I/usr/include/opus"'
 863 fi