cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall -Wno-unused-result"
  13 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  14 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  15 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  16 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  17 CFG_CFLAGS+=" -I/usr/include/freetype2"
  18
  19 AC_DEFUN([CHECK_WITH], [
  20 AC_ARG_WITH([$1],
  21   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  22   [WANT_$3=$withval], [WANT_$3='$4'])
  23 AC_SUBST([WANT_$3])
  24 ])
  25
  26 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  27 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  28 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  29 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  30 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  31 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  32 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  33 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  34 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  35
  36 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  37   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  38   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  39   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  40   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  41   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  42   sinstall=dinstall
  43   suninstall=duninstall
  44 else
  45   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  46     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  47     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  48     echo "$dir"`
  49   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  50     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  51     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  52     echo "$dir"`
  53   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  54     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  55     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  56     echo "$dir"`
  57   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  58        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  59   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  60     usrlib+="64"
  61   WANT_LOCALE_DIR="$lcldir"
  62   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  63   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  64   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  65   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  66   sinstall=cinstall
  67   suninstall=cuninstall
  68 fi
  69 AC_SUBST(sinstall)
  70 AC_SUBST(suninstall)
  71
  72 if test "x$WANT_JOBS" = "xauto"; then
  73   CPUS=`grep -c "^proc" /proc/cpuinfo`
  74   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  75 fi
  76
  77 AC_DEFUN([PKG_DEF],[
  78 STATIC_PKGS+=" [$1]"
  79 ver_$1="$2"
  80 lib_$1="$3"
  81 inc_$1="$4"
  82 ])
  83
  84 AC_DEFUN([PKG_3RD],[
  85 AC_ARG_ENABLE([$1],
  86   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  87   [PKG_$1=$enableval], [PKG_$1=$2])
  88 PKG_DEF([$1],[$3],[$4],[$5])
  89 ])
  90
  91 # thirdparty builds
  92
  93 PKG_3RD([a52dec],[yes],
  94   [a52dec-0.7.4],
  95   [ liba52/.libs/liba52.a ],
  96   [ include ])
  97
  98 PKG_3RD([djbfft],[yes],
  99   [djbfft-0.76],
 100   [ libdjbfft.a ],
 101   [ . ])
 102
 103 PKG_3RD([audiofile],[no],
 104   [audiofile-0.3.6],
 105   [ libaudiofile/.libs/libaudiofile.a \
 106     libaudiofile/modules/.libs/libmodules.a \
 107     libaudiofile/alac/.libs/libalac.a ],
 108   [ libaudiofile ])
 109
 110 PKG_3RD([encore],[no],
 111   [encore-5.0],
 112   [ \$(OBJDIR)/libencore.a ],
 113   [ . ])
 114
 115 PKG_3RD([esound],[no],
 116   [esound-0.2.41],
 117   [ .libs/libesd.a \
 118     .libs/libesddsp.a ],
 119   [ . ])
 120
 121 PKG_3RD([faac],[auto],
 122   [faac-1.28],
 123   [ libfaac/.libs/libfaac.a ],
 124   [ include ])
 125
 126 PKG_3RD([faad2],[auto],
 127   [faad2-2.7],
 128   [ libfaad/.libs/libfaad.a \
 129     common/mp4ff/libmp4ff.a ],
 130   [ include ])
 131
 132 PKG_3RD([fdk],[auto],
 133   [fdk-aac-0.1.4],
 134   [ .libs/libfdk-aac.a ],
 135   [ libAACdec/include libAACenc/include libSYS/include ])
 136
 137 PKG_3RD([ffmpeg],[yes],
 138   [ffmpeg-3.1.4],
 139   [ libavutil/libavutil.a \
 140     libavcodec/libavcodec.a \
 141     libpostproc/libpostproc.a \
 142     libavdevice/libavdevice.a \
 143     libavformat/libavformat.a \
 144     libswscale/libswscale.a \
 145     libavfilter/libavfilter.a \
 146     libswresample/libswresample.a ],
 147   [ . ])
 148
 149 PKG_3RD([fftw],[auto],
 150   [fftw-3.3.4],
 151   [ .libs/libfftw3.a \
 152     libbench2/libbench2.a \
 153     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 154     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 155     rdft/scalar/.libs/librdft_scalar.a \
 156     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 157     rdft/.libs/librdft.a \
 158     api/.libs/libapi.a \
 159     reodft/.libs/libreodft.a \
 160     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 161     dft/scalar/.libs/libdft_scalar.a \
 162     dft/.libs/libdft.a \
 163     kernel/.libs/libkernel.a \
 164     simd-support/.libs/libsimd_support.a \
 165     simd-support/.libs/libsimd_sse2_nonportable.a ],
 166   [ api ])
 167
 168 PKG_3RD([flac],[auto],
 169   [flac-1.3.1],
 170   [ src/libFLAC/.libs/libFLAC.a \
 171     src/libFLAC++/.libs/libFLAC++.a \
 172     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 173     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 174     src/share/grabbag/.libs/libgrabbag.a \
 175     src/share/utf8/.libs/libutf8.a \
 176     src/test_libs_common/.libs/libtest_libs_common.a ],
 177   [ include ])
 178
 179 PKG_3RD([giflib],[yes],
 180   [giflib-5.1.2],
 181   [ lib/.libs/libgif.a \
 182     util/libgetarg.a ],
 183   [ lib ])
 184
 185 PKG_3RD([ilmbase],[auto],
 186   [ilmbase-2.2.0],
 187   [ Iex/.libs/libIex.a \
 188     IexMath/.libs/libIexMath.a \
 189     Half/.libs/libHalf.a \
 190     Imath/.libs/libImath.a \
 191     IlmThread/.libs/libIlmThread.a ],
 192   [ Iex Half Imath config IlmThread ])
 193
 194 PKG_DEF([ladspa], [ladspa-05182015], [], [])
 195
 196 PKG_3RD([lame],[auto],
 197   [lame-3.99.5],
 198   [ libmp3lame/.libs/libmp3lame.a \
 199     mpglib/.libs/libmpgdecoder.a ],
 200   [ include ])
 201
 202 PKG_3RD([libavc1394],[auto],
 203   [libavc1394-0.5.4],
 204   [ libavc1394/.libs/libavc1394.a \
 205     librom1394/.libs/librom1394.a \
 206     common/.libs/libraw1394util.a ],
 207   [ . ])
 208
 209 PKG_3RD([libraw1394],[auto],
 210   [libraw1394-2.0.5],
 211   [ src/.libs/libraw1394.a ],
 212   [ . ])
 213
 214 PKG_3RD([libiec61883],[auto],
 215   [libiec61883-1.2.0],
 216   [ src/.libs/libiec61883.a ],
 217   [ src ])
 218
 219 PKG_3RD([libdv],[auto],
 220   [libdv-1.0.0],
 221   [ libdv/.libs/libdv.a ],
 222   [ . ])
 223
 224 PKG_3RD([libjpeg],[auto],
 225   [libjpeg-turbo-1.4.0],
 226   [ .libs/libjpeg.a \
 227     .libs/libturbojpeg.a \
 228     simd/.libs/libsimd.a ],
 229   [ . ])
 230
 231 PKG_3RD([openjpeg],[auto],
 232   [openjpeg-2.1.0-20160221],
 233   [ bin/libopenjp2.a ],
 234   [ src/lib/openjp2 ])
 235
 236 PKG_3RD([libogg],[auto],
 237   [libogg-1.3.2],
 238   [ src/.libs/libogg.a ],
 239   [ include ])
 240
 241 PKG_3RD([libsndfile],[auto],
 242   [libsndfile-1.0.26],
 243   [ src/.libs/libsndfile.a \
 244     src/.libs/libcommon.a \
 245     src/G72x/.libs/libg72x.a \
 246     src/GSM610/.libs/libgsm.a ],
 247   [ . ])
 248
 249 PKG_3RD([libtheora],[auto],
 250   [libtheora-1.1.1],
 251   [ lib/.libs/libtheora.a \
 252     lib/.libs/libtheoradec.a \
 253     lib/.libs/libtheoraenc.a ],
 254   [ . ])
 255
 256 PKG_3RD([libuuid],[yes],
 257   [libuuid-1.0.3],
 258   [ .libs/libuuid.a ],
 259   [ . ])
 260
 261 PKG_3RD([libvorbis],[auto],
 262   [libvorbis-1.3.5],
 263   [ lib/.libs/libvorbis.a \
 264     lib/.libs/libvorbisenc.a \
 265     lib/.libs/libvorbisfile.a ],
 266   [ include . ])
 267
 268 PKG_3RD([mjpegtools],[yes],
 269   [mjpegtools-2.1.0],
 270   [ utils/mmxsse/.libs/libmmxsse.a \
 271     utils/.libs/libmjpegutils.a \
 272     lavtools/.libs/liblavfile.a \
 273     lavtools/.libs/liblavjpeg.a \
 274     mplex/.libs/libmplex2.a \
 275     yuvfilters/.libs/libyuvfilters.a \
 276     mpeg2enc/.libs/libmpeg2encpp.a ],
 277   [ .  lavtools utils ])
 278
 279 PKG_3RD([openexr],[auto],
 280   [openexr-2.2.0],
 281   [ IlmImf/.libs/libIlmImf.a \
 282     IlmImfUtil/.libs/libIlmImfUtil.a ],
 283   [ IlmImf config ])
 284
 285 #PKG_3RD([festival],[no],
 286 #  [festival],
 287 #  [],
 288 #  [])
 289 #PKG_3RD(speech_tools,[no],
 290 #  [speech_tools],
 291 #  [],
 292 #  [])
 293 #
 294 PKG_3RD([tiff],[auto],
 295   [tiff-3.8.2],
 296   [ libtiff/.libs/libtiff.a \
 297     libtiff/.libs/libtiffxx.a \
 298     port/.libs/libport.a ],[
 299    . ])
 300
 301 PKG_3RD([twolame],[auto],
 302   [twolame-0.3.13],
 303   [ libtwolame/.libs/libtwolame.a ],
 304   [  libtwolame ])
 305
 306 PKG_3RD([x264],[auto],
 307   [x264-snapshot-20160220-2245-stable],
 308   [ libx264.a ],
 309   [ . ])
 310
 311 PKG_3RD([x265],[auto],
 312   [x265_2.1],
 313   [ libx265.a ],
 314   [ . source ])
 315
 316 PKG_3RD([libvpx],[auto],
 317   [libvpx-1.5.0],
 318   [ libvpx.a ],
 319   [ . ])
 320
 321 AC_SUBST(STATIC_PKGS)
 322
 323 AC_DEFUN([CHECK_ENABLE], [
 324 AC_ARG_ENABLE([$1],
 325   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 326   [WANT_$2=$enableval], [WANT_$2=[$4]])
 327 ])
 328
 329 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 330 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 331 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10/12bit], [no])
 332
 333 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 334
 335 AC_DEFUN([CHECK_PROG], [
 336  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 337 ])
 338 AC_DEFUN([REQUIRE_PROG], [
 339  CHECK_PROG([$1],[$2])
 340  if test "x$PROG_$1" = "xno"; then
 341    AC_MSG_WARN([$2 is missing and required.])
 342    FATAL_ERROR=1
 343  fi
 344 ])
 345
 346 # Checks for programs.
 347
 348 REQUIRE_PROG(NASM, [nasm])
 349 REQUIRE_PROG(YASM, [yasm])
 350 REQUIRE_PROG(OBJCOPY, [objcopy])
 351 if test "x$FATAL_ERROR" != "x"; then
 352  AC_MSG_ERROR("fatal eror.")
 353 fi
 354 CHECK_PROG(PACTL, [pactl])
 355 WANT_PACTL=$PROG_PACTL
 356
 357 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 358 if test "$no_utf" = "yes"; then
 359   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 360 fi
 361
 362 # Checks for headers/libraries.
 363
 364 AC_DEFUN([CHECK_HEADERS], [
 365 if test "x$HAVE_$1" != "xno"; then
 366  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 367   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 368 ]])])
 369  AC_SUBST([HAVE_$1])
 370  AC_MSG_CHECKING([$2])
 371  AC_MSG_RESULT([$HAVE_$1])
 372  if test "x$HAVE_$1" = "xno"; then
 373   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 374  fi
 375 fi
 376 ])
 377
 378 AC_DEFUN([CHECK_LIB], [
 379 if test "x$HAVE_$1" != "xno"; then
 380  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 381   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 382   AC_SUBST([HAVE_$1])
 383   if test "x$HAVE_$1" = "xyes"; then
 384    if test "x$PKG_$1" = "x"; then
 385     SYSTEM_LIBS+=" -l[$2]"
 386     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 387    else
 388     SHARED_$1+=" -l[$2]"
 389     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 390    fi
 391   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 392  fi
 393 fi
 394 ])
 395
 396 CHECK_LIB([X11], [X11], [XOpenDisplay])
 397 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 398 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 399 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 400 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 401 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 402 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 403 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 404 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 405 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 406 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 407 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 408 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 409 CHECK_LIB([PNG], [png], [png_read_png])
 410 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 411 CHECK_LIB([Z], [z], [gzopen])
 412 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 413 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 414 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 415 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 416 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 417 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 418 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 419 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 420 CHECK_LIB([lame], [mp3lame], [lame_init])
 421 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 422 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 423 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 424 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 425 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 426 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 427 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 428 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 429 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 430 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 431 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 432 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 433 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 434 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 435 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 436 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 437 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 438 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 439 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 440 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 441 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 442 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 443 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 444 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 445 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 446 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 447 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 448 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 449 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 450 CHECK_LIB([a52dec], [a52], [a52_init])
 451 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 452 CHECK_LIB([encore], [encore], [encore])
 453 CHECK_HEADERS([encore], [encore headers], [encore.h])
 454 CHECK_LIB([faac], [faac], [faacEncOpen])
 455 CHECK_HEADERS([faac], [faac headers], [faac.h])
 456 CHECK_LIB([faad2], [faad], [faacDecInit])
 457 CHECK_HEADERS([faad2], [faad headers], [faad.h])
 458 CHECK_LIB([giflib], [gif], [DGifOpen])
 459 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 460 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 461 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 462
 463 #if test "x$HAVE_mjpegtools" = "xyes"; then
 464 #CFG_CFLAGS+=" -I/usr/include/mjpegtools"
 465 #fi
 466
 467 AC_DEFUN([CHECK_WANT], [
 468 RESULT=yes
 469 AC_ARG_WITH(m4_tolower([$1]),
 470  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 471   [WANT_$1=$withval],[WANT_$1=$2])
 472 # WANT_$1
 473 if test "x$WANT_$1" != "xno" ; then
 474  m4_quote($4)
 475  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 476   echo "=== want $1 Failed."
 477   WANT_$1=no
 478  else
 479   WANT_$1=yes
 480  fi
 481 fi
 482 CFG_WANTS+=" $1"
 483 AC_SUBST([WANT_$1])
 484 ])
 485
 486 CHECK_WANT([GL], [auto], [use opengl], [
 487  CHECK_LIB([GL], [GL], [glUseProgram])
 488  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 489  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 490
 491 CHECK_WANT([OSS], [auto], [use OSS audio], [
 492  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 493
 494 CHECK_WANT([XFT], [auto], [use libXft], [
 495  CHECK_LIB([XFT], [Xft], [XftInit])
 496  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 497
 498 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 499  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 500  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 501
 502 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 503  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 504  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 505  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 506  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 507  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 508  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 509  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 510  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 511
 512 CHECK_WANT([DV], [auto], [use dv], [
 513  CHECK_LIB([libdv], [dv], [dv_init])
 514  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 515
 516 CHECK_WANT([DVB], [auto], [use dvb], [
 517  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 518
 519 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 520  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 521
 522 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 523  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 524
 525 CHECK_WANT([ESOUND], [no], [use esd], [
 526  CHECK_LIB([esound], [esd], [esd_open_sound])
 527  CHECK_HEADERS([esound], [esound headers], [esd.h])
 528  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 529  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 530
 531 CHECK_WANT([DL], [auto], [system has libdl], [
 532  CHECK_LIB([DL], [dl], [dlopen])])
 533
 534 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 535  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 536
 537
 538 AC_MSG_CHECKING([for openexr available])
 539 saved_LIBS="$LIBS"
 540 saved_CXXFLAGS="$CXXFLAGS"
 541 # ilmbase libs
 542 LIBS=" -lIlmImf -lIlmThread -lIex"
 543 CXXFLAGS="-I/usr/include/OpenEXR"
 544 AC_LANG_PUSH(C++)
 545 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 546 #include "ImfChannelList.h"
 547 #include "ImfChromaticities.h"
 548 #include "ImfCompression.h"
 549 #include "ImfIO.h"
 550 #include "ImfInputFile.h"
 551 #include "ImfOutputFile.h"
 552 #include "ImfPixelType.h"
 553 #include "ImfRgbaFile.h"
 554 #include "ImfRgbaYca.h"
 555 #include "ImfVersion.h"
 556 class EXRIStream : public Imf::IStream { public:
 557 EXRIStream() : Imf::IStream("mypath") {} };
 558 class EXROStream : public Imf::OStream { public:
 559 EXROStream() : Imf::OStream("mypath") {} };
 560 ]])], [HAVE_openexr=yes], [HAVE_openexr=no])
 561 if test "x$HAVE_openexr" = "xyes"; then
 562   SHARED_openexr="$LIBS"
 563 fi
 564 LIBS="$saved_LIBS"
 565 CXXFLAGS="$saved_CXXFLAGS"
 566 AC_LANG_POP(C++)
 567 AC_MSG_RESULT([$HAVE_openexr])
 568 AC_SUBST([HAVE_openexr])
 569
 570 # build global_config
 571 OBJDIR=`uname -m`
 572 AC_SUBST(OBJDIR)
 573
 574 echo "AC_HELP_STRING([Reason],[Package])"
 575 echo "AC_HELP_STRING([------],[-------])"
 576
 577 AC_DEFUN([PKG_DISABLED],[
 578   BUILD_$1=0
 579   AC_SUBST(BUILD_$1)
 580   echo "AC_HELP_STRING([disabled],[$1])"
 581 ])
 582 AC_DEFUN([PKG_SHARED],[
 583  BUILD_$1=0
 584  AC_SUBST(BUILD_$1)
 585  SHARED_LIBS+="$SHARED_$1"
 586  echo "AC_HELP_STRING([shared],[$1])"
 587 ])
 588 AC_DEFUN([PKG_STATIC],[
 589  BUILD_$1=1
 590  AC_SUBST(BUILD_$1)
 591  STATIC_BLDS+=" [$1]"
 592  echo "AC_HELP_STRING([$2],[$1])"
 593 ])
 594 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 595
 596 # order matters
 597 for dep in \
 598         ffmpeg/faac ffmpeg/faad2 ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 599         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 ffmpeg/fdk \
 600         libiec61883/libraw1394 libavc1394/librom1394 \
 601         openexr/ilmbase ilmbase/libogg \
 602         libtheora/libogg libtheora/libvorbis ; do
 603   lib=`dirname $dep`;  needs=`basename $dep`
 604   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 605   if test "x$pkg_lib" != "xno" -a "x$needs_lib" != "xyes" ; then
 606     eval "PKG_$needs=yes"
 607   fi
 608 done
 609
 610 AC_DEFUN([PKG_PROVIDE],[
 611 if test "x$BUILD_$1" = "x" ; then
 612  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 613   PKG_DISABLED([$1])
 614  elif test "x$PKG_$1" = "xyes"; then
 615   PKG_FORCED([$1])
 616  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 617   PKG_STATIC([$1],[static])
 618  elif test "x$HAVE_$1" = "xyes"; then
 619   PKG_SHARED([$1])
 620  else
 621   PKG_STATIC([$1],[needed])
 622  fi
 623 fi
 624 ])
 625
 626 PKG_PROVIDE([a52dec])
 627 PKG_PROVIDE([djbfft])
 628 PKG_PROVIDE([encore])
 629 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 630 PKG_PROVIDE([esound],[$WANT_ESOUND])
 631 PKG_PROVIDE([faac])
 632 PKG_PROVIDE([faad2])
 633 PKG_PROVIDE([fdk])
 634 PKG_PROVIDE([ffmpeg])
 635 PKG_PROVIDE([fftw])
 636 PKG_PROVIDE([flac])
 637 PKG_PROVIDE([giflib])
 638 PKG_PROVIDE([ilmbase])
 639 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 640 PKG_PROVIDE([lame])
 641 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 642 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 643 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 644 PKG_PROVIDE([libdv],[$WANT_DV])
 645 PKG_PROVIDE([libjpeg])
 646 PKG_PROVIDE([libogg])
 647 PKG_PROVIDE([libsndfile])
 648 PKG_PROVIDE([libtheora])
 649 PKG_PROVIDE([libuuid])
 650 PKG_PROVIDE([libvorbis])
 651 PKG_PROVIDE([mjpegtools])
 652 PKG_PROVIDE([openexr])
 653 PKG_PROVIDE([openjpeg])
 654 PKG_PROVIDE([tiff])
 655 PKG_PROVIDE([twolame])
 656 PKG_PROVIDE([x264])
 657 PKG_PROVIDE([x265])
 658 PKG_PROVIDE([libvpx])
 659
 660 AC_SUBST(STATIC_BLDS)
 661 AC_SUBST(SHARED_LIBS)
 662
 663 for f in $SYSTEM_LIBS; do
 664   echo "AC_HELP_STRING([system],[$f])"
 665 done
 666 AC_SUBST(SYSTEM_LIBS)
 667
 668 echo ""
 669 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 670          VIDEO4LINUX2 ESOUND PACTL; do
 671   eval vv="\$WANT_$v"
 672   if test "x$vv" != "xno"; then
 673     CFG_CFLAGS+=" -DHAVE_$v"
 674     vv=with
 675   else
 676     vv=without
 677   fi
 678   v=`echo "$v" | tr "A-Z" "a-z"`
 679   echo "  using: $vv-$v"
 680 done
 681
 682 echo "  using: with-jobs = $WANT_JOBS"
 683 echo "  using: exec-name = $WANT_CIN"
 684 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 685 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 686 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 687 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 688 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 689 echo ""
 690 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 691 echo "  using: static-build = $WANT_STATIC_BUILD"
 692 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 693 echo ""
 694
 695 # build extras
 696 if test "x$HAVE_NUMA" = "xyes"; then
 697   EXTRA_LIBS+=' -lnuma'
 698 fi
 699 if test "x$HAVE_DL" = "xyes"; then
 700   EXTRA_LIBS+=' -ldl'
 701   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 702 fi
 703 AC_SUBST(EXTRA_LIBS)
 704 AC_SUBST(FFMPEG_EXTRA_CFG)
 705 AC_SUBST(WANT_X264_HIDEPTH)
 706 AC_SUBST(WANT_X265_HIDEPTH)
 707
 708 if test "x$BUILD_openexr" = "x0"; then
 709   CFG_CFLAGS+=" -I/usr/include/OpenEXR"
 710 fi
 711
 712 AC_SUBST(CFG_CFLAGS)
 713 AC_SUBST(CFG_CXXFLAGS)
 714
 715 AC_CONFIG_FILES([Makefile])
 716 AC_OUTPUT
 717
 718 exec > global_config
 719
 720 echo "SHELL := /bin/bash"
 721 echo "export SHELL"
 722 echo "WANT_JOBS := $WANT_JOBS"
 723 echo ""
 724 echo "OBJDIR := $OBJDIR"
 725 echo "BINDIR := \$(TOPDIR)/bin"
 726 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 727 echo "GUICAST := \$(TOPDIR)/guicast"
 728 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 729 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 730 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 731 echo "PLUGINS := \$(TOPDIR)/plugins"
 732 echo "TDB := \$(TOPDIR)/db"
 733 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 734 echo "EXTRA_LIBS := $EXTRA_LIBS"
 735 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 736 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 737 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 738 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 739 echo ""
 740
 741 echo "WANT_CIN := $WANT_CIN"
 742 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 743 echo ""
 744
 745 echo "ifndef CFLAGS_"
 746 echo "ifdef CFLAGS"
 747 echo "CFLAGS_ := \$(CFLAGS)"
 748 echo "else"
 749 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 750 echo "endif"
 751 echo "endif"
 752
 753 echo "CFLAGS := \$(CFLAGS_)"
 754 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 755 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 756 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 757 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 758 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 759 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 760 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 761 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 762 echo ""
 763 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 764 echo ""
 765
 766 if test  $WANT_X264_HIDEPTH = "yes" ; then
 767   echo "x264.cfg_params := --enable-static --bit-depth=10"
 768 fi
 769 if test  $WANT_X265_HIDEPTH = "yes" ; then
 770   echo "x265.cfg_params := -DENABLE_SHARED=no -DHIGH_BIT_DEPTH:BOOL=ON"
 771 fi
 772
 773 for pkg in $STATIC_PKGS; do echo "static_pkgs += $pkg"; done
 774 echo ""
 775 for pkg in $STATIC_BLDS; do
 776   echo "static_blds += $pkg"
 777   ver_pkg=ver_$pkg
 778   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 779   inc_pkg=inc_$pkg
 780   echo "$inc_pkg := \\"
 781   for inc in ${!inc_pkg}; do
 782     echo "  -I\$($ver_pkg)/$inc \\"
 783   done
 784   echo ""
 785   echo "static_incs += \$(inc_$pkg)"
 786   lib_pkg=lib_$pkg
 787   echo "$lib_pkg := \\"
 788   for lib in ${!lib_pkg}; do
 789     echo "  \$($ver_pkg)/$lib \\"
 790   done
 791   echo ""
 792   echo "static_libs += \$($lib_pkg)"
 793   echo ""
 794 done
 795 echo ""
 796
 797 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 798 echo ""
 799 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 800 echo "export static_pkgs static_blds shared_libs system_libs"
 801 echo ""
 802
 803 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 804 echo "libraries += -Wl,--start-group"
 805 echo "libraries += \$(thirdparty_libraries)"
 806 echo "libraries += \$(system_libs)"
 807 echo "libraries += \$(EXTRA_LIBS)"
 808 echo "libraries += -Wl,--end-group"
 809 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 810 echo "libraries += \$(thirdparty_libraries)"
 811 echo "libraries += \$(system_libs)"
 812 echo "libraries += \$(EXTRA_LIBS)"
 813 echo ""
 814 echo "export thirdparty_libraries libraries"
 815 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 816 echo "unexport CFLAGS CXXFLAGS LDFLAGS"