cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-gg.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 #  this is extra work, not a gain...
  15 CFG_CFLAGS+=" -Wno-unknown-warning-option"
  16 CFG_CFLAGS+=" -Wno-attributes"
  17 CFG_CFLAGS+=" -Wno-unused-result"
  18 CFG_CFLAGS+=" -Wno-stringop-overflow"
  19 CFG_CFLAGS+=" -Wno-format-truncation"
  20 CFG_CFLAGS+=" -Wno-format-overflow"
  21 CFG_CFLAGS+=" -Wno-parentheses"
  22 CFG_CFLAGS+=" -Wno-stringop-truncation"
  23 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  24 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  25 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  26 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  27 CFG_CFLAGS+=" -I/usr/include -I/usr/local/include"
  28 CFG_CFLAGS+=" -I/usr/include/freetype2 -I/usr/local/include/freetype2"
  29 CFG_CFLAGS+=" -I/usr/include/uuid -I/usr/local/include/uuid"
  30 CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
  31
  32 CFG_LDFLAGS+=" -z noexecstack"
  33
  34 AC_DEFUN([CHECK_WITH], [
  35 AC_ARG_WITH([$1],
  36   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  37   [WANT_$3=$withval], [WANT_$3='$4'])
  38 AC_SUBST([WANT_$3])
  39 ])
  40
  41 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  42 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  43 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  44 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  45 CHECK_WITH([lv2],[lv2 library support],[LV2],[yes])
  46 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  47 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  48 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  49 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  50 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  51 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  52 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  53 CHECK_WITH([noelision],[use noelision/libpthread],[NOELISION],[auto])
  54 CHECK_WITH([booby],[window lock trace booby trap],[BOOBY],[no])
  55 CHECK_WITH([libzmpeg],[build libzmpeg],[LIBZMPEG],[yes])
  56 CHECK_WITH([commercial],[enable commercial capture],[COMMERCIAL],[yes])
  57 CHECK_WITH([thirdparty],[use thirdparty build],[CIN_3RDPARTY],[yes])
  58 CHECK_WITH([shuttle],[shuttle device],[SHUTTLE],[yes])
  59 CHECK_WITH([wintv],[usb 2040:826d wintv device],[WINTV],[yes])
  60 CHECK_WITH([vaapi],[video acceleration api],[VAAPI],[yes])
  61 CHECK_WITH([vdpau],[video decode+presentation api for unix],[VDPAU],[yes])
  62 CHECK_WITH([nv],[nvenc/nvdec ffnvcodec api],[NV],[yes])
  63 CHECK_WITH([cuda],[nv cuda plugins],[CUDA],[auto])
  64 CHECK_WITH([clang],[use clang instead of gcc/g++],[CLANG],[no])
  65
  66 if test "x$WANT_LV2" != "xno"; then
  67   GTK2_LIBS=`pkg-config --libs gtk+-2.0`
  68   AC_CHECK_LIB([m], [gtk_init], [HAVE_gtk=yes], [HAVE_gtk=no], [$GTK2_LIBS])
  69   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --cflags gtk+-2.0`" && HAVE_gtk=no
  70   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --libs gtk+-2.0`" && HAVE_gtk=no
  71   if test "x$HAVE_gtk" = "xno"; then
  72     AC_MSG_ERROR([LV2 requires gtk+-2.0 support.])
  73   fi
  74 fi
  75
  76 if test "x$WANT_COMMERCIAL" = "xyes" -a "x$WANT_LIBZMPEG" != "xyes" ; then
  77   AC_MSG_ERROR([commercial requires libzmpeg support.])
  78 fi
  79
  80 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  81   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  82   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  83   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  84   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  85   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  86 else
  87   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  88     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  89     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  90     echo "$dir"`
  91   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  92     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  93     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  94     echo "$dir"`
  95   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  96     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  97     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  98     echo "$dir"`
  99   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
 100        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
 101   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
 102     usrlib+="64"
 103   WANT_LOCALE_DIR="$lcldir"
 104   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
 105   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
 106   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
 107   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
 108 fi
 109
 110 CIN_INSTALLS=""
 111 CIN_UNINSTALLS=""
 112 if test "x$WANT_LIBZMPEG" = "xyes"; then
 113   CIN_INSTALLS+=" zmp_install"
 114   CIN_UNINSTALLS+=" zmp_uninstall"
 115 fi
 116 if test "x$WANT_COMMERCIAL" = "xyes"; then
 117   CIN_INSTALLS+=" com_install"
 118   CIN_UNINSTALLS+=" com_uninstall"
 119 fi
 120 if test "x$WANT_LADSPA_BUILD" = "xyes"; then
 121   CIN_INSTALLS+=" lad_install "
 122   CIN_UNINSTALLS+=" lad_uninstall "
 123 fi
 124 if test "x$WANT_LV2" = "xyes"; then
 125   CIN_INSTALLS+=" lv2_install "
 126   CIN_UNINSTALLS+=" lv2_uninstall "
 127 fi
 128 AC_SUBST(CIN_INSTALLS)
 129 AC_SUBST(CIN_UNINSTALLS)
 130
 131 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
 132   MAK_INSTALLS="dvl_install"
 133   MAK_UNINSTALLS="dvl_uninstall"
 134 else
 135   MAK_INSTALLS=" sys_install"
 136   MAK_UNINSTALLS="sys_uninstall"
 137 fi
 138 AC_SUBST(MAK_INSTALLS)
 139 AC_SUBST(MAK_UNINSTALLS)
 140
 141 if test "x$WANT_JOBS" = "xauto"; then
 142   CPUS=`grep -c "^proc" /proc/cpuinfo`
 143   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
 144 fi
 145
 146 AC_DEFUN([PKG_DEF],[
 147 STATIC_PKGS+=" [$1]"
 148 ver_$1="$2"
 149 lib_$1="$3"
 150 inc_$1="$4"
 151 ])
 152
 153 AC_DEFUN([PKG_3RD],[
 154 AC_ARG_ENABLE([$1],
 155   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
 156   [PKG_$1=$enableval], [PKG_$1=$2])
 157 PKG_DEF([$1],[$3],[$4],[$5])
 158 ])
 159
 160 # thirdparty builds
 161
 162 PKG_3RD([a52dec],[yes],
 163   [a52dec-0.7.4],
 164   [ liba52/.libs/liba52.a ],
 165   [ include ])
 166
 167 PKG_3RD([djbfft],[yes],
 168   [djbfft-0.76],
 169   [ libdjbfft.a ],
 170   [ . ])
 171
 172 PKG_3RD([audiofile],[no],
 173   [audiofile-0.3.6],
 174   [ libaudiofile/.libs/libaudiofile.a \
 175     libaudiofile/modules/.libs/libmodules.a \
 176     libaudiofile/alac/.libs/libalac.a ],
 177   [ libaudiofile ])
 178
 179 PKG_3RD([encore],[no],
 180   [encore-5.0],
 181   [ \$(OBJDIR)/libencore.a ],
 182   [ . ])
 183
 184 PKG_3RD([esound],[no],
 185   [esound-0.2.41],
 186   [ .libs/libesd.a \
 187     .libs/libesddsp.a ],
 188   [ . ])
 189
 190 PKG_3RD([ffmpeg],[yes],
 191   [ffmpeg-4.2],
 192   [ libavutil/libavutil.a \
 193     libavcodec/libavcodec.a \
 194     libpostproc/libpostproc.a \
 195     libavdevice/libavdevice.a \
 196     libavformat/libavformat.a \
 197     libswscale/libswscale.a \
 198     libavfilter/libavfilter.a \
 199     libswresample/libswresample.a ],
 200   [ . ])
 201
 202 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 203   ver_ffmpeg="ffmpeg.git"
 204 fi
 205
 206 PKG_3RD([fftw],[auto],
 207   [fftw-3.3.8],
 208   [ .libs/libfftw3.a \
 209     libbench2/libbench2.a \
 210     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 211     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 212     rdft/scalar/.libs/librdft_scalar.a \
 213     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 214     rdft/.libs/librdft.a \
 215     api/.libs/libapi.a \
 216     reodft/.libs/libreodft.a \
 217     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 218     dft/scalar/.libs/libdft_scalar.a \
 219     dft/.libs/libdft.a \
 220     kernel/.libs/libkernel.a \
 221     simd-support/.libs/libsimd_support.a ],
 222   [ api ])
 223
 224 PKG_3RD([flac],[auto],
 225   [flac-1.3.2],
 226   [ src/libFLAC/.libs/libFLAC.a \
 227     src/libFLAC++/.libs/libFLAC++.a \
 228     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 229     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 230     src/share/grabbag/.libs/libgrabbag.a \
 231     src/share/utf8/.libs/libutf8.a \
 232     src/test_libs_common/.libs/libtest_libs_common.a ],
 233   [ include ])
 234
 235 PKG_3RD([giflib],[yes],
 236   [giflib-5.1.6],
 237   [ libgif.a ],
 238   [ . ])
 239
 240 PKG_3RD([ilmbase],[auto],
 241   [ilmbase-2.2.1],
 242   [ Iex/.libs/libIex.a \
 243     IexMath/.libs/libIexMath.a \
 244     Half/.libs/libHalf.a \
 245     Imath/.libs/libImath.a \
 246     IlmThread/.libs/libIlmThread.a ],
 247   [ Iex Half Imath config IlmThread ])
 248
 249 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 250
 251 PKG_3RD([lame],[auto],
 252   [lame-3.100],
 253   [ libmp3lame/.libs/libmp3lame.a \
 254     mpglib/.libs/libmpgdecoder.a ],
 255   [ include ])
 256
 257 PKG_3RD([libavc1394],[auto],
 258   [libavc1394-0.5.4],
 259   [ libavc1394/.libs/libavc1394.a \
 260     librom1394/.libs/librom1394.a \
 261     common/.libs/libraw1394util.a ],
 262   [ . ])
 263
 264 PKG_3RD([libraw1394],[auto],
 265   [libraw1394-2.1.2],
 266   [ src/.libs/libraw1394.a ],
 267   [ . ])
 268
 269 PKG_3RD([libiec61883],[auto],
 270   [libiec61883-1.2.0],
 271   [ src/.libs/libiec61883.a ],
 272   [ src ])
 273
 274 PKG_3RD([libdv],[auto],
 275   [libdv-1.0.0],
 276   [ libdv/.libs/libdv.a ],
 277   [ . ])
 278
 279 PKG_3RD([libjpeg],[auto],
 280   [libjpeg-turbo-1.5.1],
 281   [ .libs/libjpeg.a \
 282     .libs/libturbojpeg.a \
 283     simd/.libs/libsimd.a ],
 284   [ . ])
 285
 286 PKG_3RD([opus],[auto],
 287   [opus-1.3],
 288   [ .libs/libopus.a ],
 289   [ include ])
 290
 291 PKG_3RD([openjpeg],[auto],
 292   [openjpeg-2.3.0],
 293   [ bin/libopenjp2.a ],
 294   [ src/lib/openjp2 ])
 295
 296 PKG_3RD([libogg],[auto],
 297   [libogg-1.3.3],
 298   [ src/.libs/libogg.a ],
 299   [ include ])
 300
 301 PKG_3RD([libsndfile],[auto],
 302   [libsndfile-1.0.28],
 303   [ src/.libs/libsndfile.a \
 304     src/.libs/libcommon.a \
 305     src/G72x/.libs/libg72x.a \
 306     src/GSM610/.libs/libgsm.a ],
 307   [ . ])
 308
 309 PKG_3RD([libtheora],[auto],
 310   [libtheora-1.1.1],
 311   [ lib/.libs/libtheora.a \
 312     lib/.libs/libtheoradec.a \
 313     lib/.libs/libtheoraenc.a ],
 314   [ . ])
 315
 316 PKG_3RD([libuuid],[yes],
 317   [libuuid-1.0.3],
 318   [ .libs/libuuid.a ],
 319   [ . ])
 320
 321 PKG_3RD([libvorbis],[auto],
 322   [libvorbis-1.3.6],
 323   [ lib/.libs/libvorbis.a \
 324     lib/.libs/libvorbisenc.a \
 325     lib/.libs/libvorbisfile.a ],
 326   [ include . ])
 327
 328 PKG_3RD([mjpegtools],[yes],
 329   [mjpegtools-2.1.0],
 330   [ utils/mmxsse/.libs/libmmxsse.a \
 331     utils/.libs/libmjpegutils.a \
 332     lavtools/.libs/liblavfile.a \
 333     lavtools/.libs/liblavjpeg.a \
 334     mplex/.libs/libmplex2.a \
 335     yuvfilters/.libs/libyuvfilters.a \
 336     mpeg2enc/.libs/libmpeg2encpp.a ],
 337   [ .  lavtools utils ])
 338
 339 PKG_3RD([openexr],[auto],
 340   [openexr-2.2.1],
 341   [ IlmImf/.libs/libIlmImf.a \
 342     IlmImfUtil/.libs/libIlmImfUtil.a ],
 343   [ IlmImf config ])
 344
 345 #PKG_3RD([festival],[no],
 346 #  [festival],
 347 #  [],
 348 #  [])
 349 #PKG_3RD(speech_tools,[no],
 350 #  [speech_tools],
 351 #  [],
 352 #  [])
 353 #
 354 PKG_3RD([tiff],[auto],
 355   [tiff-4.0.10],
 356   [ libtiff/.libs/libtiff.a \
 357     libtiff/.libs/libtiffxx.a \
 358     port/.libs/libport.a ],[
 359    . ])
 360
 361 PKG_3RD([twolame],[auto],
 362   [twolame-0.3.13],
 363   [ libtwolame/.libs/libtwolame.a ],
 364   [  libtwolame ])
 365
 366 PKG_3RD([x264],[auto],
 367   [x264-snapshot-20190117-2245-stable],
 368   [ libx264.a ],
 369   [ . ])
 370
 371 PKG_3RD([x265],[auto],
 372   [x265_3.1.2],
 373   [ libx265.a ],
 374   [ . source ])
 375
 376 PKG_3RD([libvpx],[auto],
 377   [libvpx-1.8.1],
 378   [ libvpx.a ],
 379   [ . ])
 380
 381 PKG_3RD([lv2],[auto],
 382   [lv2-1.16.0],
 383   [ ],
 384   [ usr/local/include usr/local/lib64/lv2 usr/local/lib/lv2 ])
 385
 386 PKG_3RD([sratom],[auto],
 387   [sratom-0.6.2],
 388   [ usr/local/lib/libsratom-0.a ],
 389   [ usr/local/include ])
 390
 391 PKG_3RD([serd],[auto],
 392   [serd-0.30.0],
 393   [ usr/local/lib/libserd-0.a ],
 394   [ usr/local/include ])
 395
 396 PKG_3RD([sord],[auto],
 397   [sord-0.16.2],
 398   [ usr/local/lib/libsord-0.a ],
 399   [ usr/local/include ])
 400
 401 PKG_3RD([lilv],[auto],
 402   [lilv-0.24.4],
 403   [ usr/local/lib/liblilv-0.a ],
 404   [ usr/local/include ])
 405
 406 PKG_3RD([suil],[auto],
 407   [suil-0.10.2],
 408   [ usr/local/lib/libsuil-0.a ],
 409   [ usr/local/include ])
 410
 411 PKG_3RD([libaom],[auto],
 412   [libaom-v1.0.0],
 413   [ usr/local/lib*/libaom*.a ],
 414   [ usr/local/include ])
 415
 416 PKG_3RD([dav1d],[auto],
 417   [dav1d-0.5.0],
 418   [ usr/local/lib*/libdav1d*.a ],
 419   [ usr/local/include ])
 420
 421 PKG_3RD([libwebp],[auto],
 422   [libwebp-1.0.2],
 423   [ usr/local/lib*/libwebp*.a ],
 424   [ usr/local/include ])
 425
 426 PKG_3RD([ffnvcodec],[auto],
 427   [ffnvcodec],
 428   [ ],
 429   [ . ])
 430
 431 AC_SUBST(STATIC_PKGS)
 432
 433 AC_DEFUN([CHECK_ENABLE], [
 434 AC_ARG_ENABLE([$1],
 435   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 436   [WANT_$2=$enableval], [WANT_$2=[$4]])
 437 ])
 438
 439 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 440 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 441 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10bit], [no])
 442
 443 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 444
 445 AC_DEFUN([CHECK_PROG], [
 446  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 447 ])
 448 AC_DEFUN([REQUIRE_PROG], [
 449  CHECK_PROG([$1],[$2])
 450  if test "x$PROG_$1" = "xno"; then
 451    AC_MSG_WARN([$2 is missing and required.])
 452    FATAL_ERROR=1
 453  fi
 454 ])
 455
 456 ## arch dep tests
 457 ARCH=[`uname -m`]
 458 I86=[`expr "x$ARCH" : 'xi[346]86.*'`]
 459 X86=[`expr "x$ARCH" : 'x..._64*'`]
 460
 461 if test "x$I86$X86" != "x00" ; then
 462   # Checks for ix86 programs.
 463   REQUIRE_PROG(NASM, [nasm])
 464   # libx264 nasm fix
 465   AC_MSG_CHECKING([nasm x264 compatible])
 466   echo "vmovdqa32 [[eax]]{k1}{z}, zmm0" > conftest.asm
 467   nasm conftest.asm -o conftest.o > /dev/null 2>&1
 468   if test $? != 0 ; then
 469    AC_MSG_RESULT([no])
 470    AC_MSG_WARN([libx264 built without assembly code])
 471    X264_CFG_PARAMS="$X264_CFG_PARAMS --disable-asm"
 472   else
 473    AC_MSG_RESULT([yes])
 474   fi
 475   rm -f conftest.asm conftest.o
 476   REQUIRE_PROG(YASM, [yasm])
 477 fi
 478
 479 ## end arch dep tests
 480
 481 REQUIRE_PROG(OBJCOPY, [objcopy])
 482 if test "x$FATAL_ERROR" != "x"; then
 483  AC_MSG_ERROR("fatal eror.")
 484 fi
 485 CHECK_PROG(PACTL, [pactl])
 486 WANT_PACTL=$PROG_PACTL
 487
 488 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 489 if test "$no_utf" = "yes"; then
 490   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 491 fi
 492
 493 # Checks for headers/libraries.
 494
 495 AC_DEFUN([CHECK_HEADERS], [
 496 if test "x$HAVE_$1" != "xno"; then
 497  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 498   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 499 ]])])
 500  AC_SUBST([HAVE_$1])
 501  AC_MSG_CHECKING([$2])
 502  AC_MSG_RESULT([$HAVE_$1])
 503  if test "x$HAVE_$1" = "xno"; then
 504   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 505  fi
 506 fi
 507 ])
 508
 509 AC_DEFUN([CHECK_LIB], [
 510 if test "x$HAVE_$1" != "xno"; then
 511  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno" -a "x$PKG_$1" = "xauto"; then
 512   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 513   AC_SUBST([HAVE_$1])
 514   if test "x$WANT_$1" != "xno"; then
 515    if test "x$HAVE_$1" = "xyes"; then
 516     if test "x$PKG_$1" = "x"; then
 517      SYSTEM_LIBS+=" -l[$2]"
 518      for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 519     else
 520      SHARED_$1+=" -l[$2]"
 521      for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 522     fi
 523    elif test "x$PKG_$1" = "x"; then
 524     RESULT=no
 525    fi
 526   fi
 527  fi
 528 fi
 529 ])
 530
 531 CHECK_LIB([X11], [X11], [XOpenDisplay])
 532 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 533 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 534 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 535 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 536 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 537 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 538 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 539 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 540 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 541 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 542 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 543 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 544 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 545 CHECK_LIB([PNG], [png], [png_read_png])
 546 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 547 CHECK_LIB([Z], [z], [gzopen])
 548 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 549 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 550 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 551 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 552 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 553 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 554 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 555 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 556 CHECK_LIB([lame], [mp3lame], [lame_init])
 557 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 558 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 559 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 560 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 561 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 562 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 563 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 564 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 565 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 566 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 567 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 568 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 569 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 570 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 571 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 572 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 573 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 574 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 575 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 576 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 577 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 578 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 579 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 580 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 581 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 582 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 583 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 584 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 585 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 586 CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 587 CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])
 588 CHECK_LIB([libaom], [aom], [aom_codec_version])
 589 CHECK_HEADERS([libaom], [libaom headers], [aom/aom.h])
 590 CHECK_LIB([dav1d], [dav1d], [dav1d_version])
 591 CHECK_HEADERS([dav1d], [libdav1d headers], [dav1d/dav1d.h])
 592 CHECK_LIB([libwebp], [webp], [WebPGetEncoderVersion])
 593 CHECK_HEADERS([libwebp], [libwebp headers], [webp/encode.h])
 594 CHECK_LIB([a52dec], [a52], [a52_init])
 595 CHECK_HEADERS([a52dec], [a52 headers], [stdint.h a52.h])
 596 CHECK_LIB([encore], [encore], [encore])
 597 CHECK_HEADERS([encore], [encore headers], [encore.h])
 598 CHECK_LIB([giflib], [gif], [DGifOpen])
 599 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 600 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 601
 602 CHECK_LIB([VDPAU], [vdpau], [vdp_device_create_x11])
 603 if test "x$HAVE_VDPAU" != "xyes" -a "x$WANT_VDPAU" = "xyes"; then
 604   AC_MSG_ERROR([requires vdpau support.])
 605 fi
 606
 607 CHECK_LIB([VAAPI], [va], [vaInitialize])
 608 if test "x$HAVE_VAAPI" = "xyes" -a "x$WANT_VAAPI" != "xno"; then
 609   CHECK_HEADERS([vaapi_x11], [va x11 headers], [va/va_x11.h])
 610   CHECK_LIB([vaapi_x11], [va-x11], [vaGetDisplay])
 611   CHECK_HEADERS([vaapi_drm], [va drm headers], [va/va_drm.h])
 612   CHECK_LIB([vaapi_drm], [va-drm], [vaGetDisplayDRM])
 613 fi
 614 if test "x$HAVE_VAAPI" != "xyes" -a "x$WANT_VAAPI" = "xyes"; then
 615   AC_MSG_ERROR([requires vaapi support.])
 616 fi
 617
 618 #CHECK_LIB([NVENC], [nvidia-encode], [NvEncodeAPICreateInstance])
 619
 620 #if test "x$HAVE_mjpegtools" = "xyes"; then
 621 #CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
 622 #fi
 623
 624 AC_DEFUN([CHECK_WANT], [
 625 RESULT=yes
 626 # WANT_$1
 627 if test "x$WANT_$1" != "xno" ; then
 628 AC_ARG_WITH(m4_tolower([$1]),
 629  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 630   [WANT_$1=$withval],[WANT_$1=$2])
 631  m4_quote($4)
 632  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 633   if test "x$WANT_$1" = "xyes" ; then
 634     AC_MSG_ERROR([required for $1 support.])
 635   fi
 636   WANT_$1=no
 637  elif test "x$WANT_$1" = "xauto" ; then
 638   WANT_$1=yes
 639  fi
 640 fi
 641 CFG_WANTS+=" $1"
 642 AC_SUBST([WANT_$1])
 643 ])
 644
 645 CHECK_WANT([GL], [auto], [use opengl], [
 646  CHECK_LIB([GL], [GL], [glUseProgram])
 647  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 648  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 649
 650 CHECK_WANT([OSS], [auto], [use OSS audio], [
 651  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 652
 653 CHECK_WANT([XFT], [auto], [use libXft], [
 654  CHECK_LIB([XFT], [Xft], [XftInit])
 655  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 656
 657 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 658  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 659  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 660
 661 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 662  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 663  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 664  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 665  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 666  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 667  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 668  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 669  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 670
 671 CHECK_WANT([DV], [auto], [use dv], [
 672  CHECK_LIB([libdv], [dv], [dv_init])
 673  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 674
 675 CHECK_WANT([DVB], [auto], [use dvb], [
 676  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 677
 678 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 679  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 680
 681 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 682  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 683
 684 CHECK_WANT([ESOUND], [no], [use esd], [
 685  CHECK_LIB([esound], [esd], [esd_open_sound])
 686  CHECK_HEADERS([esound], [esound headers], [esd.h])
 687  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 688  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 689
 690 CHECK_WANT([SHUTTLE], [yes], [shuttle dev support], [
 691  CHECK_HEADERS([keysyms], [x11 keysym defs], [X11/keysymdef.h])])
 692 if test "x$WANT_SHUTTLE" = "xno"; then
 693  WANT_SHUTTLE_USB="no"
 694 fi
 695 CHECK_WANT([SHUTTLE_USB], [yes], [use libusb-1.0], [
 696  CHECK_LIB([libusbx], [usb-1.0], [libusb_init])
 697  CHECK_HEADERS([libusbx], [libusb headers], [libusb-1.0/libusb.h])])
 698
 699 CHECK_WANT([LV2], [auto], [use lv2], [
 700  saved_CFLAGS="$CFLAGS"
 701  CHECK_LIB([lilv], [lilv-0], [lilv_world_new])
 702  CHECK_LIB([sord], [sord-0], [sord_world_new])
 703  CHECK_LIB([serd], [serd-0], [serd_reader_new])
 704  CHECK_LIB([sratom], [sratom-0], [sratom_new])
 705  CFLAGS="-I/usr/include/lilv-0 -I/usr/local/include/lilv-0"
 706  CHECK_HEADERS([lv2], [lilv headers], [lilv/lilv.h])
 707  CHECK_LIB([suil], [suil-0], [suil_instance_new])
 708  CFLAGS="-I/usr/include/suil-0 -I/usr/local/include/suil-0"
 709  CHECK_HEADERS([lv2], [suil headers], [suil/suil.h])
 710  CFLAGS="$saved_CFLAGS"])
 711
 712 CHECK_WANT([CUDA], [auto], [build cuda plugins], [
 713   CHECK_HEADERS([CUDA], [cuda sdk], [${CUDA_PATH:-/usr/local/cuda}/include/cuda.h])])
 714
 715 CHECK_WANT([DL], [auto], [system has libdl], [
 716  CHECK_LIB([DL], [dl], [dlopen])])
 717
 718 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 719 ])
 720
 721 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 722  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 723
 724 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 725  AC_MSG_CHECKING([for openexr available])
 726  saved_LIBS="$LIBS"
 727  saved_CXXFLAGS="$CXXFLAGS"
 728  # ilmbase libs
 729  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 730  CXXFLAGS="-I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 731  AC_LANG_PUSH(C++)
 732  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 733 #include "ImfChannelList.h"
 734 #include "ImfChromaticities.h"
 735 #include "ImfCompression.h"
 736 #include "ImfIO.h"
 737 #include "ImfInputFile.h"
 738 #include "ImfOutputFile.h"
 739 #include "ImfPixelType.h"
 740 #include "ImfRgbaFile.h"
 741 #include "ImfRgbaYca.h"
 742 #include "ImfVersion.h"
 743 class EXRIStream : public Imf::IStream { public:
 744 EXRIStream() : Imf::IStream("mypath") {} };
 745 class EXROStream : public Imf::OStream { public:
 746 EXROStream() : Imf::OStream("mypath") {} };
 747 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 748  RESULT="$HAVE_OPENEXR"
 749  if test "x$RESULT" = "xyes"; then
 750    SHARED_openexr="$LIBS"
 751    CFG_CFLAGS+=" -I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 752  fi
 753  LIBS="$saved_LIBS"
 754  CXXFLAGS="$saved_CXXFLAGS"
 755  AC_LANG_POP(C++)
 756  AC_MSG_RESULT([$HAVE_OPENEXR])
 757 ])
 758 AC_SUBST([HAVE_OPENEXR])
 759
 760 # build global_config
 761 OBJDIR=`uname -m`
 762 AC_SUBST(OBJDIR)
 763
 764 echo "AC_HELP_STRING([Reason],[Package])"
 765 echo "AC_HELP_STRING([------],[-------])"
 766
 767 AC_DEFUN([PKG_DISABLED],[
 768  PKG_$1="no"
 769  BUILD_$1=0
 770  AC_SUBST(BUILD_$1)
 771  echo "AC_HELP_STRING([disabled],[$1])"
 772 ])
 773 AC_DEFUN([PKG_SHARED],[
 774  PKG_$1="shared"
 775  BUILD_$1=0
 776  AC_SUBST(BUILD_$1)
 777  SHARED_LIBS+="$SHARED_$1"
 778 ])
 779
 780 AC_DEFUN([PKG_STATIC],[
 781  if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 782   PKG_$1="yes"
 783   BUILD_$1=1
 784   AC_SUBST(BUILD_$1)
 785   STATIC_BLDS+=" [$1]"
 786   echo "AC_HELP_STRING([$2],[$1])"
 787  fi
 788 ])
 789
 790 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 791
 792 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 793 # order matters
 794 for dep in \
 795         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 796         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 \
 797         libiec61883/libraw1394 libavc1394/librom1394 \
 798         openexr/ilmbase ilmbase/libogg \
 799         libtheora/libogg libtheora/libvorbis ; do
 800   lib=`dirname $dep`;  needs=`basename $dep`
 801   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 802   if test "x$pkg_lib" != "xno"; then
 803     eval "PKG_$needs=yes"
 804   fi
 805 done
 806 fi
 807
 808 AC_DEFUN([PKG_PROVIDE],[
 809 if test "x$BUILD_$1" = "x" ; then
 810  if test "x$PKG_$1" = "xyes"; then
 811   PKG_FORCED([$1])
 812  elif test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 813   PKG_DISABLED([$1])
 814  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 815   PKG_STATIC([$1],[static])
 816  elif test "x$HAVE_$1" = "xyes"; then
 817   PKG_SHARED([$1])
 818  else
 819   PKG_STATIC([$1],[needed])
 820  fi
 821 fi
 822 ])
 823
 824 PKG_PROVIDE([a52dec])
 825 PKG_PROVIDE([djbfft])
 826 PKG_PROVIDE([encore])
 827 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 828 PKG_PROVIDE([esound],[$WANT_ESOUND])
 829 PKG_PROVIDE([ffmpeg])
 830 PKG_PROVIDE([fftw])
 831 PKG_PROVIDE([flac])
 832 PKG_PROVIDE([giflib])
 833 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 834 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 835 PKG_PROVIDE([lame])
 836 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 837 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 838 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 839 PKG_PROVIDE([libdv],[$WANT_DV])
 840 PKG_PROVIDE([libjpeg])
 841 PKG_PROVIDE([libogg])
 842 PKG_PROVIDE([libsndfile])
 843 PKG_PROVIDE([libtheora])
 844 PKG_PROVIDE([libuuid])
 845 PKG_PROVIDE([libvorbis])
 846 PKG_PROVIDE([mjpegtools])
 847 PKG_PROVIDE([libaom])
 848 PKG_PROVIDE([dav1d])
 849 PKG_PROVIDE([libwebp])
 850 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 851 PKG_PROVIDE([openjpeg])
 852 PKG_PROVIDE([tiff])
 853 PKG_PROVIDE([twolame])
 854 PKG_PROVIDE([x264])
 855 PKG_PROVIDE([x265])
 856 PKG_PROVIDE([libvpx])
 857 PKG_PROVIDE([opus])
 858 PKG_PROVIDE([lv2], [$WANT_LV2])
 859 PKG_PROVIDE([lilv], [$WANT_LV2])
 860 PKG_PROVIDE([sratom], [$WANT_LV2])
 861 PKG_PROVIDE([serd], [$WANT_LV2])
 862 PKG_PROVIDE([sord], [$WANT_LV2])
 863 PKG_PROVIDE([suil], [$WANT_LV2])
 864 PKG_PROVIDE([ffnvcodec], [$WANT_NV])
 865
 866 if test "x$WANT_LV2" = "xyes"; then
 867   if test "x$HAVE_lv2" = "xyes" -a "x$BUILD_lilv" = "x0"; then
 868     CFG_CFLAGS+=' -I/usr/include/lilv-0 -I/usr/local/include/lilv-0'
 869     CFG_CFLAGS+=' -I/usr/include/suil-0 -I/usr/local/include/suil-0'
 870   fi
 871 fi
 872
 873 AC_SUBST(STATIC_BLDS)
 874 for f in $SHARED_LIBS; do
 875   echo "AC_HELP_STRING([shared],[$f])"
 876 done
 877 AC_SUBST(SHARED_LIBS)
 878 for f in $SYSTEM_LIBS; do
 879   echo "AC_HELP_STRING([system],[$f])"
 880 done
 881 AC_SUBST(SYSTEM_LIBS)
 882
 883 echo ""
 884 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 885   CFG_CFLAGS+=" -DHAVE_CIN_3RDPARTY"
 886 fi
 887 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 888          VIDEO4LINUX2 ESOUND PACTL OPENEXR LV2 \
 889          COMMERCIAL LIBZMPEG SHUTTLE SHUTTLE_USB \
 890          VAAPI VDPAU CUDA NV WINTV; do
 891   eval vv="\$WANT_$v"
 892   if test "x$vv" != "xno"; then
 893     CFG_CFLAGS+=" -DHAVE_$v"
 894     vv=with
 895   else
 896     vv=without
 897   fi
 898   v=`echo "$v" | tr "A-Z" "a-z"`
 899   echo "  using: $vv-$v"
 900 done
 901
 902 # build extras
 903 if test "x$WANT_CLANG" = "xyes" ; then
 904   FFMPEG_EXTRA_CFG+=' --cc=clang --cxx=clang++'
 905 fi
 906 if test "x$HAVE_tiff" = "xyes"; then
 907   if test "x$HAVE_jbig" = "xyes"; then
 908     EXTRA_LIBS+=' -ljbig'
 909   fi
 910 fi
 911 if test "x$HAVE_NUMA" = "xyes"; then
 912   EXTRA_LIBS+=' -lnuma'
 913 fi
 914
 915 FFMPEG_EXTRA_LDFLAGS=""
 916 if test "x$WANT_VAAPI" != "xno" -a "x$HAVE_VAAPI" = "xyes"; then
 917   FFMPEG_EXTRA_LDFLAGS+=' -lva'
 918   EXTRA_LIBS+=' -lva'
 919   WANT_VAAPI="yes"
 920   if test "x$HAVE_vaapi_x11" = "xyes"; then
 921     FFMPEG_EXTRA_LDFLAGS+=' -lva-x11'
 922     EXTRA_LIBS+=' -lva-x11'
 923   fi
 924   if test "x$HAVE_vaapi_drm" = "xyes"; then
 925     FFMPEG_EXTRA_LDFLAGS+=' -lva-drm'
 926     EXTRA_LIBS+=' -lva-drm'
 927   fi
 928 fi
 929 CFG_WANTS+=" VAAPI"
 930
 931 if test "x$WANT_VDPAU" != "xno" -a "x$HAVE_VDPAU" = "xyes"; then
 932   WANT_VDPAU="yes"
 933 fi
 934 CFG_WANTS+=" VDPAU"
 935
 936 if test "x$WANT_NV" != "xno"; then
 937   WANT_NV="yes"
 938   CFG_WANTS+=" NV"
 939 fi
 940
 941 if test "x$HAVE_DL" = "xyes"; then
 942   EXTRA_LIBS+=' -ldl'
 943   FFMPEG_EXTRA_LDFLAGS+=' -ldl'
 944 fi
 945 if test "x$FFMPEG_EXTRA_LDFLAGS" != "x"; then
 946   FFMPEG_EXTRA_CFG+=' --extra-ldflags="'$FFMPEG_EXTRA_LDFLAGS'"'
 947 fi
 948
 949 if test "x$WANT_BOOBY" != "xno"; then
 950   CFG_CFLAGS+=" -DBOOBY"
 951 fi
 952
 953 # intel lock elision bugs
 954 if test "x$WANT_NOELISION" != "xno"; then
 955   CFG_RPATH=`ls -1fd 2> /dev/null \
 956  /usr/lib/noelision \
 957  /lib/noelision \
 958  /usr/lib64/noelision \
 959  /lib64/noelision \
 960   | tail -1`
 961 fi
 962
 963 echo "  using: with-jobs = $WANT_JOBS"
 964 echo "  using: exec-name = $WANT_CIN"
 965 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 966 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 967 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 968 echo "  using: with-browser = $WANT_CIN_BROWSER"
 969 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 970 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 971 echo "  using: with-opencv = $WANT_OPENCV"
 972 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 973 echo "  using: with-noelision = $WANT_NOELISION"
 974 echo "  using: with-booby = $WANT_BOOBY"
 975 echo "  using: with-clang = $WANT_CLANG"
 976 echo ""
 977 echo "  using: thirdparty build = $WANT_CIN_3RDPARTY"
 978 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 979 echo "  using: static-build = $WANT_STATIC_BUILD"
 980 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 981 echo ""
 982
 983 AC_SUBST(WANT_CIN_3RDPARTY)
 984 AC_SUBST(EXTRA_LIBS)
 985 AC_SUBST(FFMPEG_EXTRA_CFG)
 986 AC_SUBST(WANT_X264_HIDEPTH)
 987 AC_SUBST(WANT_X265_HIDEPTH)
 988
 989 AC_SUBST(CFG_CFLAGS)
 990 AC_SUBST(CFG_CXXFLAGS)
 991
 992 AC_CONFIG_FILES([Makefile])
 993 AC_OUTPUT
 994
 995 exec > global_config
 996
 997 echo "SHELL := /bin/bash"
 998 echo "export SHELL"
 999 echo "WANT_JOBS := $WANT_JOBS"
1000 if test "x$WANT_CLANG" = "xyes" ; then
1001   echo "CC = clang"
1002   echo "CXX = clang++"
1003   echo "export CC CXX"
1004 fi
1005 echo ""
1006 echo "OBJDIR := $OBJDIR"
1007 echo "BINDIR := \$(TOPDIR)/bin"
1008 echo "CINELERRA := \$(TOPDIR)/cinelerra"
1009 echo "GUICAST := \$(TOPDIR)/guicast"
1010 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
1011 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
1012 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
1013 echo "PLUGINS := \$(TOPDIR)/plugins"
1014 echo "TDB := \$(TOPDIR)/db"
1015 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
1016 echo "EXTRA_LIBS := $EXTRA_LIBS"
1017 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
1018 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
1019 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
1020 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
1021 echo ""
1022
1023 echo "WANT_CIN := $WANT_CIN"
1024 CFG_WANTS+=" CIN_3RDPARTY LIBZMPEG COMMERCIAL STATIC_BUILD"
1025 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
1026 echo ""
1027
1028 echo "ifndef CFLAGS_"
1029 echo "ifdef CFLAGS"
1030 echo "CFLAGS_ := \$(CFLAGS)"
1031 echo "else"
1032 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
1033 echo "endif"
1034 echo "endif"
1035 echo "ifndef CXXFLAGS_"
1036 echo "ifdef CXXFLAGS"
1037 echo "CXXFLAGS_ := \$(CXXFLAGS)"
1038 echo "endif"
1039 echo "endif"
1040 echo "ifndef LDFLAGS_"
1041 echo "ifdef LDFLAGS"
1042 echo "LDFLAGS_ := \$(LDFLAGS)"
1043 echo "endif"
1044 echo "endif"
1045
1046 echo "CFLAGS := \$(CFLAGS_)"
1047 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
1048 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
1049 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
1050 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
1051 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
1052 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
1053 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
1054 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
1055 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
1056 echo ""
1057 if test "x$CFG_CXXFLAGS" != "x"; then
1058   for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
1059   echo ""
1060 fi
1061 if test "x$CFG_LDFLAGS" != "x" ; then
1062   echo "LDFLAGS +=$CFG_LDFLAGS"
1063   echo ""
1064 fi
1065
1066 if test "x$WANT_X264_HIDEPTH" = "xyes" ; then
1067   X264_CFG_PARAMS="$X264_CFG_PARAMS --bit-depth=10"
1068 fi
1069 if test "x$WANT_X265_HIDEPTH" = "xyes" ; then
1070   X265_CFG_PARAMS="$X265_CFG_PARAMS -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
1071 fi
1072
1073 for pkg in $STATIC_PKGS; do
1074   eval pkg_lib="\$PKG_$pkg"
1075   if test "x$pkg_lib" = "xyes"; then
1076     echo "static_pkgs += $pkg"
1077   elif test "x$pkg_lib" = "xshared"; then
1078     echo "shared_pkgs += $pkg"
1079   fi
1080 done
1081 echo ""
1082
1083 for pkg in $STATIC_BLDS; do
1084   echo "static_blds += $pkg"
1085   ver_pkg=ver_$pkg
1086   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
1087   inc_pkg=inc_$pkg
1088   echo "$inc_pkg := \\"
1089   for inc in ${!inc_pkg}; do
1090     echo "  -I\$($ver_pkg)/$inc \\"
1091   done
1092   echo ""
1093   echo "static_incs += \$(inc_$pkg)"
1094   lib_pkg=lib_$pkg
1095   echo "$lib_pkg := \\"
1096   for lib in ${!lib_pkg}; do
1097     echo "  \$($ver_pkg)/$lib \\"
1098   done
1099   echo ""
1100   echo "static_libs += \$($lib_pkg)"
1101   echo ""
1102 done
1103 echo ""
1104
1105 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
1106 echo ""
1107 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
1108 echo "export static_pkgs shared_pkgs static_blds shared_libs system_libs"
1109 echo ""
1110
1111 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
1112
1113 if test "x$CFG_RPATH" != "x"; then
1114   echo "libraries+= -Wl,-rpath=$CFG_RPATH"
1115 fi
1116
1117 echo "libraries += -Wl,--start-group"
1118 echo "libraries += \$(thirdparty_libraries)"
1119 echo "libraries += \$(shared_libs)"
1120 echo "libraries += \$(system_libs)"
1121 echo "libraries += \$(EXTRA_LIBS)"
1122 echo "libraries += -Wl,--end-group"
1123 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
1124 echo "libraries += \$(thirdparty_libraries)"
1125 echo "libraries += \$(shared_libs)"
1126 echo "libraries += \$(system_libs)"
1127 echo "libraries += \$(EXTRA_LIBS)"
1128 echo ""
1129 echo "export thirdparty_libraries libraries"
1130 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
1131 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
1132
1133 if test "x$HAVE_tiff" = "xyes"; then
1134   if test "x$HAVE_jbig" != "xyes"; then
1135     echo "tiff.cfg_params+= --disable-jbig"
1136   fi
1137 fi
1138
1139 if test "x$WANT_GIT_FFMPEG" != "xno"; then
1140   echo "ffmpeg.git := $WANT_GIT_FFMPEG"
1141 fi
1142 if test "x$X264_CFG_PARAMS" != "x" ; then
1143   echo "x264.cfg_params :=$X264_CFG_PARAMS --enable-static --enable-pic"
1144 fi
1145 if test "x$X265_CFG_PARAMS" != "x" ; then
1146   echo "x265.cfg_params :=$X265_CFG_PARAMS -DENABLE_SHARED=no"
1147 fi