cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-gg.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 CFG_CFLAGS+=" -Wno-unknown-warning"
  15 CFG_CFLAGS+=" -Wno-unused-result"
  16 CFG_CFLAGS+=" -Wno-stringop-overflow"
  17 CFG_CFLAGS+=" -Wno-format-truncation"
  18 CFG_CFLAGS+=" -Wno-format-overflow"
  19 CFG_CFLAGS+=" -Wno-parentheses"
  20 CFG_CFLAGS+=" -Wno-stringop-truncation"
  21 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  22 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  23 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  24 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  25 CFG_CFLAGS+=" -I/usr/include -I/usr/local/include"
  26 CFG_CFLAGS+=" -I/usr/include/freetype2 -I/usr/local/include/freetype2"
  27 CFG_CFLAGS+=" -I/usr/include/uuid -I/usr/local/include/uuid"
  28 CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
  29
  30 CFG_LDFLAGS+=" -z noexecstack"
  31
  32 AC_DEFUN([CHECK_WITH], [
  33 AC_ARG_WITH([$1],
  34   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  35   [WANT_$3=$withval], [WANT_$3='$4'])
  36 AC_SUBST([WANT_$3])
  37 ])
  38
  39 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  40 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  41 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  42 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  43 CHECK_WITH([lv2],[lv2 library support],[LV2],[yes])
  44 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  45 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  46 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  47 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  48 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  49 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  50 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  51 CHECK_WITH([noelision],[use noelision/libpthread],[NOELISION],[auto])
  52 CHECK_WITH([booby],[window lock trace booby trap],[BOOBY],[no])
  53 CHECK_WITH([libzmpeg],[build libzmpeg],[LIBZMPEG],[yes])
  54 CHECK_WITH([commercial],[enable commercial capture],[COMMERCIAL],[yes])
  55 CHECK_WITH([thirdparty],[use thirdparty build],[CIN_3RDPARTY],[yes])
  56 CHECK_WITH([shuttle],[shuttle device],[SHUTTLE],[yes])
  57
  58 if test "x$WANT_LV2" != "xno"; then
  59   GTK2_LIBS=`pkg-config --libs gtk+-2.0`
  60   AC_CHECK_LIB([m], [gtk_init], [HAVE_gtk=yes], [HAVE_gtk=no], [$GTK2_LIBS])
  61   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --cflags gtk+-2.0`" && HAVE_gtk=no
  62   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --libs gtk+-2.0`" && HAVE_gtk=no
  63   if test "x$HAVE_gtk" = "xno"; then
  64     AC_MSG_ERROR([LV2 requires gtk+-2.0 support.])
  65   fi
  66 fi
  67
  68 if test "x$WANT_COMMERCIAL" = "xyes" -a "x$WANT_LIBZMPEG" != "xyes" ; then
  69   AC_MSG_ERROR([commercial requires libzmpeg support.])
  70 fi
  71
  72 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  73   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  74   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  75   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  76   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  77   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  78 else
  79   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  80     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  81     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  82     echo "$dir"`
  83   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  84     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  85     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  86     echo "$dir"`
  87   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  88     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  89     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  90     echo "$dir"`
  91   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  92        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  93   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  94     usrlib+="64"
  95   WANT_LOCALE_DIR="$lcldir"
  96   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  97   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  98   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  99   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
 100 fi
 101
 102 CIN_INSTALLS=""
 103 CIN_UNINSTALLS=""
 104 if test "x$WANT_LIBZMPEG" = "xyes"; then
 105   CIN_INSTALLS+=" zmp_install"
 106   CIN_UNINSTALLS+=" zmp_uninstall"
 107 fi
 108 if test "x$WANT_COMMERCIAL" = "xyes"; then
 109   CIN_INSTALLS+=" com_install"
 110   CIN_UNINSTALLS+=" com_uninstall"
 111 fi
 112 if test "x$WANT_LADSPA_BUILD" = "xyes"; then
 113   CIN_INSTALLS+=" lad_install "
 114   CIN_UNINSTALLS+=" lad_uninstall "
 115 fi
 116 if test "x$WANT_LV2" = "xyes"; then
 117   CIN_INSTALLS+=" lv2_install "
 118   CIN_UNINSTALLS+=" lv2_uninstall "
 119 fi
 120 AC_SUBST(CIN_INSTALLS)
 121 AC_SUBST(CIN_UNINSTALLS)
 122
 123 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
 124   MAK_INSTALLS="dvl_install"
 125   MAK_UNINSTALLS="dvl_uninstall"
 126 else
 127   MAK_INSTALLS=" sys_install"
 128   MAK_UNINSTALLS="sys_uninstall"
 129 fi
 130 AC_SUBST(MAK_INSTALLS)
 131 AC_SUBST(MAK_UNINSTALLS)
 132
 133 if test "x$WANT_JOBS" = "xauto"; then
 134   CPUS=`grep -c "^proc" /proc/cpuinfo`
 135   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
 136 fi
 137
 138 AC_DEFUN([PKG_DEF],[
 139 STATIC_PKGS+=" [$1]"
 140 ver_$1="$2"
 141 lib_$1="$3"
 142 inc_$1="$4"
 143 ])
 144
 145 AC_DEFUN([PKG_3RD],[
 146 AC_ARG_ENABLE([$1],
 147   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
 148   [PKG_$1=$enableval], [PKG_$1=$2])
 149 PKG_DEF([$1],[$3],[$4],[$5])
 150 ])
 151
 152 # thirdparty builds
 153
 154 PKG_3RD([a52dec],[yes],
 155   [a52dec-0.7.4],
 156   [ liba52/.libs/liba52.a ],
 157   [ include ])
 158
 159 PKG_3RD([djbfft],[yes],
 160   [djbfft-0.76],
 161   [ libdjbfft.a ],
 162   [ . ])
 163
 164 PKG_3RD([audiofile],[no],
 165   [audiofile-0.3.6],
 166   [ libaudiofile/.libs/libaudiofile.a \
 167     libaudiofile/modules/.libs/libmodules.a \
 168     libaudiofile/alac/.libs/libalac.a ],
 169   [ libaudiofile ])
 170
 171 PKG_3RD([encore],[no],
 172   [encore-5.0],
 173   [ \$(OBJDIR)/libencore.a ],
 174   [ . ])
 175
 176 PKG_3RD([esound],[no],
 177   [esound-0.2.41],
 178   [ .libs/libesd.a \
 179     .libs/libesddsp.a ],
 180   [ . ])
 181
 182 PKG_3RD([ffmpeg],[yes],
 183   [ffmpeg-4.1],
 184   [ libavutil/libavutil.a \
 185     libavcodec/libavcodec.a \
 186     libpostproc/libpostproc.a \
 187     libavdevice/libavdevice.a \
 188     libavformat/libavformat.a \
 189     libswscale/libswscale.a \
 190     libavfilter/libavfilter.a \
 191     libswresample/libswresample.a ],
 192   [ . ])
 193
 194 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 195   ver_ffmpeg="ffmpeg.git"
 196 fi
 197
 198 PKG_3RD([fftw],[auto],
 199   [fftw-3.3.8],
 200   [ .libs/libfftw3.a \
 201     libbench2/libbench2.a \
 202     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 203     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 204     rdft/scalar/.libs/librdft_scalar.a \
 205     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 206     rdft/.libs/librdft.a \
 207     api/.libs/libapi.a \
 208     reodft/.libs/libreodft.a \
 209     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 210     dft/scalar/.libs/libdft_scalar.a \
 211     dft/.libs/libdft.a \
 212     kernel/.libs/libkernel.a \
 213     simd-support/.libs/libsimd_support.a ],
 214   [ api ])
 215
 216 PKG_3RD([flac],[auto],
 217   [flac-1.3.2],
 218   [ src/libFLAC/.libs/libFLAC.a \
 219     src/libFLAC++/.libs/libFLAC++.a \
 220     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 221     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 222     src/share/grabbag/.libs/libgrabbag.a \
 223     src/share/utf8/.libs/libutf8.a \
 224     src/test_libs_common/.libs/libtest_libs_common.a ],
 225   [ include ])
 226
 227 PKG_3RD([giflib],[yes],
 228   [giflib-5.1.4],
 229   [ lib/.libs/libgif.a \
 230     util/libgetarg.a ],
 231   [ lib ])
 232
 233 PKG_3RD([ilmbase],[auto],
 234   [ilmbase-2.2.1],
 235   [ Iex/.libs/libIex.a \
 236     IexMath/.libs/libIexMath.a \
 237     Half/.libs/libHalf.a \
 238     Imath/.libs/libImath.a \
 239     IlmThread/.libs/libIlmThread.a ],
 240   [ Iex Half Imath config IlmThread ])
 241
 242 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 243
 244 PKG_3RD([lame],[auto],
 245   [lame-3.100],
 246   [ libmp3lame/.libs/libmp3lame.a \
 247     mpglib/.libs/libmpgdecoder.a ],
 248   [ include ])
 249
 250 PKG_3RD([libavc1394],[auto],
 251   [libavc1394-0.5.4],
 252   [ libavc1394/.libs/libavc1394.a \
 253     librom1394/.libs/librom1394.a \
 254     common/.libs/libraw1394util.a ],
 255   [ . ])
 256
 257 PKG_3RD([libraw1394],[auto],
 258   [libraw1394-2.1.2],
 259   [ src/.libs/libraw1394.a ],
 260   [ . ])
 261
 262 PKG_3RD([libiec61883],[auto],
 263   [libiec61883-1.2.0],
 264   [ src/.libs/libiec61883.a ],
 265   [ src ])
 266
 267 PKG_3RD([libdv],[auto],
 268   [libdv-1.0.0],
 269   [ libdv/.libs/libdv.a ],
 270   [ . ])
 271
 272 PKG_3RD([libjpeg],[auto],
 273   [libjpeg-turbo-1.5.1],
 274   [ .libs/libjpeg.a \
 275     .libs/libturbojpeg.a \
 276     simd/.libs/libsimd.a ],
 277   [ . ])
 278
 279 PKG_3RD([opus],[auto],
 280   [opus-1.3],
 281   [ .libs/libopus.a ],
 282   [ include ])
 283
 284 PKG_3RD([openjpeg],[auto],
 285   [openjpeg-2.3.0],
 286   [ bin/libopenjp2.a ],
 287   [ src/lib/openjp2 ])
 288
 289 PKG_3RD([libogg],[auto],
 290   [libogg-1.3.3],
 291   [ src/.libs/libogg.a ],
 292   [ include ])
 293
 294 PKG_3RD([libsndfile],[auto],
 295   [libsndfile-1.0.28],
 296   [ src/.libs/libsndfile.a \
 297     src/.libs/libcommon.a \
 298     src/G72x/.libs/libg72x.a \
 299     src/GSM610/.libs/libgsm.a ],
 300   [ . ])
 301
 302 PKG_3RD([libtheora],[auto],
 303   [libtheora-1.1.1],
 304   [ lib/.libs/libtheora.a \
 305     lib/.libs/libtheoradec.a \
 306     lib/.libs/libtheoraenc.a ],
 307   [ . ])
 308
 309 PKG_3RD([libuuid],[yes],
 310   [libuuid-1.0.3],
 311   [ .libs/libuuid.a ],
 312   [ . ])
 313
 314 PKG_3RD([libvorbis],[auto],
 315   [libvorbis-1.3.6],
 316   [ lib/.libs/libvorbis.a \
 317     lib/.libs/libvorbisenc.a \
 318     lib/.libs/libvorbisfile.a ],
 319   [ include . ])
 320
 321 PKG_3RD([mjpegtools],[yes],
 322   [mjpegtools-2.1.0],
 323   [ utils/mmxsse/.libs/libmmxsse.a \
 324     utils/.libs/libmjpegutils.a \
 325     lavtools/.libs/liblavfile.a \
 326     lavtools/.libs/liblavjpeg.a \
 327     mplex/.libs/libmplex2.a \
 328     yuvfilters/.libs/libyuvfilters.a \
 329     mpeg2enc/.libs/libmpeg2encpp.a ],
 330   [ .  lavtools utils ])
 331
 332 PKG_3RD([openexr],[auto],
 333   [openexr-2.2.1],
 334   [ IlmImf/.libs/libIlmImf.a \
 335     IlmImfUtil/.libs/libIlmImfUtil.a ],
 336   [ IlmImf config ])
 337
 338 #PKG_3RD([festival],[no],
 339 #  [festival],
 340 #  [],
 341 #  [])
 342 #PKG_3RD(speech_tools,[no],
 343 #  [speech_tools],
 344 #  [],
 345 #  [])
 346 #
 347 PKG_3RD([tiff],[auto],
 348   [tiff-4.0.10],
 349   [ libtiff/.libs/libtiff.a \
 350     libtiff/.libs/libtiffxx.a \
 351     port/.libs/libport.a ],[
 352    . ])
 353
 354 PKG_3RD([twolame],[auto],
 355   [twolame-0.3.13],
 356   [ libtwolame/.libs/libtwolame.a ],
 357   [  libtwolame ])
 358
 359 PKG_3RD([x264],[auto],
 360   [x264-snapshot-20190117-2245-stable],
 361   [ libx264.a ],
 362   [ . ])
 363
 364 PKG_3RD([x265],[auto],
 365   [x265_3.0],
 366   [ libx265.a ],
 367   [ . source ])
 368
 369 PKG_3RD([libvpx],[auto],
 370   [libvpx-1.7.0],
 371   [ libvpx.a ],
 372   [ . ])
 373
 374 PKG_3RD([lv2],[auto],
 375   [lv2-1.14.0],
 376   [ ],
 377   [ usr/local/include usr/local/lib64/lv2 usr/local/lib/lv2 ])
 378
 379 PKG_3RD([sratom],[auto],
 380   [sratom-0.6.0],
 381   [ usr/local/lib/libsratom-0.a ],
 382   [ usr/local/include ])
 383
 384 PKG_3RD([serd],[auto],
 385   [serd-0.28.0],
 386   [ usr/local/lib/libserd-0.a ],
 387   [ usr/local/include ])
 388
 389 PKG_3RD([sord],[auto],
 390   [sord-0.16.0],
 391   [ usr/local/lib/libsord-0.a ],
 392   [ usr/local/include ])
 393
 394 PKG_3RD([lilv],[auto],
 395   [lilv-0.24.2],
 396   [ usr/local/lib/liblilv-0.a ],
 397   [ usr/local/include ])
 398
 399 PKG_3RD([suil],[auto],
 400   [suil-0.8.4],
 401   [ usr/local/lib/libsuil-0.a ],
 402   [ usr/local/include ])
 403
 404 PKG_3RD([libaom],[auto],
 405   [libaom-v1.0.0],
 406   [ usr/local/lib*/libaom*.a ],
 407   [ usr/local/include ])
 408
 409 PKG_3RD([libwebp],[auto],
 410   [libwebp-1.0.2],
 411   [ usr/local/lib*/libwebp*.a ],
 412   [ usr/local/include ])
 413
 414 AC_SUBST(STATIC_PKGS)
 415
 416 AC_DEFUN([CHECK_ENABLE], [
 417 AC_ARG_ENABLE([$1],
 418   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 419   [WANT_$2=$enableval], [WANT_$2=[$4]])
 420 ])
 421
 422 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 423 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 424 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10bit], [no])
 425
 426 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 427
 428 AC_DEFUN([CHECK_PROG], [
 429  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 430 ])
 431 AC_DEFUN([REQUIRE_PROG], [
 432  CHECK_PROG([$1],[$2])
 433  if test "x$PROG_$1" = "xno"; then
 434    AC_MSG_WARN([$2 is missing and required.])
 435    FATAL_ERROR=1
 436  fi
 437 ])
 438
 439 # Checks for programs.
 440
 441 REQUIRE_PROG(NASM, [nasm])
 442 REQUIRE_PROG(YASM, [yasm])
 443 REQUIRE_PROG(OBJCOPY, [objcopy])
 444 if test "x$FATAL_ERROR" != "x"; then
 445  AC_MSG_ERROR("fatal eror.")
 446 fi
 447 CHECK_PROG(PACTL, [pactl])
 448 WANT_PACTL=$PROG_PACTL
 449
 450 # libx264 nasm fix
 451 AC_MSG_CHECKING([nasm x264 compatible])
 452 echo "vmovdqa32 [[eax]]{k1}{z}, zmm0" > conftest.asm
 453 nasm conftest.asm -o conftest.o > /dev/null 2>&1
 454 if test $? != 0 ; then
 455  AC_MSG_RESULT([no])
 456  AC_MSG_WARN([libx264 built without assembly code])
 457  X264_CFG_PARAMS="$X264_CFG_PARAMS --disable-asm"
 458 else
 459  AC_MSG_RESULT([yes])
 460 fi
 461 rm -f conftest.asm conftest.o
 462
 463 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 464 if test "$no_utf" = "yes"; then
 465   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 466 fi
 467
 468 # Checks for headers/libraries.
 469
 470 AC_DEFUN([CHECK_HEADERS], [
 471 if test "x$HAVE_$1" != "xno"; then
 472  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 473   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 474 ]])])
 475  AC_SUBST([HAVE_$1])
 476  AC_MSG_CHECKING([$2])
 477  AC_MSG_RESULT([$HAVE_$1])
 478  if test "x$HAVE_$1" = "xno"; then
 479   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 480  fi
 481 fi
 482 ])
 483
 484 AC_DEFUN([CHECK_LIB], [
 485 if test "x$HAVE_$1" != "xno"; then
 486  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno" -a "x$PKG_$1" = "xauto"; then
 487   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 488   AC_SUBST([HAVE_$1])
 489   if test "x$HAVE_$1" = "xyes"; then
 490    if test "x$PKG_$1" = "x"; then
 491     SYSTEM_LIBS+=" -l[$2]"
 492     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 493    else
 494     SHARED_$1+=" -l[$2]"
 495     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 496    fi
 497   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 498  fi
 499 fi
 500 ])
 501
 502 CHECK_LIB([X11], [X11], [XOpenDisplay])
 503 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 504 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 505 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 506 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 507 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 508 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 509 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 510 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 511 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 512 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 513 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 514 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 515 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 516 CHECK_LIB([PNG], [png], [png_read_png])
 517 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 518 CHECK_LIB([Z], [z], [gzopen])
 519 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 520 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 521 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 522 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 523 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 524 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 525 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 526 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 527 CHECK_LIB([lame], [mp3lame], [lame_init])
 528 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 529 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 530 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 531 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 532 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 533 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 534 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 535 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 536 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 537 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 538 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 539 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 540 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 541 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 542 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 543 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 544 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 545 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 546 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 547 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 548 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 549 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 550 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 551 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 552 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 553 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 554 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 555 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 556 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 557 CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 558 CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])
 559 CHECK_LIB([libaom], [aom], [aom_codec_version])
 560 CHECK_HEADERS([libaom], [libaom headers], [aom/aom.h])
 561 CHECK_LIB([libwebp], [webp], [WebPGetEncoderVersion])
 562 CHECK_HEADERS([libwebp], [libwebp headers], [webp/encode.h])
 563 CHECK_LIB([a52dec], [a52], [a52_init])
 564 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 565 CHECK_LIB([encore], [encore], [encore])
 566 CHECK_HEADERS([encore], [encore headers], [encore.h])
 567 CHECK_LIB([giflib], [gif], [DGifOpen])
 568 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 569 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 570 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 571
 572 #if test "x$HAVE_mjpegtools" = "xyes"; then
 573 #CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
 574 #fi
 575
 576 AC_DEFUN([CHECK_WANT], [
 577 RESULT=yes
 578 # WANT_$1
 579 if test "x$WANT_$1" != "xno" ; then
 580 AC_ARG_WITH(m4_tolower([$1]),
 581  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 582   [WANT_$1=$withval],[WANT_$1=$2])
 583  m4_quote($4)
 584  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 585   if test "x$WANT_$1" = "xyes" ; then
 586     AC_MSG_ERROR([required for $1 support.])
 587   fi
 588   echo "=== want $1 Failed."
 589   WANT_$1=no
 590  elif test "x$WANT_$1" = "xauto" ; then
 591   WANT_$1=yes
 592  fi
 593 fi
 594 CFG_WANTS+=" $1"
 595 AC_SUBST([WANT_$1])
 596 ])
 597
 598 CHECK_WANT([GL], [auto], [use opengl], [
 599  CHECK_LIB([GL], [GL], [glUseProgram])
 600  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 601  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 602
 603 CHECK_WANT([OSS], [auto], [use OSS audio], [
 604  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 605
 606 CHECK_WANT([XFT], [auto], [use libXft], [
 607  CHECK_LIB([XFT], [Xft], [XftInit])
 608  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 609
 610 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 611  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 612  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 613
 614 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 615  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 616  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 617  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 618  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 619  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 620  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 621  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 622  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 623
 624 CHECK_WANT([DV], [auto], [use dv], [
 625  CHECK_LIB([libdv], [dv], [dv_init])
 626  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 627
 628 CHECK_WANT([DVB], [auto], [use dvb], [
 629  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 630
 631 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 632  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 633
 634 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 635  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 636
 637 CHECK_WANT([ESOUND], [no], [use esd], [
 638  CHECK_LIB([esound], [esd], [esd_open_sound])
 639  CHECK_HEADERS([esound], [esound headers], [esd.h])
 640  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 641  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 642
 643 CHECK_WANT([SHUTTLE_USB], [yes], [use libusb-1.0], [
 644  CHECK_LIB([libusbx], [usb-1.0], [libusb_init])
 645  CHECK_HEADERS([libusbx], [libusb headers], [libusb-1.0/libusb.h])])
 646
 647 CHECK_WANT([LV2], [auto], [use lv2], [
 648  saved_CFLAGS="$CFLAGS"
 649  CHECK_LIB([lilv], [lilv-0], [lilv_world_new])
 650  CHECK_LIB([sord], [sord-0], [sord_world_new])
 651  CHECK_LIB([serd], [serd-0], [serd_reader_new])
 652  CHECK_LIB([sratom], [sratom-0], [sratom_new])
 653  CFLAGS="-I/usr/include/lilv-0 -I/usr/local/include/lilv-0"
 654  CHECK_HEADERS([lv2], [lilv headers], [lilv/lilv.h])
 655  CHECK_LIB([suil], [suil-0], [suil_instance_new])
 656  CFLAGS="-I/usr/include/suil-0 -I/usr/local/include/suil-0"
 657  CHECK_HEADERS([lv2], [suil headers], [suil/suil.h])
 658  CFLAGS="$saved_CFLAGS"])
 659
 660 CHECK_WANT([DL], [auto], [system has libdl], [
 661  CHECK_LIB([DL], [dl], [dlopen])])
 662
 663 CHECK_WANT([EXR], [auto], [use exr], [])
 664
 665 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 666 ])
 667
 668 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 669  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 670
 671 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 672  AC_MSG_CHECKING([for openexr available])
 673  saved_LIBS="$LIBS"
 674  saved_CXXFLAGS="$CXXFLAGS"
 675  # ilmbase libs
 676  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 677  CXXFLAGS="-I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 678  AC_LANG_PUSH(C++)
 679  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 680 #include "ImfChannelList.h"
 681 #include "ImfChromaticities.h"
 682 #include "ImfCompression.h"
 683 #include "ImfIO.h"
 684 #include "ImfInputFile.h"
 685 #include "ImfOutputFile.h"
 686 #include "ImfPixelType.h"
 687 #include "ImfRgbaFile.h"
 688 #include "ImfRgbaYca.h"
 689 #include "ImfVersion.h"
 690 class EXRIStream : public Imf::IStream { public:
 691 EXRIStream() : Imf::IStream("mypath") {} };
 692 class EXROStream : public Imf::OStream { public:
 693 EXROStream() : Imf::OStream("mypath") {} };
 694 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 695  RESULT="$HAVE_OPENEXR"
 696  if test "x$RESULT" = "xyes"; then
 697    SHARED_openexr="$LIBS"
 698    CFG_CFLAGS+=" -I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 699  fi
 700  LIBS="$saved_LIBS"
 701  CXXFLAGS="$saved_CXXFLAGS"
 702  AC_LANG_POP(C++)
 703  AC_MSG_RESULT([$HAVE_OPENEXR])
 704 ])
 705 AC_SUBST([HAVE_OPENEXR])
 706
 707 # build global_config
 708 OBJDIR=`uname -m`
 709 AC_SUBST(OBJDIR)
 710
 711 echo "AC_HELP_STRING([Reason],[Package])"
 712 echo "AC_HELP_STRING([------],[-------])"
 713
 714 AC_DEFUN([PKG_DISABLED],[
 715  PKG_$1="no"
 716  BUILD_$1=0
 717  AC_SUBST(BUILD_$1)
 718  echo "AC_HELP_STRING([disabled],[$1])"
 719 ])
 720 AC_DEFUN([PKG_SHARED],[
 721  BUILD_$1=0
 722  AC_SUBST(BUILD_$1)
 723  SHARED_LIBS+="$SHARED_$1"
 724 ])
 725
 726 AC_DEFUN([PKG_STATIC],[
 727  if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 728   PKG_$1="yes"
 729   BUILD_$1=1
 730   AC_SUBST(BUILD_$1)
 731   STATIC_BLDS+=" [$1]"
 732   echo "AC_HELP_STRING([$2],[$1])"
 733  fi
 734 ])
 735
 736 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 737
 738 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 739 # order matters
 740 for dep in \
 741         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 742         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 \
 743         libiec61883/libraw1394 libavc1394/librom1394 \
 744         openexr/ilmbase ilmbase/libogg \
 745         libtheora/libogg libtheora/libvorbis ; do
 746   lib=`dirname $dep`;  needs=`basename $dep`
 747   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 748   if test "x$pkg_lib" != "xno"; then
 749     eval "PKG_$needs=yes"
 750   fi
 751 done
 752 fi
 753
 754 AC_DEFUN([PKG_PROVIDE],[
 755 if test "x$BUILD_$1" = "x" ; then
 756  if test "x$PKG_$1" = "xyes"; then
 757   PKG_FORCED([$1])
 758  elif test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 759   PKG_DISABLED([$1])
 760  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 761   PKG_STATIC([$1],[static])
 762  elif test "x$HAVE_$1" = "xyes"; then
 763   PKG_SHARED([$1])
 764  else
 765   PKG_STATIC([$1],[needed])
 766  fi
 767 fi
 768 ])
 769
 770 PKG_PROVIDE([a52dec])
 771 PKG_PROVIDE([djbfft])
 772 PKG_PROVIDE([encore])
 773 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 774 PKG_PROVIDE([esound],[$WANT_ESOUND])
 775 PKG_PROVIDE([ffmpeg])
 776 PKG_PROVIDE([fftw])
 777 PKG_PROVIDE([flac])
 778 PKG_PROVIDE([giflib])
 779 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 780 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 781 PKG_PROVIDE([lame])
 782 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 783 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 784 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 785 PKG_PROVIDE([libdv],[$WANT_DV])
 786 PKG_PROVIDE([libjpeg])
 787 PKG_PROVIDE([libogg])
 788 PKG_PROVIDE([libsndfile])
 789 PKG_PROVIDE([libtheora])
 790 PKG_PROVIDE([libuuid])
 791 PKG_PROVIDE([libvorbis])
 792 PKG_PROVIDE([mjpegtools])
 793 PKG_PROVIDE([libaom])
 794 PKG_PROVIDE([libwebp])
 795 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 796 PKG_PROVIDE([openjpeg])
 797 PKG_PROVIDE([tiff])
 798 PKG_PROVIDE([twolame])
 799 PKG_PROVIDE([x264])
 800 PKG_PROVIDE([x265])
 801 PKG_PROVIDE([libvpx])
 802 PKG_PROVIDE([opus])
 803 PKG_PROVIDE([lv2], [$WANT_LV2])
 804 PKG_PROVIDE([lilv], [$WANT_LV2])
 805 PKG_PROVIDE([sratom], [$WANT_LV2])
 806 PKG_PROVIDE([serd], [$WANT_LV2])
 807 PKG_PROVIDE([sord], [$WANT_LV2])
 808 PKG_PROVIDE([suil], [$WANT_LV2])
 809
 810 if test "x$WANT_LV2" = "xyes"; then
 811   if test "x$HAVE_lv2" = "xyes" -a "x$BUILD_lilv" = "x0"; then
 812     CFG_CFLAGS+=' -I/usr/include/lilv-0 -I/usr/local/include/lilv-0'
 813     CFG_CFLAGS+=' -I/usr/include/suil-0 -I/usr/local/include/suil-0'
 814   fi
 815 fi
 816
 817 AC_SUBST(STATIC_BLDS)
 818 for f in $SHARED_LIBS; do
 819   echo "AC_HELP_STRING([shared],[$f])"
 820 done
 821 AC_SUBST(SHARED_LIBS)
 822 for f in $SYSTEM_LIBS; do
 823   echo "AC_HELP_STRING([system],[$f])"
 824 done
 825 AC_SUBST(SYSTEM_LIBS)
 826
 827 echo ""
 828 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 829   CFG_CFLAGS+=" -DHAVE_CIN_3RDPARTY"
 830 fi
 831 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 832          VIDEO4LINUX2 ESOUND PACTL OPENEXR LV2 \
 833          COMMERCIAL LIBZMPEG SHUTTLE SHUTTLE_USB; do
 834   eval vv="\$WANT_$v"
 835   if test "x$vv" != "xno"; then
 836     CFG_CFLAGS+=" -DHAVE_$v"
 837     vv=with
 838   else
 839     vv=without
 840   fi
 841   v=`echo "$v" | tr "A-Z" "a-z"`
 842   echo "  using: $vv-$v"
 843 done
 844
 845 echo "  using: with-jobs = $WANT_JOBS"
 846 echo "  using: exec-name = $WANT_CIN"
 847 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 848 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 849 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 850 echo "  using: with-browser = $WANT_CIN_BROWSER"
 851 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 852 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 853 echo "  using: with-opencv = $WANT_OPENCV"
 854 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 855 echo "  using: with-noelision = $WANT_NOELISION"
 856 echo "  using: with-booby = $WANT_BOOBY"
 857 echo "  using: with-libzmpeg = $WANT_LIBZMPEG"
 858 echo "  using: with-commerical = $WANT_COMMERCIAL"
 859 echo ""
 860 echo "  using: thirdparty build = $WANT_CIN_3RDPARTY"
 861 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 862 echo "  using: static-build = $WANT_STATIC_BUILD"
 863 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 864 echo ""
 865
 866 # build extras
 867 if test "x$HAVE_tiff" = "xyes"; then
 868   if test "x$HAVE_jbig" = "xyes"; then
 869     EXTRA_LIBS+=' -ljbig'
 870   fi
 871 fi
 872 if test "x$HAVE_NUMA" = "xyes"; then
 873   EXTRA_LIBS+=' -lnuma'
 874 fi
 875 if test "x$HAVE_DL" = "xyes"; then
 876   EXTRA_LIBS+=' -ldl'
 877   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 878 fi
 879 if test "x$WANT_BOOBY" != "xno"; then
 880   CFG_CFLAGS+=" -DBOOBY"
 881 fi
 882
 883 # intel lock elision bugs
 884 if test "x$WANT_NOELISION" != "xno"; then
 885   CFG_RPATH=`ls -1fd 2> /dev/null \
 886  /usr/lib/noelision \
 887  /lib/noelision \
 888  /usr/lib64/noelision \
 889  /lib64/noelision \
 890   | tail -1`
 891 fi
 892
 893 AC_SUBST(WANT_CIN_3RDPARTY)
 894 AC_SUBST(EXTRA_LIBS)
 895 AC_SUBST(FFMPEG_EXTRA_CFG)
 896 AC_SUBST(WANT_X264_HIDEPTH)
 897 AC_SUBST(WANT_X265_HIDEPTH)
 898
 899 AC_SUBST(CFG_CFLAGS)
 900 AC_SUBST(CFG_CXXFLAGS)
 901
 902 AC_CONFIG_FILES([Makefile])
 903 AC_OUTPUT
 904
 905 exec > global_config
 906
 907 echo "SHELL := /bin/bash"
 908 echo "export SHELL"
 909 echo "WANT_JOBS := $WANT_JOBS"
 910 echo ""
 911 echo "OBJDIR := $OBJDIR"
 912 echo "BINDIR := \$(TOPDIR)/bin"
 913 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 914 echo "GUICAST := \$(TOPDIR)/guicast"
 915 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 916 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 917 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 918 echo "PLUGINS := \$(TOPDIR)/plugins"
 919 echo "TDB := \$(TOPDIR)/db"
 920 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 921 echo "EXTRA_LIBS := $EXTRA_LIBS"
 922 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 923 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 924 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 925 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 926 echo ""
 927
 928 echo "WANT_CIN := $WANT_CIN"
 929 CFG_WANTS+=" CIN_3RDPARTY LIBZMPEG COMMERCIAL"
 930 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 931 echo ""
 932
 933 echo "ifndef CFLAGS_"
 934 echo "ifdef CFLAGS"
 935 echo "CFLAGS_ := \$(CFLAGS)"
 936 echo "else"
 937 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 938 echo "endif"
 939 echo "endif"
 940 echo "ifndef CXXFLAGS_"
 941 echo "ifdef CXXFLAGS"
 942 echo "CXXFLAGS_ := \$(CXXFLAGS)"
 943 echo "endif"
 944 echo "endif"
 945 echo "ifndef LDFLAGS_"
 946 echo "ifdef LDFLAGS"
 947 echo "LDFLAGS_ := \$(LDFLAGS)"
 948 echo "endif"
 949 echo "endif"
 950
 951 echo "CFLAGS := \$(CFLAGS_)"
 952 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 953 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 954 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 955 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 956 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 957 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 958 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 959 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 960 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 961 echo ""
 962 if test "x$CFG_CXXFLAGS" != "x"; then
 963   for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 964   echo ""
 965 fi
 966 if test "x$CFG_LDFLAGS" != "x" ; then
 967   echo "LDFLAGS +=$CFG_LDFLAGS"
 968   echo ""
 969 fi
 970
 971 if test "x$WANT_X264_HIDEPTH" = "xyes" ; then
 972   X264_CFG_PARAMS="$X264_CFG_PARAMS --bit-depth=10"
 973 fi
 974 if test "x$WANT_X265_HIDEPTH" = "xyes" ; then
 975   X265_CFG_PARAMS="$X265_CFG_PARAMS -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
 976 fi
 977
 978 for pkg in $STATIC_PKGS; do
 979   eval pkg_lib="\$PKG_$pkg"
 980   if test "x$pkg_lib" = "xno"; then continue; fi;
 981   echo "static_pkgs += $pkg"
 982 done
 983 echo ""
 984
 985 for pkg in $STATIC_BLDS; do
 986   echo "static_blds += $pkg"
 987   ver_pkg=ver_$pkg
 988   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 989   inc_pkg=inc_$pkg
 990   echo "$inc_pkg := \\"
 991   for inc in ${!inc_pkg}; do
 992     echo "  -I\$($ver_pkg)/$inc \\"
 993   done
 994   echo ""
 995   echo "static_incs += \$(inc_$pkg)"
 996   lib_pkg=lib_$pkg
 997   echo "$lib_pkg := \\"
 998   for lib in ${!lib_pkg}; do
 999     echo "  \$($ver_pkg)/$lib \\"
1000   done
1001   echo ""
1002   echo "static_libs += \$($lib_pkg)"
1003   echo ""
1004 done
1005 echo ""
1006
1007 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
1008 echo ""
1009 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
1010 echo "export static_pkgs static_blds shared_libs system_libs"
1011 echo ""
1012
1013 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
1014
1015 if test "x$CFG_RPATH" != "x"; then
1016   echo "libraries+= -Wl,-rpath=$CFG_RPATH"
1017 fi
1018
1019 echo "libraries += -Wl,--start-group"
1020 echo "libraries += \$(thirdparty_libraries)"
1021 echo "libraries += \$(system_libs)"
1022 echo "libraries += \$(EXTRA_LIBS)"
1023 echo "libraries += -Wl,--end-group"
1024 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
1025 echo "libraries += \$(thirdparty_libraries)"
1026 echo "libraries += \$(system_libs)"
1027 echo "libraries += \$(EXTRA_LIBS)"
1028 echo ""
1029 echo "export thirdparty_libraries libraries"
1030 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
1031 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
1032
1033 if test "x$HAVE_tiff" = "xyes"; then
1034   if test "x$HAVE_jbig" != "xyes"; then
1035     echo "tiff.cfg_params+= --disable-jbig"
1036   fi
1037 fi
1038
1039 if test "x$WANT_GIT_FFMPEG" != "xno"; then
1040   echo "ffmpeg.git := $WANT_GIT_FFMPEG"
1041 fi
1042 if test "x$X264_CFG_PARAMS" != "x" ; then
1043   echo "x264.cfg_params :=$X264_CFG_PARAMS --enable-static --enable-pic"
1044 fi
1045 if test "x$X265_CFG_PARAMS" != "x" ; then
1046   echo "x265.cfg_params :=$X265_CFG_PARAMS -DENABLE_SHARED=no"
1047 fi