cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 CFG_CFLAGS+=" -Wno-unused-result"
  15 CFG_CFLAGS+=" -Wno-stringop-overflow"
  16 CFG_CFLAGS+=" -Wno-format-truncation"
  17 CFG_CFLAGS+=" -Wno-format-overflow"
  18 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  19 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  20 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  21 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  22 CFG_CFLAGS+=" -I/usr/include/freetype2"
  23
  24 AC_DEFUN([CHECK_WITH], [
  25 AC_ARG_WITH([$1],
  26   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  27   [WANT_$3=$withval], [WANT_$3='$4'])
  28 AC_SUBST([WANT_$3])
  29 ])
  30
  31 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  32 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  33 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  34 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  35 CHECK_WITH([lv2],[lv2 library support],[LV2],[yes])
  36 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  37 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  38 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  39 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  40 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  41 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  42 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  43
  44 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  45   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  46   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  47   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  48   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  49   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  50   sinstall=dinstall
  51   suninstall=duninstall
  52 else
  53   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  54     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  55     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  56     echo "$dir"`
  57   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  58     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  59     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  60     echo "$dir"`
  61   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  62     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  63     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  64     echo "$dir"`
  65   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  66        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  67   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  68     usrlib+="64"
  69   WANT_LOCALE_DIR="$lcldir"
  70   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  71   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  72   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  73   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  74   sinstall=cinstall
  75   suninstall=cuninstall
  76 fi
  77 AC_SUBST(sinstall)
  78 AC_SUBST(suninstall)
  79
  80 if test "x$WANT_JOBS" = "xauto"; then
  81   CPUS=`grep -c "^proc" /proc/cpuinfo`
  82   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  83 fi
  84
  85 AC_DEFUN([PKG_DEF],[
  86 STATIC_PKGS+=" [$1]"
  87 ver_$1="$2"
  88 lib_$1="$3"
  89 inc_$1="$4"
  90 ])
  91
  92 AC_DEFUN([PKG_3RD],[
  93 AC_ARG_ENABLE([$1],
  94   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  95   [PKG_$1=$enableval], [PKG_$1=$2])
  96 PKG_DEF([$1],[$3],[$4],[$5])
  97 ])
  98
  99 # thirdparty builds
 100
 101 PKG_3RD([a52dec],[yes],
 102   [a52dec-0.7.4],
 103   [ liba52/.libs/liba52.a ],
 104   [ include ])
 105
 106 PKG_3RD([djbfft],[yes],
 107   [djbfft-0.76],
 108   [ libdjbfft.a ],
 109   [ . ])
 110
 111 PKG_3RD([audiofile],[no],
 112   [audiofile-0.3.6],
 113   [ libaudiofile/.libs/libaudiofile.a \
 114     libaudiofile/modules/.libs/libmodules.a \
 115     libaudiofile/alac/.libs/libalac.a ],
 116   [ libaudiofile ])
 117
 118 PKG_3RD([encore],[no],
 119   [encore-5.0],
 120   [ \$(OBJDIR)/libencore.a ],
 121   [ . ])
 122
 123 PKG_3RD([esound],[no],
 124   [esound-0.2.41],
 125   [ .libs/libesd.a \
 126     .libs/libesddsp.a ],
 127   [ . ])
 128
 129 PKG_3RD([fdk],[auto],
 130   [fdk-aac-0.1.5],
 131   [ .libs/libfdk-aac.a ],
 132   [ libAACdec/include libAACenc/include libSYS/include ])
 133
 134 PKG_3RD([ffmpeg],[yes],
 135   [ffmpeg-4.0],
 136   [ libavutil/libavutil.a \
 137     libavcodec/libavcodec.a \
 138     libpostproc/libpostproc.a \
 139     libavdevice/libavdevice.a \
 140     libavformat/libavformat.a \
 141     libswscale/libswscale.a \
 142     libavfilter/libavfilter.a \
 143     libswresample/libswresample.a ],
 144   [ . ])
 145
 146 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 147   ver_ffmpeg="ffmpeg.git"
 148 fi
 149
 150 PKG_3RD([fftw],[auto],
 151   [fftw-3.3.7],
 152   [ .libs/libfftw3.a \
 153     libbench2/libbench2.a \
 154     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 155     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 156     rdft/scalar/.libs/librdft_scalar.a \
 157     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 158     rdft/.libs/librdft.a \
 159     api/.libs/libapi.a \
 160     reodft/.libs/libreodft.a \
 161     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 162     dft/scalar/.libs/libdft_scalar.a \
 163     dft/.libs/libdft.a \
 164     kernel/.libs/libkernel.a \
 165     simd-support/.libs/libsimd_support.a ],
 166   [ api ])
 167
 168 PKG_3RD([flac],[auto],
 169   [flac-1.3.2],
 170   [ src/libFLAC/.libs/libFLAC.a \
 171     src/libFLAC++/.libs/libFLAC++.a \
 172     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 173     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 174     src/share/grabbag/.libs/libgrabbag.a \
 175     src/share/utf8/.libs/libutf8.a \
 176     src/test_libs_common/.libs/libtest_libs_common.a ],
 177   [ include ])
 178
 179 PKG_3RD([giflib],[yes],
 180   [giflib-5.1.4],
 181   [ lib/.libs/libgif.a \
 182     util/libgetarg.a ],
 183   [ lib ])
 184
 185 PKG_3RD([ilmbase],[auto],
 186   [ilmbase-2.2.1],
 187   [ Iex/.libs/libIex.a \
 188     IexMath/.libs/libIexMath.a \
 189     Half/.libs/libHalf.a \
 190     Imath/.libs/libImath.a \
 191     IlmThread/.libs/libIlmThread.a ],
 192   [ Iex Half Imath config IlmThread ])
 193
 194 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 195
 196 PKG_3RD([lame],[auto],
 197   [lame-3.100],
 198   [ libmp3lame/.libs/libmp3lame.a \
 199     mpglib/.libs/libmpgdecoder.a ],
 200   [ include ])
 201
 202 PKG_3RD([libavc1394],[auto],
 203   [libavc1394-0.5.4],
 204   [ libavc1394/.libs/libavc1394.a \
 205     librom1394/.libs/librom1394.a \
 206     common/.libs/libraw1394util.a ],
 207   [ . ])
 208
 209 PKG_3RD([libraw1394],[auto],
 210   [libraw1394-2.1.2],
 211   [ src/.libs/libraw1394.a ],
 212   [ . ])
 213
 214 PKG_3RD([libiec61883],[auto],
 215   [libiec61883-1.2.0],
 216   [ src/.libs/libiec61883.a ],
 217   [ src ])
 218
 219 PKG_3RD([libdv],[auto],
 220   [libdv-1.0.0],
 221   [ libdv/.libs/libdv.a ],
 222   [ . ])
 223
 224 PKG_3RD([libjpeg],[auto],
 225   [libjpeg-turbo-1.5.1],
 226   [ .libs/libjpeg.a \
 227     .libs/libturbojpeg.a \
 228     simd/.libs/libsimd.a ],
 229   [ . ])
 230
 231 PKG_3RD([opus],[auto],
 232   [opus-1.2.1],
 233   [ .libs/libopus.a ],
 234   [ include ])
 235
 236 PKG_3RD([openjpeg],[auto],
 237   [openjpeg-2.1.0-20160221],
 238   [ bin/libopenjp2.a ],
 239   [ src/lib/openjp2 ])
 240
 241 PKG_3RD([libogg],[auto],
 242   [libogg-1.3.2],
 243   [ src/.libs/libogg.a ],
 244   [ include ])
 245
 246 PKG_3RD([libsndfile],[auto],
 247   [libsndfile-1.0.28],
 248   [ src/.libs/libsndfile.a \
 249     src/.libs/libcommon.a \
 250     src/G72x/.libs/libg72x.a \
 251     src/GSM610/.libs/libgsm.a ],
 252   [ . ])
 253
 254 PKG_3RD([libtheora],[auto],
 255   [libtheora-1.1.1],
 256   [ lib/.libs/libtheora.a \
 257     lib/.libs/libtheoradec.a \
 258     lib/.libs/libtheoraenc.a ],
 259   [ . ])
 260
 261 PKG_3RD([libuuid],[yes],
 262   [libuuid-1.0.3],
 263   [ .libs/libuuid.a ],
 264   [ . ])
 265
 266 PKG_3RD([libvorbis],[auto],
 267   [libvorbis-1.3.5],
 268   [ lib/.libs/libvorbis.a \
 269     lib/.libs/libvorbisenc.a \
 270     lib/.libs/libvorbisfile.a ],
 271   [ include . ])
 272
 273 PKG_3RD([mjpegtools],[yes],
 274   [mjpegtools-2.1.0],
 275   [ utils/mmxsse/.libs/libmmxsse.a \
 276     utils/.libs/libmjpegutils.a \
 277     lavtools/.libs/liblavfile.a \
 278     lavtools/.libs/liblavjpeg.a \
 279     mplex/.libs/libmplex2.a \
 280     yuvfilters/.libs/libyuvfilters.a \
 281     mpeg2enc/.libs/libmpeg2encpp.a ],
 282   [ .  lavtools utils ])
 283
 284 PKG_3RD([openexr],[auto],
 285   [openexr-2.2.1],
 286   [ IlmImf/.libs/libIlmImf.a \
 287     IlmImfUtil/.libs/libIlmImfUtil.a ],
 288   [ IlmImf config ])
 289
 290 #PKG_3RD([festival],[no],
 291 #  [festival],
 292 #  [],
 293 #  [])
 294 #PKG_3RD(speech_tools,[no],
 295 #  [speech_tools],
 296 #  [],
 297 #  [])
 298 #
 299 PKG_3RD([tiff],[auto],
 300   [tiff-4.0.9],
 301   [ libtiff/.libs/libtiff.a \
 302     libtiff/.libs/libtiffxx.a \
 303     port/.libs/libport.a ],[
 304    . ])
 305
 306 PKG_3RD([twolame],[auto],
 307   [twolame-0.3.13],
 308   [ libtwolame/.libs/libtwolame.a ],
 309   [  libtwolame ])
 310
 311 PKG_3RD([x264],[auto],
 312   [x264-snapshot-20180118-2245],
 313   [ libx264.a ],
 314   [ . ])
 315
 316 PKG_3RD([x265],[auto],
 317   [x265_2.7],
 318   [ libx265.a ],
 319   [ . source ])
 320
 321 PKG_3RD([libvpx],[auto],
 322   [libvpx-1.7.0],
 323   [ libvpx.a ],
 324   [ . ])
 325
 326 AC_SUBST(STATIC_PKGS)
 327
 328 AC_DEFUN([CHECK_ENABLE], [
 329 AC_ARG_ENABLE([$1],
 330   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 331   [WANT_$2=$enableval], [WANT_$2=[$4]])
 332 ])
 333
 334 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 335 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 336
 337 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 338
 339 AC_DEFUN([CHECK_PROG], [
 340  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 341 ])
 342 AC_DEFUN([REQUIRE_PROG], [
 343  CHECK_PROG([$1],[$2])
 344  if test "x$PROG_$1" = "xno"; then
 345    AC_MSG_WARN([$2 is missing and required.])
 346    FATAL_ERROR=1
 347  fi
 348 ])
 349
 350 # Checks for programs.
 351
 352 REQUIRE_PROG(NASM, [nasm])
 353 REQUIRE_PROG(YASM, [yasm])
 354 REQUIRE_PROG(OBJCOPY, [objcopy])
 355 if test "x$FATAL_ERROR" != "x"; then
 356  AC_MSG_ERROR("fatal eror.")
 357 fi
 358 CHECK_PROG(PACTL, [pactl])
 359 WANT_PACTL=$PROG_PACTL
 360
 361 # libx264 nasm fix
 362 AC_MSG_CHECKING([nasm x264 compatible])
 363 echo "vmovdqa32 [[eax]]{k1}{z}, zmm0" > conftest.asm
 364 nasm conftest.asm -o conftest.o > /dev/null 2>&1
 365 if test $? != 0 ; then
 366  AC_MSG_RESULT([no])
 367  AC_MSG_WARN([libx264 built without assembly code])
 368  X264_CFG_PARAMS="$X264_CFG_PARAMS --disable-asm"
 369 else
 370  AC_MSG_RESULT([yes])
 371 fi
 372 rm -f conftest.asm conftest.o
 373
 374 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 375 if test "$no_utf" = "yes"; then
 376   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 377 fi
 378
 379 # Checks for headers/libraries.
 380
 381 AC_DEFUN([CHECK_HEADERS], [
 382 if test "x$HAVE_$1" != "xno"; then
 383  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 384   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 385 ]])])
 386  AC_SUBST([HAVE_$1])
 387  AC_MSG_CHECKING([$2])
 388  AC_MSG_RESULT([$HAVE_$1])
 389  if test "x$HAVE_$1" = "xno"; then
 390   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 391  fi
 392 fi
 393 ])
 394
 395 AC_DEFUN([CHECK_LIB], [
 396 if test "x$HAVE_$1" != "xno"; then
 397  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 398   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 399   AC_SUBST([HAVE_$1])
 400   if test "x$HAVE_$1" = "xyes"; then
 401    if test "x$PKG_$1" = "x"; then
 402     SYSTEM_LIBS+=" -l[$2]"
 403     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 404    else
 405     SHARED_$1+=" -l[$2]"
 406     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 407    fi
 408   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 409  fi
 410 fi
 411 ])
 412
 413 CHECK_LIB([X11], [X11], [XOpenDisplay])
 414 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 415 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 416 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 417 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 418 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 419 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 420 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 421 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 422 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 423 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 424 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 425 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 426 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 427 CHECK_LIB([PNG], [png], [png_read_png])
 428 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 429 CHECK_LIB([Z], [z], [gzopen])
 430 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 431 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 432 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 433 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 434 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 435 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 436 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 437 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 438 CHECK_LIB([lame], [mp3lame], [lame_init])
 439 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 440 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 441 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 442 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 443 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 444 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 445 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 446 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 447 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 448 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 449 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 450 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 451 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 452 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 453 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 454 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 455 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 456 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 457 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 458 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 459 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 460 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 461 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 462 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 463 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 464 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 465 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 466 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 467 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 468 CHECK_LIB([a52dec], [a52], [a52_init])
 469 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 470 CHECK_LIB([encore], [encore], [encore])
 471 CHECK_HEADERS([encore], [encore headers], [encore.h])
 472 CHECK_LIB([giflib], [gif], [DGifOpen])
 473 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 474 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 475 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 476 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 477 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 478
 479 #if test "x$HAVE_mjpegtools" = "xyes"; then
 480 #CFG_CFLAGS+=" -I/usr/include/mjpegtools"
 481 #fi
 482
 483 AC_DEFUN([CHECK_WANT], [
 484 RESULT=yes
 485 AC_ARG_WITH(m4_tolower([$1]),
 486  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 487   [WANT_$1=$withval],[WANT_$1=$2])
 488 # WANT_$1
 489 if test "x$WANT_$1" != "xno" ; then
 490  m4_quote($4)
 491  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 492   echo "=== want $1 Failed."
 493   WANT_$1=no
 494  elif test "x$WANT_$1" = "xauto" ; then
 495   WANT_$1=yes
 496  fi
 497 fi
 498 CFG_WANTS+=" $1"
 499 AC_SUBST([WANT_$1])
 500 ])
 501
 502 CHECK_WANT([GL], [auto], [use opengl], [
 503  CHECK_LIB([GL], [GL], [glUseProgram])
 504  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 505  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 506
 507 CHECK_WANT([OSS], [auto], [use OSS audio], [
 508  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 509
 510 CHECK_WANT([XFT], [auto], [use libXft], [
 511  CHECK_LIB([XFT], [Xft], [XftInit])
 512  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 513
 514 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 515  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 516  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 517
 518 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 519  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 520  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 521  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 522  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 523  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 524  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 525  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 526  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 527
 528 CHECK_WANT([DV], [auto], [use dv], [
 529  CHECK_LIB([libdv], [dv], [dv_init])
 530  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 531
 532 CHECK_WANT([DVB], [auto], [use dvb], [
 533  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 534
 535 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 536  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 537
 538 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 539  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 540
 541 CHECK_WANT([ESOUND], [no], [use esd], [
 542  CHECK_LIB([esound], [esd], [esd_open_sound])
 543  CHECK_HEADERS([esound], [esound headers], [esd.h])
 544  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 545  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 546
 547 CHECK_WANT([LIBOPUS], [auto], [use libopus], [
 548  CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 549  CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])])
 550
 551 CHECK_WANT([LV2], [auto], [use lv2], [
 552  CHECK_LIB([lv2], [lilv-0], [lilv_world_new])
 553  CHECK_LIB([sord], [sord-0], [sord_world_new])
 554  CHECK_LIB([serd], [serd-0], [serd_reader_new])
 555  CHECK_LIB([sratom], [sratom-0], [sratom_new])
 556  saved_CFLAGS="$CXXFLAGS"
 557  CFLAGS="-I/usr/include/lilv-0"
 558  CHECK_HEADERS([lv2], [lilv headers], [lilv/lilv.h])
 559  CFLAGS="$saved_CXXFLAGS"])
 560
 561 CHECK_WANT([DL], [auto], [system has libdl], [
 562  CHECK_LIB([DL], [dl], [dlopen])])
 563
 564 CHECK_WANT([EXR], [auto], [use exr], [])
 565 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 566  WANT_OPENCV="$withval"
 567 ])
 568
 569 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 570  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 571
 572 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 573  AC_MSG_CHECKING([for openexr available])
 574  saved_LIBS="$LIBS"
 575  saved_CXXFLAGS="$CXXFLAGS"
 576  # ilmbase libs
 577  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 578  CXXFLAGS="-I/usr/include/OpenEXR"
 579  AC_LANG_PUSH(C++)
 580  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 581 #include "ImfChannelList.h"
 582 #include "ImfChromaticities.h"
 583 #include "ImfCompression.h"
 584 #include "ImfIO.h"
 585 #include "ImfInputFile.h"
 586 #include "ImfOutputFile.h"
 587 #include "ImfPixelType.h"
 588 #include "ImfRgbaFile.h"
 589 #include "ImfRgbaYca.h"
 590 #include "ImfVersion.h"
 591 class EXRIStream : public Imf::IStream { public:
 592 EXRIStream() : Imf::IStream("mypath") {} };
 593 class EXROStream : public Imf::OStream { public:
 594 EXROStream() : Imf::OStream("mypath") {} };
 595 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 596  RESULT="$HAVE_OPENEXR"
 597  if test "x$RESULT" = "xyes"; then
 598    SHARED_openexr="$LIBS"
 599    CFG_CFLAGS+=" -I/usr/include/OpenEXR"
 600  fi
 601  LIBS="$saved_LIBS"
 602  CXXFLAGS="$saved_CXXFLAGS"
 603  AC_LANG_POP(C++)
 604  AC_MSG_RESULT([$HAVE_OPENEXR])
 605 ])
 606 AC_SUBST([HAVE_OPENEXR])
 607
 608 # build global_config
 609 OBJDIR=`uname -m`
 610 AC_SUBST(OBJDIR)
 611
 612 echo "AC_HELP_STRING([Reason],[Package])"
 613 echo "AC_HELP_STRING([------],[-------])"
 614
 615 AC_DEFUN([PKG_DISABLED],[
 616  PKG_$1="no"
 617  BUILD_$1=0
 618  AC_SUBST(BUILD_$1)
 619  echo "AC_HELP_STRING([disabled],[$1])"
 620 ])
 621 AC_DEFUN([PKG_SHARED],[
 622  BUILD_$1=0
 623  AC_SUBST(BUILD_$1)
 624  SHARED_LIBS+="$SHARED_$1"
 625  echo "AC_HELP_STRING([shared],[$1])"
 626 ])
 627 AC_DEFUN([PKG_STATIC],[
 628  PKG_$1="yes"
 629  BUILD_$1=1
 630  AC_SUBST(BUILD_$1)
 631  STATIC_BLDS+=" [$1]"
 632  echo "AC_HELP_STRING([$2],[$1])"
 633 ])
 634 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 635
 636 # order matters
 637 for dep in \
 638         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 639         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 ffmpeg/fdk \
 640         libiec61883/libraw1394 libavc1394/librom1394 \
 641         openexr/ilmbase ilmbase/libogg \
 642         libtheora/libogg libtheora/libvorbis ; do
 643   lib=`dirname $dep`;  needs=`basename $dep`
 644   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 645   if test "x$pkg_lib" != "xno"; then
 646     eval "PKG_$needs=yes"
 647   fi
 648 done
 649
 650 AC_DEFUN([PKG_PROVIDE],[
 651 if test "x$BUILD_$1" = "x" ; then
 652  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 653   PKG_DISABLED([$1])
 654  elif test "x$PKG_$1" = "xyes"; then
 655   PKG_FORCED([$1])
 656  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 657   PKG_STATIC([$1],[static])
 658  elif test "x$HAVE_$1" = "xyes"; then
 659   PKG_SHARED([$1])
 660  else
 661   PKG_STATIC([$1],[needed])
 662  fi
 663 fi
 664 ])
 665
 666 PKG_PROVIDE([a52dec])
 667 PKG_PROVIDE([djbfft])
 668 PKG_PROVIDE([encore])
 669 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 670 PKG_PROVIDE([esound],[$WANT_ESOUND])
 671 PKG_PROVIDE([fdk])
 672 PKG_PROVIDE([ffmpeg])
 673 PKG_PROVIDE([fftw])
 674 PKG_PROVIDE([flac])
 675 PKG_PROVIDE([giflib])
 676 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 677 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 678 PKG_PROVIDE([lame])
 679 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 680 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 681 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 682 PKG_PROVIDE([libdv],[$WANT_DV])
 683 PKG_PROVIDE([libjpeg])
 684 PKG_PROVIDE([libogg])
 685 PKG_PROVIDE([libsndfile])
 686 PKG_PROVIDE([libtheora])
 687 PKG_PROVIDE([libuuid])
 688 PKG_PROVIDE([libvorbis])
 689 PKG_PROVIDE([mjpegtools])
 690 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 691 PKG_PROVIDE([openjpeg])
 692 PKG_PROVIDE([tiff])
 693 PKG_PROVIDE([twolame])
 694 PKG_PROVIDE([x264])
 695 PKG_PROVIDE([x265])
 696 PKG_PROVIDE([libvpx])
 697 PKG_PROVIDE([opus], [$WANT_OPUS])
 698
 699 AC_SUBST(STATIC_BLDS)
 700 AC_SUBST(SHARED_LIBS)
 701
 702 for f in $SYSTEM_LIBS; do
 703   echo "AC_HELP_STRING([system],[$f])"
 704 done
 705 AC_SUBST(SYSTEM_LIBS)
 706
 707 echo ""
 708 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 709          VIDEO4LINUX2 ESOUND PACTL OPENEXR LV2; do
 710   eval vv="\$WANT_$v"
 711   if test "x$vv" != "xno"; then
 712     CFG_CFLAGS+=" -DHAVE_$v"
 713     vv=with
 714   else
 715     vv=without
 716   fi
 717   v=`echo "$v" | tr "A-Z" "a-z"`
 718   echo "  using: $vv-$v"
 719 done
 720
 721 echo "  using: with-jobs = $WANT_JOBS"
 722 echo "  using: exec-name = $WANT_CIN"
 723 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 724 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 725 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 726 echo "  using: with-browser = $WANT_CIN_BROWSER"
 727 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 728 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 729 echo "  using: with-opencv = $WANT_OPENCV"
 730 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 731 echo ""
 732 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 733 echo "  using: static-build = $WANT_STATIC_BUILD"
 734 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 735 echo ""
 736
 737 # build extras
 738 if test "x$HAVE_tiff" = "xyes"; then
 739   if test "x$HAVE_jbig" = "xyes"; then
 740     EXTRA_LIBS+=' -ljbig'
 741   fi
 742 fi
 743 if test "x$HAVE_NUMA" = "xyes"; then
 744   EXTRA_LIBS+=' -lnuma'
 745 fi
 746 if test "x$HAVE_DL" = "xyes"; then
 747   EXTRA_LIBS+=' -ldl'
 748   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 749 fi
 750 if test "x$HAVE_opus" = "xyes"; then
 751   EXTRA_LIBS+=' -lopus'
 752   CFG_CFLAGS+=' -I/usr/include/opus'
 753   FFMPEG_EXTRA_CFG+=' --enable-libopus'
 754 fi
 755 if test "x$HAVE_lv2" = "xyes"; then
 756   CFG_CFLAGS+=' -I/usr/include/lilv-0'
 757 fi
 758
 759 AC_SUBST(EXTRA_LIBS)
 760 AC_SUBST(FFMPEG_EXTRA_CFG)
 761 AC_SUBST(WANT_X264_HIDEPTH)
 762
 763 AC_SUBST(CFG_CFLAGS)
 764 AC_SUBST(CFG_CXXFLAGS)
 765
 766 AC_CONFIG_FILES([Makefile])
 767 AC_OUTPUT
 768
 769 exec > global_config
 770
 771 echo "SHELL := /bin/bash"
 772 echo "export SHELL"
 773 echo "WANT_JOBS := $WANT_JOBS"
 774 echo ""
 775 echo "OBJDIR := $OBJDIR"
 776 echo "BINDIR := \$(TOPDIR)/bin"
 777 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 778 echo "GUICAST := \$(TOPDIR)/guicast"
 779 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 780 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 781 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 782 echo "PLUGINS := \$(TOPDIR)/plugins"
 783 echo "TDB := \$(TOPDIR)/db"
 784 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 785 echo "EXTRA_LIBS := $EXTRA_LIBS"
 786 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 787 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 788 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 789 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 790 echo ""
 791
 792 echo "WANT_CIN := $WANT_CIN"
 793 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 794 echo ""
 795
 796 echo "ifndef CFLAGS_"
 797 echo "ifdef CFLAGS"
 798 echo "CFLAGS_ := \$(CFLAGS)"
 799 echo "else"
 800 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 801 echo "endif"
 802 echo "endif"
 803
 804 echo "CFLAGS := \$(CFLAGS_)"
 805 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 806 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 807 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 808 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 809 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 810 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 811 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 812 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 813 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 814 echo ""
 815 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 816 echo ""
 817
 818 if test  $WANT_X264_HIDEPTH = "yes" ; then
 819   X264_CFG_PARAMS="$X264_CFG_PARAMS --bit-depth=10"
 820 fi
 821
 822 for pkg in $STATIC_PKGS; do
 823   eval pkg_lib="\$PKG_$pkg"
 824   if test "x$pkg_lib" = "xno"; then continue; fi;
 825   echo "static_pkgs += $pkg"
 826 done
 827 echo ""
 828
 829 for pkg in $STATIC_BLDS; do
 830   echo "static_blds += $pkg"
 831   ver_pkg=ver_$pkg
 832   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 833   inc_pkg=inc_$pkg
 834   echo "$inc_pkg := \\"
 835   for inc in ${!inc_pkg}; do
 836     echo "  -I\$($ver_pkg)/$inc \\"
 837   done
 838   echo ""
 839   echo "static_incs += \$(inc_$pkg)"
 840   lib_pkg=lib_$pkg
 841   echo "$lib_pkg := \\"
 842   for lib in ${!lib_pkg}; do
 843     echo "  \$($ver_pkg)/$lib \\"
 844   done
 845   echo ""
 846   echo "static_libs += \$($lib_pkg)"
 847   echo ""
 848 done
 849 echo ""
 850
 851 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 852 echo ""
 853 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 854 echo "export static_pkgs static_blds shared_libs system_libs"
 855 echo ""
 856
 857 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 858 echo "libraries += -Wl,--start-group"
 859 echo "libraries += \$(thirdparty_libraries)"
 860 echo "libraries += \$(system_libs)"
 861 echo "libraries += \$(EXTRA_LIBS)"
 862 echo "libraries += -Wl,--end-group"
 863 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 864 echo "libraries += \$(thirdparty_libraries)"
 865 echo "libraries += \$(system_libs)"
 866 echo "libraries += \$(EXTRA_LIBS)"
 867 echo ""
 868 echo "export thirdparty_libraries libraries"
 869 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 870 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
 871
 872 if test "x$HAVE_tiff" = "xyes"; then
 873   if test "x$HAVE_jbig" != "xyes"; then
 874     echo "tiff.cfg_params+= --disable-jbig"
 875   fi
 876 fi
 877
 878 if test "x$WANT_GIT_FFMPEG" != "xno"; then
 879 echo "ffmpeg.git := $WANT_GIT_FFMPEG"
 880 fi
 881 if test "x$HAVE_opus" = "xyes"; then
 882 echo 'ffmpeg.cflags+=" -I/usr/include/opus"'
 883 fi
 884 if test "x$X264_CFG_PARAMS" != "x" ; then
 885   echo "x264.cfg_params :=$X264_CFG_PARAMS --enable-static --enable-pic"
 886 fi