cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-gg.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 #  this is extra work, not a gain...
  15 CFG_CFLAGS+=" -Wno-unknown-warning-option"
  16 CFG_CFLAGS+=" -Wno-attributes"
  17 CFG_CFLAGS+=" -Wno-unused-result"
  18 CFG_CFLAGS+=" -Wno-stringop-overflow"
  19 CFG_CFLAGS+=" -Wno-format-truncation"
  20 CFG_CFLAGS+=" -Wno-format-overflow"
  21 CFG_CFLAGS+=" -Wno-parentheses"
  22 CFG_CFLAGS+=" -Wno-stringop-truncation"
  23 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  24 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  25 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  26 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  27 CFG_CFLAGS+=" -I/usr/include -I/usr/local/include"
  28 CFG_CFLAGS+=" -I/usr/include/freetype2 -I/usr/local/include/freetype2"
  29 CFG_CFLAGS+=" -I/usr/include/uuid -I/usr/local/include/uuid"
  30 CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
  31
  32 AC_DEFUN([CHECK_WITH], [
  33 AC_ARG_WITH([$1],
  34   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  35   [WANT_$3=$withval], [WANT_$3='$4'])
  36 AC_SUBST([WANT_$3])
  37 ])
  38
  39 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  40 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  41 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  42 CHECK_WITH([lv2],[lv2 library support],[LV2],[yes])
  43 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  44 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  45 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  46 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  47 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  48 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  49 CHECK_WITH([nested-dir],[nested proxy dir],[NESTED_DIR],[$$HOME/Videos])
  50 CHECK_WITH([snap-dir],[snapshot/grabshot dir],[SNAP_DIR],[$$HOME/Pictures])
  51 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  52 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  53 CHECK_WITH([noelision],[use noelision/libpthread],[NOELISION],[auto])
  54 CHECK_WITH([booby],[window lock trace booby trap],[BOOBY],[no])
  55 CHECK_WITH([libzmpeg],[build libzmpeg],[LIBZMPEG],[yes])
  56 CHECK_WITH([commercial],[enable commercial capture],[COMMERCIAL],[yes])
  57 CHECK_WITH([thirdparty],[use thirdparty build],[CIN_3RDPARTY],[yes])
  58 CHECK_WITH([shuttle],[shuttle device],[SHUTTLE],[yes])
  59 CHECK_WITH([wintv],[usb 2040:826d wintv device],[WINTV],[yes])
  60 CHECK_WITH([x10tv],[usb 0bc7:0004 X10 remote device],[X10TV],[yes])
  61 CHECK_WITH([vaapi],[video acceleration api],[VAAPI],[yes])
  62 CHECK_WITH([vdpau],[video decode+presentation api for unix],[VDPAU],[yes])
  63 CHECK_WITH([nv],[nvenc/nvdec ffnvcodec api],[NV],[yes])
  64 CHECK_WITH([cuda],[nv cuda plugins],[CUDA],[auto])
  65 CHECK_WITH([clang],[use clang instead of gcc/g++],[CLANG],[no])
  66
  67 if test "x$WANT_LV2" != "xno"; then
  68   GTK2_LIBS=`pkg-config --libs gtk+-2.0`
  69   AC_CHECK_LIB([m], [gtk_init], [HAVE_gtk=yes], [HAVE_gtk=no], [$GTK2_LIBS])
  70   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --cflags gtk+-2.0`" && HAVE_gtk=no
  71   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --libs gtk+-2.0`" && HAVE_gtk=no
  72   if test "x$HAVE_gtk" = "xno"; then
  73     AC_MSG_ERROR([LV2 requires gtk+-2.0 support.])
  74   fi
  75 fi
  76
  77 if test "x$WANT_COMMERCIAL" = "xyes" -a "x$WANT_LIBZMPEG" != "xyes" ; then
  78   AC_MSG_ERROR([commercial requires libzmpeg support.])
  79 fi
  80
  81 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  82   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  83   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  84   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  85   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  86   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  87 else
  88   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  89     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  90     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  91     echo "$dir"`
  92   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  93     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  94     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  95     echo "$dir"`
  96   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  97     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  98     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  99     echo "$dir"`
 100   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
 101        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
 102   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
 103     usrlib+="64"
 104   WANT_LOCALE_DIR="$lcldir"
 105   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
 106   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
 107   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
 108   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
 109 fi
 110
 111 CIN_INSTALLS=""
 112 CIN_UNINSTALLS=""
 113 if test "x$WANT_LIBZMPEG" = "xyes"; then
 114   CIN_INSTALLS+=" zmp_install"
 115   CIN_UNINSTALLS+=" zmp_uninstall"
 116 fi
 117 if test "x$WANT_COMMERCIAL" = "xyes"; then
 118   CIN_INSTALLS+=" com_install"
 119   CIN_UNINSTALLS+=" com_uninstall"
 120 fi
 121 if test "x$WANT_LADSPA_BUILD" = "xyes"; then
 122   CIN_INSTALLS+=" lad_install "
 123   CIN_UNINSTALLS+=" lad_uninstall "
 124 fi
 125 if test "x$WANT_LV2" = "xyes"; then
 126   CIN_INSTALLS+=" lv2_install "
 127   CIN_UNINSTALLS+=" lv2_uninstall "
 128 fi
 129 AC_SUBST(CIN_INSTALLS)
 130 AC_SUBST(CIN_UNINSTALLS)
 131
 132 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
 133   MAK_INSTALLS="dvl_install"
 134   MAK_UNINSTALLS="dvl_uninstall"
 135 else
 136   MAK_INSTALLS=" sys_install"
 137   MAK_UNINSTALLS="sys_uninstall"
 138 fi
 139 AC_SUBST(MAK_INSTALLS)
 140 AC_SUBST(MAK_UNINSTALLS)
 141
 142 if test "x$WANT_JOBS" = "xauto"; then
 143   CPUS=`grep -c "^proc" /proc/cpuinfo`
 144   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
 145 fi
 146
 147 AC_DEFUN([PKG_DEF],[
 148 STATIC_PKGS+=" [$1]"
 149 ver_$1="$2"
 150 lib_$1="$3"
 151 inc_$1="$4"
 152 ])
 153
 154 AC_DEFUN([PKG_3RD],[
 155 AC_ARG_ENABLE([$1],
 156   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
 157   [PKG_$1=$enableval], [PKG_$1=$2])
 158 PKG_DEF([$1],[$3],[$4],[$5])
 159 ])
 160
 161 # thirdparty builds
 162
 163 PKG_3RD([a52dec],[yes],
 164   [a52dec-0.7.4],
 165   [ liba52/.libs/liba52.a ],
 166   [ include ])
 167
 168 PKG_3RD([djbfft],[yes],
 169   [djbfft-0.76],
 170   [ libdjbfft.a ],
 171   [ . ])
 172
 173 PKG_3RD([audiofile],[no],
 174   [audiofile-0.3.6],
 175   [ libaudiofile/.libs/libaudiofile.a \
 176     libaudiofile/modules/.libs/libmodules.a \
 177     libaudiofile/alac/.libs/libalac.a ],
 178   [ libaudiofile ])
 179
 180 PKG_3RD([encore],[no],
 181   [encore-5.0],
 182   [ \$(OBJDIR)/libencore.a ],
 183   [ . ])
 184
 185 PKG_3RD([esound],[no],
 186   [esound-0.2.41],
 187   [ .libs/libesd.a \
 188     .libs/libesddsp.a ],
 189   [ . ])
 190
 191 PKG_3RD([ffmpeg],[yes],
 192   [ffmpeg-4.2],
 193   [ libavutil/libavutil.a \
 194     libavcodec/libavcodec.a \
 195     libpostproc/libpostproc.a \
 196     libavdevice/libavdevice.a \
 197     libavformat/libavformat.a \
 198     libswscale/libswscale.a \
 199     libavfilter/libavfilter.a \
 200     libswresample/libswresample.a ],
 201   [ . ])
 202
 203 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 204   ver_ffmpeg="ffmpeg.git"
 205 fi
 206
 207 PKG_3RD([fftw],[auto],
 208   [fftw-3.3.8],
 209   [ .libs/libfftw3.a \
 210     libbench2/libbench2.a \
 211     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 212     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 213     rdft/scalar/.libs/librdft_scalar.a \
 214     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 215     rdft/.libs/librdft.a \
 216     api/.libs/libapi.a \
 217     reodft/.libs/libreodft.a \
 218     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 219     dft/scalar/.libs/libdft_scalar.a \
 220     dft/.libs/libdft.a \
 221     kernel/.libs/libkernel.a \
 222     simd-support/.libs/libsimd_support.a ],
 223   [ api ])
 224
 225 PKG_3RD([flac],[auto],
 226   [flac-1.3.2],
 227   [ src/libFLAC/.libs/libFLAC.a \
 228     src/libFLAC++/.libs/libFLAC++.a \
 229     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 230     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 231     src/share/grabbag/.libs/libgrabbag.a \
 232     src/share/utf8/.libs/libutf8.a \
 233     src/test_libs_common/.libs/libtest_libs_common.a ],
 234   [ include ])
 235
 236 PKG_3RD([giflib],[yes],
 237   [giflib-5.1.6],
 238   [ libgif.a ],
 239   [ . ])
 240
 241 PKG_3RD([ilmbase],[auto],
 242   [ilmbase-2.2.1],
 243   [ Iex/.libs/libIex.a \
 244     IexMath/.libs/libIexMath.a \
 245     Half/.libs/libHalf.a \
 246     Imath/.libs/libImath.a \
 247     IlmThread/.libs/libIlmThread.a ],
 248   [ Iex Half Imath config IlmThread ])
 249
 250 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 251
 252 PKG_3RD([lame],[auto],
 253   [lame-3.100],
 254   [ libmp3lame/.libs/libmp3lame.a \
 255     mpglib/.libs/libmpgdecoder.a ],
 256   [ include ])
 257
 258 PKG_3RD([libavc1394],[auto],
 259   [libavc1394-0.5.4],
 260   [ libavc1394/.libs/libavc1394.a \
 261     librom1394/.libs/librom1394.a \
 262     common/.libs/libraw1394util.a ],
 263   [ . ])
 264
 265 PKG_3RD([libraw1394],[auto],
 266   [libraw1394-2.1.2],
 267   [ src/.libs/libraw1394.a ],
 268   [ . ])
 269
 270 PKG_3RD([libiec61883],[auto],
 271   [libiec61883-1.2.0],
 272   [ src/.libs/libiec61883.a ],
 273   [ src ])
 274
 275 PKG_3RD([libdv],[auto],
 276   [libdv-1.0.0],
 277   [ libdv/.libs/libdv.a ],
 278   [ . ])
 279
 280 PKG_3RD([libjpeg],[auto],
 281   [libjpeg-turbo-1.5.1],
 282   [ .libs/libjpeg.a \
 283     .libs/libturbojpeg.a \
 284     simd/.libs/libsimd.a ],
 285   [ . ])
 286
 287 PKG_3RD([opus],[auto],
 288   [opus-1.3],
 289   [ .libs/libopus.a ],
 290   [ include ])
 291
 292 PKG_3RD([openjpeg],[auto],
 293   [openjpeg-2.3.0],
 294   [ bin/libopenjp2.a ],
 295   [ src/lib/openjp2 ])
 296
 297 PKG_3RD([libogg],[auto],
 298   [libogg-1.3.3],
 299   [ src/.libs/libogg.a ],
 300   [ include ])
 301
 302 PKG_3RD([libsndfile],[auto],
 303   [libsndfile-1.0.28],
 304   [ src/.libs/libsndfile.a \
 305     src/.libs/libcommon.a \
 306     src/G72x/.libs/libg72x.a \
 307     src/GSM610/.libs/libgsm.a ],
 308   [ . ])
 309
 310 PKG_3RD([libtheora],[auto],
 311   [libtheora-1.1.1],
 312   [ lib/.libs/libtheora.a \
 313     lib/.libs/libtheoradec.a \
 314     lib/.libs/libtheoraenc.a ],
 315   [ . ])
 316
 317 PKG_3RD([libuuid],[yes],
 318   [libuuid-1.0.3],
 319   [ .libs/libuuid.a ],
 320   [ . ])
 321
 322 PKG_3RD([libvorbis],[auto],
 323   [libvorbis-1.3.6],
 324   [ lib/.libs/libvorbis.a \
 325     lib/.libs/libvorbisenc.a \
 326     lib/.libs/libvorbisfile.a ],
 327   [ include . ])
 328
 329 PKG_3RD([mjpegtools],[yes],
 330   [mjpegtools-2.1.0],
 331   [ utils/mmxsse/.libs/libmmxsse.a \
 332     utils/.libs/libmjpegutils.a \
 333     lavtools/.libs/liblavfile.a \
 334     lavtools/.libs/liblavjpeg.a \
 335     mplex/.libs/libmplex2.a \
 336     yuvfilters/.libs/libyuvfilters.a \
 337     mpeg2enc/.libs/libmpeg2encpp.a ],
 338   [ .  lavtools utils ])
 339
 340 PKG_3RD([openexr],[auto],
 341   [openexr-2.2.1],
 342   [ IlmImf/.libs/libIlmImf.a \
 343     IlmImfUtil/.libs/libIlmImfUtil.a ],
 344   [ IlmImf config ])
 345
 346 #PKG_3RD([festival],[no],
 347 #  [festival],
 348 #  [],
 349 #  [])
 350 #PKG_3RD(speech_tools,[no],
 351 #  [speech_tools],
 352 #  [],
 353 #  [])
 354 #
 355 PKG_3RD([tiff],[auto],
 356   [tiff-4.0.10],
 357   [ libtiff/.libs/libtiff.a \
 358     libtiff/.libs/libtiffxx.a \
 359     port/.libs/libport.a ],[
 360    . ])
 361
 362 PKG_3RD([twolame],[auto],
 363   [twolame-0.3.13],
 364   [ libtwolame/.libs/libtwolame.a ],
 365   [  libtwolame ])
 366
 367 PKG_3RD([x264],[auto],
 368   [x264-snapshot-20190117-2245-stable],
 369   [ libx264.a ],
 370   [ . ])
 371
 372 PKG_3RD([x265],[auto],
 373   [x265_3.1.2],
 374   [ libx265.a ],
 375   [ . source ])
 376
 377 PKG_3RD([libvpx],[auto],
 378   [libvpx-1.8.1],
 379   [ libvpx.a ],
 380   [ . ])
 381
 382 PKG_3RD([lv2],[auto],
 383   [lv2-1.16.0],
 384   [ ],
 385   [ usr/local/include usr/local/lib64/lv2 usr/local/lib/lv2 ])
 386
 387 PKG_3RD([sratom],[auto],
 388   [sratom-0.6.2],
 389   [ usr/local/lib/libsratom-0.a ],
 390   [ usr/local/include ])
 391
 392 PKG_3RD([serd],[auto],
 393   [serd-0.30.0],
 394   [ usr/local/lib/libserd-0.a ],
 395   [ usr/local/include ])
 396
 397 PKG_3RD([sord],[auto],
 398   [sord-0.16.2],
 399   [ usr/local/lib/libsord-0.a ],
 400   [ usr/local/include ])
 401
 402 PKG_3RD([lilv],[auto],
 403   [lilv-0.24.4],
 404   [ usr/local/lib/liblilv-0.a ],
 405   [ usr/local/include ])
 406
 407 PKG_3RD([suil],[auto],
 408   [suil-0.10.2],
 409   [ usr/local/lib/libsuil-0.a ],
 410   [ usr/local/include ])
 411
 412 PKG_3RD([libaom],[auto],
 413   [libaom-v1.0.0],
 414   [ usr/local/lib*/libaom*.a ],
 415   [ usr/local/include ])
 416
 417 PKG_3RD([dav1d],[auto],
 418   [dav1d-0.5.0],
 419   [ usr/local/lib*/libdav1d*.a ],
 420   [ usr/local/include ])
 421
 422 PKG_3RD([libwebp],[auto],
 423   [libwebp-1.0.2],
 424   [ usr/local/lib*/libwebp*.a ],
 425   [ usr/local/include ])
 426
 427 PKG_3RD([ffnvcodec],[auto],
 428   [ffnvcodec],
 429   [ ],
 430   [ . ])
 431
 432 AC_SUBST(STATIC_PKGS)
 433
 434 AC_DEFUN([CHECK_ENABLE], [
 435 AC_ARG_ENABLE([$1],
 436   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 437   [WANT_$2=$enableval], [WANT_$2=[$4]])
 438 ])
 439
 440 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 441 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 442 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10bit], [no])
 443
 444 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 445
 446 AC_DEFUN([CHECK_PROG], [
 447  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 448 ])
 449 AC_DEFUN([REQUIRE_PROG], [
 450  CHECK_PROG([$1],[$2])
 451  if test "x$PROG_$1" = "xno"; then
 452    AC_MSG_WARN([$2 is missing and required.])
 453    FATAL_ERROR=1
 454  fi
 455 ])
 456
 457 ## arch dep tests
 458 ARCH=[`uname -m`]
 459 I86=[`expr "x$ARCH" : 'xi[346]86.*'`]
 460 X86=[`expr "x$ARCH" : 'x..._64*'`]
 461
 462 if test "x$I86$X86" != "x00" ; then
 463   # Checks for ix86 programs.
 464   REQUIRE_PROG(NASM, [nasm])
 465   # libx264 nasm fix
 466   AC_MSG_CHECKING([nasm x264 compatible])
 467   echo "vmovdqa32 [[eax]]{k1}{z}, zmm0" > conftest.asm
 468   nasm conftest.asm -o conftest.o > /dev/null 2>&1
 469   if test $? != 0 ; then
 470    AC_MSG_RESULT([no])
 471    AC_MSG_WARN([libx264 built without assembly code])
 472    X264_CFG_PARAMS="$X264_CFG_PARAMS --disable-asm"
 473   else
 474    AC_MSG_RESULT([yes])
 475   fi
 476   rm -f conftest.asm conftest.o
 477   REQUIRE_PROG(YASM, [yasm])
 478 fi
 479
 480 ## end arch dep tests
 481
 482 REQUIRE_PROG(OBJCOPY, [objcopy])
 483 if test "x$FATAL_ERROR" != "x"; then
 484  AC_MSG_ERROR("fatal eror.")
 485 fi
 486 CHECK_PROG(PACTL, [pactl])
 487 WANT_PACTL=$PROG_PACTL
 488
 489 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 490 if test "$no_utf" = "yes"; then
 491   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 492 fi
 493
 494 # Checks for headers/libraries.
 495
 496 AC_DEFUN([CHECK_HEADERS], [
 497 if test "x$HAVE_$1" != "xno"; then
 498  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 499   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 500 ]])])
 501  AC_SUBST([HAVE_$1])
 502  AC_MSG_CHECKING([$2])
 503  AC_MSG_RESULT([$HAVE_$1])
 504  if test "x$HAVE_$1" = "xno"; then
 505   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 506  fi
 507 fi
 508 ])
 509
 510 AC_DEFUN([CHECK_LIB], [
 511 if test "x$HAVE_$1" != "xno"; then
 512  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno" -a "x$PKG_$1" != "xno"; then
 513   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 514   AC_SUBST([HAVE_$1])
 515   if test "x$WANT_$1" != "xno"; then
 516    if test "x$HAVE_$1" = "xyes"; then
 517     if test "x$PKG_$1" = "x"; then
 518      SYSTEM_LIBS+=" -l[$2]"
 519      for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 520     else
 521      SHARED_$1+=" -l[$2]"
 522      for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 523     fi
 524    elif test "x$PKG_$1" = "x"; then
 525     RESULT=no
 526    fi
 527   fi
 528  fi
 529 fi
 530 ])
 531
 532 CHECK_LIB([X11], [X11], [XOpenDisplay])
 533 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 534 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 535 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 536 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 537 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 538 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 539 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 540 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 541 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 542 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 543 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 544 CHECK_LIB([PNG], [png], [png_read_png])
 545 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 546 CHECK_LIB([Z], [z], [gzopen])
 547 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 548 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 549 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 550 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 551 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 552 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 553 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 554 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 555 CHECK_LIB([lame], [mp3lame], [lame_init])
 556 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 557 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 558 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 559 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 560 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 561 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 562 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 563 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 564 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 565 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 566 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 567 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 568 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 569 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 570 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 571 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 572 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 573 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 574 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 575 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 576 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 577 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 578 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 579 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 580 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 581 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 582 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 583 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 584 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 585 CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 586 CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])
 587 CHECK_LIB([libaom], [aom], [aom_codec_version])
 588 CHECK_HEADERS([libaom], [libaom headers], [aom/aom.h])
 589 CHECK_LIB([dav1d], [dav1d], [dav1d_version])
 590 CHECK_HEADERS([dav1d], [libdav1d headers], [dav1d/dav1d.h])
 591 CHECK_LIB([libwebp], [webp], [WebPGetEncoderVersion])
 592 CHECK_HEADERS([libwebp], [libwebp headers], [webp/encode.h])
 593 CHECK_LIB([a52dec], [a52], [a52_init])
 594 CHECK_HEADERS([a52dec], [a52 headers], [stdint.h a52.h])
 595 CHECK_LIB([encore], [encore], [encore])
 596 CHECK_HEADERS([encore], [encore headers], [encore.h])
 597 CHECK_LIB([giflib], [gif], [DGifOpen])
 598 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 599 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 600
 601 CHECK_LIB([VDPAU], [vdpau], [vdp_device_create_x11])
 602 if test "x$HAVE_VDPAU" != "xyes" -a "x$WANT_VDPAU" = "xyes"; then
 603   AC_MSG_ERROR([requires vdpau support.])
 604 fi
 605
 606 CHECK_LIB([VAAPI], [va], [vaInitialize])
 607 if test "x$HAVE_VAAPI" = "xyes" -a "x$WANT_VAAPI" != "xno"; then
 608   CHECK_HEADERS([vaapi_x11], [va x11 headers], [va/va_x11.h])
 609   CHECK_LIB([vaapi_x11], [va-x11], [vaGetDisplay])
 610   CHECK_HEADERS([vaapi_drm], [va drm headers], [va/va_drm.h])
 611   CHECK_LIB([vaapi_drm], [va-drm], [vaGetDisplayDRM])
 612 fi
 613 if test "x$HAVE_VAAPI" != "xyes" -a "x$WANT_VAAPI" = "xyes"; then
 614   AC_MSG_ERROR([requires vaapi support.])
 615 fi
 616
 617 #CHECK_LIB([NVENC], [nvidia-encode], [NvEncodeAPICreateInstance])
 618
 619 #if test "x$HAVE_mjpegtools" = "xyes"; then
 620 #CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
 621 #fi
 622
 623 AC_DEFUN([CHECK_WANT], [
 624 RESULT=yes
 625 # WANT_$1
 626 AC_ARG_WITH(m4_tolower([$1]),
 627  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 628   [WANT_$1=$withval],[WANT_$1=$2])
 629  m4_quote($4)
 630  if test "x$WANT_$1" = "xauto" ; then
 631   WANT_$1="$RESULT"
 632  elif test "x$WANT_$1" = "xyes" ; then
 633   if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 634     AC_MSG_ERROR([required for $1 support.])
 635   fi
 636  fi
 637 CFG_WANTS+=" $1"
 638 AC_SUBST([WANT_$1])
 639 ])
 640
 641 CHECK_WANT([GL], [auto], [use opengl], [
 642  CHECK_LIB([GL], [GL], [glUseProgram])
 643  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 644  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 645
 646 CHECK_WANT([XV], [auto], [use xv], [
 647  CHECK_LIB([xv], [Xv], [XvQueryExtension])
 648  CHECK_HEADERS([xv], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])])
 649
 650 CHECK_WANT([OSS], [auto], [use OSS audio], [
 651  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 652
 653 CHECK_WANT([XFT], [auto], [use libXft], [
 654  CHECK_LIB([XFT], [Xft], [XftInit])
 655  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 656
 657 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 658  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 659  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 660
 661 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 662  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 663  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 664  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 665  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 666  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 667  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 668  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 669  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 670 # have all or none
 671 test "x$HAVE_libavc1394" = "xyes" && \
 672 test "x$HAVE_libiec61883" = "xyes" && \
 673 test "x$HAVE_libraw1394" = "xyes" && \
 674   HAVE_FIREWIRE=yes || \
 675 HAVE_libavc1394=no && \
 676 HAVE_libiec61883=no && \
 677 HAVE_libraw1394=no && \
 678  HAVE_FIREWIRE=no
 679
 680 CHECK_WANT([DV], [auto], [use dv], [
 681  CHECK_LIB([libdv], [dv], [dv_init])
 682  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 683
 684 CHECK_WANT([DVB], [auto], [use dvb], [
 685  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 686
 687 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 688  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 689
 690 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 691  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 692
 693 CHECK_WANT([ESOUND], [no], [use esd], [
 694  CHECK_LIB([esound], [esd], [esd_open_sound])
 695  CHECK_HEADERS([esound], [esound headers], [esd.h])
 696  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 697  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 698 # have all or none
 699 test "x$HAVE_esound" = "xyes" && \
 700 test "x$HAVE_audiofile" = "xyes" && \
 701   HAVE_ESOUND=yes || \
 702 HAVE_esound=no && \
 703 HAVE_audiofile=no && \
 704   HAVE_ESOUND=no
 705
 706 CHECK_WANT([PULSE], [auto], [use pulseaudio], [
 707  CHECK_LIB([pulse_simple], [pulse-simple], [pa_simple_new])
 708  CHECK_HEADERS([pulse_simple], [pulse-simple headers], [pulse/simple.h])
 709  CHECK_LIB([pulse], [pulse], [pa_context_new])
 710  CHECK_HEADERS([pulse], [pulse headers], [pulse/error.h])])
 711
 712 CHECK_WANT([ISOFS], [auto], [use isofs], [
 713  CHECK_HEADERS([isofs], [isofs headers], [linux/isofs.h])])
 714
 715 if test "x$WANT_LADSPA_BUILD" != "xyes" ; then
 716  CHECK_WANT([LADSPA], [auto], [ladspa plugin clients], [
 717   CHECK_HEADERS([ladspa], [ladspa headers], [ladspa.h])])
 718 else
 719  WANT_LADSPA=yes
 720 fi
 721
 722 CHECK_WANT([SHUTTLE], [yes], [shuttle dev support], [
 723  CHECK_HEADERS([keysyms], [x11 keysym defs], [X11/keysymdef.h])])
 724 if test "x$WANT_SHUTTLE" = "xno"; then
 725  WANT_SHUTTLE_USB="no"
 726 fi
 727 CHECK_WANT([SHUTTLE_USB], [yes], [use libusb-1.0], [
 728  CHECK_LIB([libusbx], [usb-1.0], [libusb_init])
 729  CHECK_HEADERS([libusbx], [libusb headers], [libusb-1.0/libusb.h])])
 730
 731 CHECK_WANT([LV2], [auto], [use lv2], [
 732  saved_CFLAGS="$CFLAGS"
 733  CHECK_LIB([lilv], [lilv-0], [lilv_world_new])
 734  CHECK_LIB([sord], [sord-0], [sord_world_new])
 735  CHECK_LIB([serd], [serd-0], [serd_reader_new])
 736  CHECK_LIB([sratom], [sratom-0], [sratom_new])
 737  CFLAGS="-I/usr/include/lilv-0 -I/usr/local/include/lilv-0"
 738  CHECK_HEADERS([lv2], [lilv headers], [lilv/lilv.h])
 739  CHECK_LIB([suil], [suil-0], [suil_instance_new])
 740  CFLAGS="-I/usr/include/suil-0 -I/usr/local/include/suil-0"
 741  CHECK_HEADERS([lv2], [suil headers], [suil/suil.h])
 742  CFLAGS="$saved_CFLAGS"])
 743 # have all or none
 744 test "x$HAVE_lv2" = "xyes" && \
 745 test "x$HAVE_lilv" = "xyes" && \
 746 test "x$HAVE_sord" = "xyes" && \
 747 test "x$HAVE_serd" = "xyes" && \
 748 test "x$HAVE_sratom" = "xyes" && \
 749 test "x$HAVE_suil" = "xyes" && \
 750   HAVE_LV2=yes || \
 751 HAVE_lv2=no && \
 752 HAVE_lilv=no && \
 753 HAVE_sord=no && \
 754 HAVE_serd=no && \
 755 HAVE_sratom=no && \
 756 HAVE_suil=no && \
 757   HAVE_LV2=no
 758
 759 CHECK_WANT([CUDA], [auto], [build cuda plugins], [
 760   CHECK_HEADERS([CUDA], [cuda sdk], [${CUDA_PATH:-/usr/local/cuda}/include/cuda.h])])
 761
 762 CHECK_WANT([DL], [auto], [system has libdl], [
 763  CHECK_LIB([DL], [dl], [dlopen])])
 764
 765 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 766 ])
 767
 768 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 769  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 770
 771 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 772  AC_MSG_CHECKING([for openexr available])
 773  saved_LIBS="$LIBS"
 774  saved_CXXFLAGS="$CXXFLAGS"
 775  # ilmbase libs
 776  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 777  CXXFLAGS="-I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 778  AC_LANG_PUSH(C++)
 779  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 780 #include "ImfChannelList.h"
 781 #include "ImfChromaticities.h"
 782 #include "ImfCompression.h"
 783 #include "ImfIO.h"
 784 #include "ImfInputFile.h"
 785 #include "ImfOutputFile.h"
 786 #include "ImfPixelType.h"
 787 #include "ImfRgbaFile.h"
 788 #include "ImfRgbaYca.h"
 789 #include "ImfVersion.h"
 790 class EXRIStream : public Imf::IStream { public:
 791 EXRIStream() : Imf::IStream("mypath") {} };
 792 class EXROStream : public Imf::OStream { public:
 793 EXROStream() : Imf::OStream("mypath") {} };
 794 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 795  if test "x$WANT_OPENEXR" = "xauto"; then
 796    WANT_OPENEXR="yes"
 797  fi
 798  if test "x$WANT_OPENEXR" = "xyes" -a "x$HAVE_OPENEXR" = "xyes"; then
 799   if test "x$WANT_STATIC_BUILD" = "xno"; then
 800     SHARED_openexr="$LIBS"
 801     SHARED_LIBS+=" $LIBS"
 802     CFG_CFLAGS+=" -I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 803   fi
 804  fi
 805  LIBS="$saved_LIBS"
 806  CXXFLAGS="$saved_CXXFLAGS"
 807  AC_LANG_POP(C++)
 808  AC_MSG_RESULT([$HAVE_OPENEXR])
 809 ])
 810 AC_SUBST([HAVE_OPENEXR])
 811 # have all or none
 812 test "x$HAVE_openexr" = "xyes" && \
 813 test "x$HAVE_ilmbase" = "xyes" && \
 814   HAVE_OPENEXR=yes || \
 815 HAVE_openexr=no && \
 816 HAVE_ilmbase=no &&
 817   HAVE_OPENEXR=no
 818
 819 # build global_config
 820 OBJDIR=`uname -m`
 821 AC_SUBST(OBJDIR)
 822
 823 echo "AC_HELP_STRING([Reason],[Package])"
 824 echo "AC_HELP_STRING([------],[-------])"
 825
 826 AC_DEFUN([PKG_DISABLED],[
 827  PKG_$1="no"
 828  BUILD_$1=0
 829  AC_SUBST(BUILD_$1)
 830  echo "AC_HELP_STRING([disabled],[$1])"
 831 ])
 832 AC_DEFUN([PKG_SHARED],[
 833  PKG_$1="shared"
 834  BUILD_$1=0
 835  AC_SUBST(BUILD_$1)
 836  SHARED_LIBS+="$SHARED_$1"
 837 ])
 838
 839 AC_DEFUN([PKG_STATIC],[
 840  if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 841   PKG_$1="yes"
 842   BUILD_$1=1
 843   AC_SUBST(BUILD_$1)
 844   STATIC_BLDS+=" [$1]"
 845   echo "AC_HELP_STRING([$2],[$1])"
 846  fi
 847 ])
 848
 849 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 850
 851 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 852 # order matters
 853 for dep in \
 854         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 855         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 \
 856         libiec61883/libraw1394 libavc1394/librom1394 \
 857         openexr/ilmbase ilmbase/libogg \
 858         libtheora/libogg libtheora/libvorbis ; do
 859   lib=`dirname $dep`;  needs=`basename $dep`
 860   eval pkg_lib="\$PKG_$lib"
 861   if test "x$pkg_lib" != "xno"; then
 862     eval "PKG_$needs=yes"
 863   fi
 864 done
 865 fi
 866
 867 AC_DEFUN([PKG_PROVIDE],[
 868 if test "x$BUILD_$1" = "x" ; then
 869  if test "x$PKG_$1" = "xyes"; then
 870   if test "x$WANT_CIN_3RDPARTY" = "xno"; then
 871     PKG_SHARED([$1])
 872   else
 873     PKG_FORCED([$1])
 874   fi
 875  elif test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 876   PKG_DISABLED([$1])
 877  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 878   PKG_STATIC([$1],[static])
 879  elif test "x$HAVE_$1" = "xyes"; then
 880   PKG_SHARED([$1])
 881  else
 882   PKG_STATIC([$1],[needed])
 883  fi
 884 fi
 885 ])
 886
 887 PKG_PROVIDE([a52dec])
 888 PKG_PROVIDE([djbfft])
 889 PKG_PROVIDE([encore])
 890 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 891 PKG_PROVIDE([esound],[$WANT_ESOUND])
 892 PKG_PROVIDE([ffmpeg])
 893 PKG_PROVIDE([fftw])
 894 PKG_PROVIDE([flac])
 895 PKG_PROVIDE([giflib])
 896 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 897 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 898 PKG_PROVIDE([lame])
 899 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 900 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 901 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 902 PKG_PROVIDE([libdv],[$WANT_DV])
 903 PKG_PROVIDE([libjpeg])
 904 PKG_PROVIDE([libogg])
 905 PKG_PROVIDE([libsndfile])
 906 PKG_PROVIDE([libtheora])
 907 PKG_PROVIDE([libuuid])
 908 PKG_PROVIDE([libvorbis])
 909 PKG_PROVIDE([mjpegtools])
 910 PKG_PROVIDE([libaom])
 911 PKG_PROVIDE([dav1d])
 912 PKG_PROVIDE([libwebp])
 913 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 914 PKG_PROVIDE([openjpeg])
 915 PKG_PROVIDE([tiff])
 916 PKG_PROVIDE([twolame])
 917 PKG_PROVIDE([x264])
 918 PKG_PROVIDE([x265])
 919 PKG_PROVIDE([libvpx])
 920 PKG_PROVIDE([opus])
 921 PKG_PROVIDE([lv2], [$WANT_LV2])
 922 PKG_PROVIDE([lilv], [$WANT_LV2])
 923 PKG_PROVIDE([sratom], [$WANT_LV2])
 924 PKG_PROVIDE([serd], [$WANT_LV2])
 925 PKG_PROVIDE([sord], [$WANT_LV2])
 926 PKG_PROVIDE([suil], [$WANT_LV2])
 927 PKG_PROVIDE([ffnvcodec], [$WANT_NV])
 928
 929 if test "x$WANT_LV2" = "xyes"; then
 930   if test "x$HAVE_lv2" = "xyes" -a "x$BUILD_lilv" = "x0"; then
 931     CFG_CFLAGS+=' -I/usr/include/lilv-0 -I/usr/local/include/lilv-0'
 932     CFG_CFLAGS+=' -I/usr/include/suil-0 -I/usr/local/include/suil-0'
 933   fi
 934 fi
 935
 936 AC_SUBST(STATIC_BLDS)
 937 for f in $SHARED_LIBS; do
 938   echo "AC_HELP_STRING([shared],[$f])"
 939 done
 940 AC_SUBST(SHARED_LIBS)
 941 for f in $SYSTEM_LIBS; do
 942   echo "AC_HELP_STRING([system],[$f])"
 943 done
 944 AC_SUBST(SYSTEM_LIBS)
 945
 946 echo ""
 947 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 948   CFG_CFLAGS+=" -DHAVE_CIN_3RDPARTY"
 949 fi
 950 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB LADSPA \
 951          VIDEO4LINUX2 ESOUND PULSE PACTL OPENEXR LV2 \
 952          COMMERCIAL LIBZMPEG SHUTTLE SHUTTLE_USB XV \
 953          VAAPI VDPAU CUDA NV WINTV X10TV; do
 954   eval vv="\$WANT_$v"
 955   if test "x$vv" != "xno"; then
 956     CFG_CFLAGS+=" -DHAVE_$v"
 957     vv=with
 958   else
 959     vv=without
 960   fi
 961   v=`echo "$v" | tr "A-Z" "a-z"`
 962   echo "  using: $vv-$v"
 963 done
 964
 965 # build extras
 966 if test "x$WANT_CLANG" = "xyes" ; then
 967   FFMPEG_EXTRA_CFG+=' --cc=clang --cxx=clang++'
 968 fi
 969 if test "x$HAVE_tiff" = "xyes"; then
 970   if test "x$HAVE_jbig" = "xyes"; then
 971     EXTRA_LIBS+=' -ljbig'
 972   fi
 973 fi
 974 if test "x$HAVE_NUMA" = "xyes"; then
 975   EXTRA_LIBS+=' -lnuma'
 976 fi
 977
 978 FFMPEG_EXTRA_LDFLAGS=""
 979 if test "x$WANT_VAAPI" != "xno" -a "x$HAVE_VAAPI" = "xyes"; then
 980   FFMPEG_EXTRA_LDFLAGS+=' -lva'
 981   EXTRA_LIBS+=' -lva'
 982   WANT_VAAPI="yes"
 983   if test "x$HAVE_vaapi_x11" = "xyes"; then
 984     FFMPEG_EXTRA_LDFLAGS+=' -lva-x11'
 985     EXTRA_LIBS+=' -lva-x11'
 986   fi
 987   if test "x$HAVE_vaapi_drm" = "xyes"; then
 988     FFMPEG_EXTRA_LDFLAGS+=' -lva-drm'
 989     EXTRA_LIBS+=' -lva-drm'
 990   fi
 991 fi
 992 CFG_WANTS+=" VAAPI"
 993
 994 if test "x$WANT_VDPAU" != "xno" -a "x$HAVE_VDPAU" = "xyes"; then
 995   WANT_VDPAU="yes"
 996 fi
 997 CFG_WANTS+=" VDPAU"
 998
 999 if test "x$WANT_NV" != "xno"; then
1000   WANT_NV="yes"
1001   CFG_WANTS+=" NV"
1002 fi
1003
1004 if test "x$HAVE_DL" = "xyes"; then
1005   EXTRA_LIBS+=' -ldl'
1006   FFMPEG_EXTRA_LDFLAGS+=' -ldl'
1007 fi
1008 if test "x$FFMPEG_EXTRA_LDFLAGS" != "x"; then
1009   FFMPEG_EXTRA_CFG+=' --extra-ldflags="'$FFMPEG_EXTRA_LDFLAGS'"'
1010 fi
1011
1012 if test "x$WANT_BOOBY" != "xno"; then
1013   CFG_CFLAGS+=" -DBOOBY"
1014 fi
1015
1016 # intel lock elision bugs
1017 if test "x$WANT_NOELISION" != "xno"; then
1018   CFG_RPATH=`ls -1fd 2> /dev/null \
1019  /usr/lib/noelision \
1020  /lib/noelision \
1021  /usr/lib64/noelision \
1022  /lib64/noelision \
1023   | tail -1`
1024 fi
1025
1026 echo "  using: with-jobs = $WANT_JOBS"
1027 echo "  using: exec-name = $WANT_CIN"
1028 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
1029 echo "  using: with-cindat = $WANT_CINDAT_DIR"
1030 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
1031 echo "  using: with-nested-dir = $WANT_NESTED_DIR"
1032 echo "  using: with-snap-dir = $WANT_SNAP_DIR"
1033 echo "  using: with-browser = $WANT_CIN_BROWSER"
1034 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
1035 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
1036 echo "  using: with-opencv = $WANT_OPENCV"
1037 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
1038 echo "  using: with-noelision = $WANT_NOELISION"
1039 echo "  using: with-booby = $WANT_BOOBY"
1040 echo "  using: with-clang = $WANT_CLANG"
1041 echo ""
1042 echo "  using: thirdparty build = $WANT_CIN_3RDPARTY"
1043 echo "  using: single-user  = $WANT_CINBIN_BUILD"
1044 echo "  using: static-build = $WANT_STATIC_BUILD"
1045 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
1046 echo ""
1047
1048 AC_SUBST(WANT_CIN_3RDPARTY)
1049 AC_SUBST(EXTRA_LIBS)
1050 AC_SUBST(FFMPEG_EXTRA_CFG)
1051 AC_SUBST(WANT_X264_HIDEPTH)
1052 AC_SUBST(WANT_X265_HIDEPTH)
1053
1054 AC_SUBST(CFG_CFLAGS)
1055 AC_SUBST(CFG_CXXFLAGS)
1056
1057 AC_CONFIG_FILES([Makefile])
1058 AC_OUTPUT
1059
1060 exec > global_config
1061
1062 echo "SHELL := /bin/bash"
1063 echo "export SHELL"
1064 echo "WANT_JOBS := $WANT_JOBS"
1065 if test "x$WANT_CLANG" = "xyes" ; then
1066   echo "CC = clang"
1067   echo "CXX = clang++"
1068   echo "export CC CXX"
1069 fi
1070 echo ""
1071 echo "OBJDIR := $OBJDIR"
1072 echo "BINDIR := \$(TOPDIR)/bin"
1073 echo "CINELERRA := \$(TOPDIR)/cinelerra"
1074 echo "GUICAST := \$(TOPDIR)/guicast"
1075 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
1076 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
1077 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
1078 echo "PLUGINS := \$(TOPDIR)/plugins"
1079 echo "TDB := \$(TOPDIR)/db"
1080 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
1081 echo "EXTRA_LIBS := $EXTRA_LIBS"
1082 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
1083 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
1084 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
1085 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
1086 echo ""
1087
1088 echo "WANT_CIN := $WANT_CIN"
1089 CFG_WANTS+=" CIN_3RDPARTY LIBZMPEG COMMERCIAL STATIC_BUILD"
1090 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
1091 echo ""
1092
1093 echo "ifndef CFLAGS_"
1094 echo "ifdef CFLAGS"
1095 echo "CFLAGS_ := \$(CFLAGS)"
1096 echo "else"
1097 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
1098 echo "endif"
1099 echo "endif"
1100 echo "ifndef CXXFLAGS_"
1101 echo "ifdef CXXFLAGS"
1102 echo "CXXFLAGS_ := \$(CXXFLAGS)"
1103 echo "endif"
1104 echo "endif"
1105 echo "ifndef LDFLAGS_"
1106 echo "ifdef LDFLAGS"
1107 echo "LDFLAGS_ := \$(LDFLAGS)"
1108 echo "endif"
1109 echo "endif"
1110
1111 echo "CFLAGS := \$(CFLAGS_)"
1112 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
1113 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
1114 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
1115 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
1116 echo "CFLAGS += '-DNESTED_DIR=\"$WANT_NESTED_DIR\"'"
1117 echo "CFLAGS += '-DSNAP_DIR=\"$WANT_SNAP_DIR\"'"
1118 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
1119 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
1120 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
1121 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
1122 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
1123 echo ""
1124 if test "x$CFG_CXXFLAGS" != "x"; then
1125   for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
1126   echo ""
1127 fi
1128 if test "x$CFG_LDFLAGS" != "x" ; then
1129   echo "LDFLAGS +=$CFG_LDFLAGS"
1130   echo ""
1131 fi
1132
1133 if test "x$CYGWIN" != "x" ; then
1134   echo 'FF_PATH ?= /usr/local'
1135   echo 'LDFLAGS += -L$(FF_PATH)/lib'
1136   echo 'CFLAGS += -I$(FF_PATH)/include'
1137   echo ""
1138   echo "CFLAGS += -DNO_BTRACE"
1139   echo "CFLAGS += -DNO_GDB"
1140   echo "CFLAGS += -DNO_CTX"
1141   echo "CFLAGS += -DNO_PRCTL"
1142   echo "CFLAGS += -DNO_TID"
1143   echo "CFLAGS += -DNO_XSELECT"
1144   echo ""
1145 else
1146   LDFLAGS+=" -z noexecstack"
1147 fi
1148 if test "x$BSD" != "x" ; then
1149   echo "CFLAGS += -DNO_PRCTL"
1150   echo "CFLAGS += -DNO_TID"
1151   echo "CFLAGS += -DNO_GDB"
1152 fi
1153
1154 if test "x$WANT_X264_HIDEPTH" = "xyes" ; then
1155   X264_CFG_PARAMS="$X264_CFG_PARAMS --bit-depth=10"
1156 fi
1157 if test "x$WANT_X265_HIDEPTH" = "xyes" ; then
1158   X265_CFG_PARAMS="$X265_CFG_PARAMS -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
1159 fi
1160
1161 for pkg in $STATIC_PKGS; do
1162   eval pkg_lib="\$PKG_$pkg"
1163   if test "x$pkg_lib" = "xyes"; then
1164     echo "static_pkgs += $pkg"
1165   elif test "x$pkg_lib" = "xshared"; then
1166     echo "shared_pkgs += $pkg"
1167   fi
1168 done
1169 echo ""
1170
1171 for pkg in $STATIC_BLDS; do
1172   echo "static_blds += $pkg"
1173   ver_pkg=ver_$pkg
1174   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
1175   inc_pkg=inc_$pkg
1176   echo "$inc_pkg := \\"
1177   for inc in ${!inc_pkg}; do
1178     echo "  -I\$($ver_pkg)/$inc \\"
1179   done
1180   echo ""
1181   echo "static_incs += \$(inc_$pkg)"
1182   lib_pkg=lib_$pkg
1183   echo "$lib_pkg := \\"
1184   for lib in ${!lib_pkg}; do
1185     echo "  \$($ver_pkg)/$lib \\"
1186   done
1187   echo ""
1188   echo "static_libs += \$($lib_pkg)"
1189   echo ""
1190 done
1191 echo ""
1192
1193 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
1194 echo ""
1195 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
1196 echo "export static_pkgs shared_pkgs static_blds shared_libs system_libs"
1197 echo ""
1198
1199 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
1200
1201 if test "x$CFG_RPATH" != "x"; then
1202   echo "libraries+= -Wl,-rpath=$CFG_RPATH"
1203 fi
1204
1205 echo "libraries += -Wl,--start-group"
1206 echo "libraries += \$(thirdparty_libraries)"
1207 echo "libraries += \$(shared_libs)"
1208 echo "libraries += \$(system_libs)"
1209 echo "libraries += \$(EXTRA_LIBS)"
1210 echo "libraries += -Wl,--end-group"
1211 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
1212 echo "libraries += \$(thirdparty_libraries)"
1213 echo "libraries += \$(shared_libs)"
1214 echo "libraries += \$(system_libs)"
1215 echo "libraries += \$(EXTRA_LIBS)"
1216 echo ""
1217 echo "export thirdparty_libraries libraries"
1218 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
1219 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
1220
1221 if test "x$HAVE_tiff" = "xyes"; then
1222   if test "x$HAVE_jbig" != "xyes"; then
1223     echo "tiff.cfg_params+= --disable-jbig"
1224   fi
1225 fi
1226
1227 if test "x$WANT_GIT_FFMPEG" != "xno"; then
1228   echo "ffmpeg.git := $WANT_GIT_FFMPEG"
1229 fi
1230 if test "x$X264_CFG_PARAMS" != "x" ; then
1231   echo "x264.cfg_params :=$X264_CFG_PARAMS --enable-static --enable-pic"
1232 fi
1233 if test "x$X265_CFG_PARAMS" != "x" ; then
1234   echo "x265.cfg_params :=$X265_CFG_PARAMS -DENABLE_SHARED=no"
1235 fi
1236