cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 CFG_CFLAGS+=" -Wno-unused-result"
  15 CFG_CFLAGS+=" -Wno-stringop-overflow"
  16 CFG_CFLAGS+=" -Wno-format-truncation"
  17 CFG_CFLAGS+=" -Wno-format-overflow"
  18 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  19 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  20 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  21 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  22 CFG_CFLAGS+=" -I/usr/include/freetype2"
  23
  24 AC_DEFUN([CHECK_WITH], [
  25 AC_ARG_WITH([$1],
  26   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  27   [WANT_$3=$withval], [WANT_$3='$4'])
  28 AC_SUBST([WANT_$3])
  29 ])
  30
  31 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  32 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  33 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  34 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  35 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  36 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  37 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  38 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  39 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  40 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  41 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  42
  43 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  44   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  45   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  46   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  47   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  48   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  49   sinstall=dinstall
  50   suninstall=duninstall
  51 else
  52   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  53     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  54     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  55     echo "$dir"`
  56   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  57     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  58     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  59     echo "$dir"`
  60   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  61     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  62     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  63     echo "$dir"`
  64   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  65        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  66   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  67     usrlib+="64"
  68   WANT_LOCALE_DIR="$lcldir"
  69   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  70   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  71   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  72   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  73   sinstall=cinstall
  74   suninstall=cuninstall
  75 fi
  76 AC_SUBST(sinstall)
  77 AC_SUBST(suninstall)
  78
  79 if test "x$WANT_JOBS" = "xauto"; then
  80   CPUS=`grep -c "^proc" /proc/cpuinfo`
  81   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  82 fi
  83
  84 AC_DEFUN([PKG_DEF],[
  85 STATIC_PKGS+=" [$1]"
  86 ver_$1="$2"
  87 lib_$1="$3"
  88 inc_$1="$4"
  89 ])
  90
  91 AC_DEFUN([PKG_3RD],[
  92 AC_ARG_ENABLE([$1],
  93   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  94   [PKG_$1=$enableval], [PKG_$1=$2])
  95 PKG_DEF([$1],[$3],[$4],[$5])
  96 ])
  97
  98 # thirdparty builds
  99
 100 PKG_3RD([a52dec],[yes],
 101   [a52dec-0.7.4],
 102   [ liba52/.libs/liba52.a ],
 103   [ include ])
 104
 105 PKG_3RD([djbfft],[yes],
 106   [djbfft-0.76],
 107   [ libdjbfft.a ],
 108   [ . ])
 109
 110 PKG_3RD([audiofile],[no],
 111   [audiofile-0.3.6],
 112   [ libaudiofile/.libs/libaudiofile.a \
 113     libaudiofile/modules/.libs/libmodules.a \
 114     libaudiofile/alac/.libs/libalac.a ],
 115   [ libaudiofile ])
 116
 117 PKG_3RD([encore],[no],
 118   [encore-5.0],
 119   [ \$(OBJDIR)/libencore.a ],
 120   [ . ])
 121
 122 PKG_3RD([esound],[no],
 123   [esound-0.2.41],
 124   [ .libs/libesd.a \
 125     .libs/libesddsp.a ],
 126   [ . ])
 127
 128 PKG_3RD([fdk],[auto],
 129   [fdk-aac-0.1.5],
 130   [ .libs/libfdk-aac.a ],
 131   [ libAACdec/include libAACenc/include libSYS/include ])
 132
 133 PKG_3RD([ffmpeg],[yes],
 134   [ffmpeg-4.0],
 135   [ libavutil/libavutil.a \
 136     libavcodec/libavcodec.a \
 137     libpostproc/libpostproc.a \
 138     libavdevice/libavdevice.a \
 139     libavformat/libavformat.a \
 140     libswscale/libswscale.a \
 141     libavfilter/libavfilter.a \
 142     libswresample/libswresample.a ],
 143   [ . ])
 144
 145 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 146   ver_ffmpeg="ffmpeg.git"
 147 fi
 148
 149 PKG_3RD([fftw],[auto],
 150   [fftw-3.3.7],
 151   [ .libs/libfftw3.a \
 152     libbench2/libbench2.a \
 153     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 154     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 155     rdft/scalar/.libs/librdft_scalar.a \
 156     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 157     rdft/.libs/librdft.a \
 158     api/.libs/libapi.a \
 159     reodft/.libs/libreodft.a \
 160     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 161     dft/scalar/.libs/libdft_scalar.a \
 162     dft/.libs/libdft.a \
 163     kernel/.libs/libkernel.a \
 164     simd-support/.libs/libsimd_support.a ],
 165   [ api ])
 166
 167 PKG_3RD([flac],[auto],
 168   [flac-1.3.2],
 169   [ src/libFLAC/.libs/libFLAC.a \
 170     src/libFLAC++/.libs/libFLAC++.a \
 171     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 172     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 173     src/share/grabbag/.libs/libgrabbag.a \
 174     src/share/utf8/.libs/libutf8.a \
 175     src/test_libs_common/.libs/libtest_libs_common.a ],
 176   [ include ])
 177
 178 PKG_3RD([giflib],[yes],
 179   [giflib-5.1.4],
 180   [ lib/.libs/libgif.a \
 181     util/libgetarg.a ],
 182   [ lib ])
 183
 184 PKG_3RD([ilmbase],[auto],
 185   [ilmbase-2.2.1],
 186   [ Iex/.libs/libIex.a \
 187     IexMath/.libs/libIexMath.a \
 188     Half/.libs/libHalf.a \
 189     Imath/.libs/libImath.a \
 190     IlmThread/.libs/libIlmThread.a ],
 191   [ Iex Half Imath config IlmThread ])
 192
 193 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 194
 195 PKG_3RD([lame],[auto],
 196   [lame-3.100],
 197   [ libmp3lame/.libs/libmp3lame.a \
 198     mpglib/.libs/libmpgdecoder.a ],
 199   [ include ])
 200
 201 PKG_3RD([libavc1394],[auto],
 202   [libavc1394-0.5.4],
 203   [ libavc1394/.libs/libavc1394.a \
 204     librom1394/.libs/librom1394.a \
 205     common/.libs/libraw1394util.a ],
 206   [ . ])
 207
 208 PKG_3RD([libraw1394],[auto],
 209   [libraw1394-2.1.2],
 210   [ src/.libs/libraw1394.a ],
 211   [ . ])
 212
 213 PKG_3RD([libiec61883],[auto],
 214   [libiec61883-1.2.0],
 215   [ src/.libs/libiec61883.a ],
 216   [ src ])
 217
 218 PKG_3RD([libdv],[auto],
 219   [libdv-1.0.0],
 220   [ libdv/.libs/libdv.a ],
 221   [ . ])
 222
 223 PKG_3RD([libjpeg],[auto],
 224   [libjpeg-turbo-1.5.1],
 225   [ .libs/libjpeg.a \
 226     .libs/libturbojpeg.a \
 227     simd/.libs/libsimd.a ],
 228   [ . ])
 229
 230 PKG_3RD([opus],[auto],
 231   [opus-1.2.1],
 232   [ .libs/libopus.a ],
 233   [ include ])
 234
 235 PKG_3RD([openjpeg],[auto],
 236   [openjpeg-2.1.0-20160221],
 237   [ bin/libopenjp2.a ],
 238   [ src/lib/openjp2 ])
 239
 240 PKG_3RD([libogg],[auto],
 241   [libogg-1.3.2],
 242   [ src/.libs/libogg.a ],
 243   [ include ])
 244
 245 PKG_3RD([libsndfile],[auto],
 246   [libsndfile-1.0.28],
 247   [ src/.libs/libsndfile.a \
 248     src/.libs/libcommon.a \
 249     src/G72x/.libs/libg72x.a \
 250     src/GSM610/.libs/libgsm.a ],
 251   [ . ])
 252
 253 PKG_3RD([libtheora],[auto],
 254   [libtheora-1.1.1],
 255   [ lib/.libs/libtheora.a \
 256     lib/.libs/libtheoradec.a \
 257     lib/.libs/libtheoraenc.a ],
 258   [ . ])
 259
 260 PKG_3RD([libuuid],[yes],
 261   [libuuid-1.0.3],
 262   [ .libs/libuuid.a ],
 263   [ . ])
 264
 265 PKG_3RD([libvorbis],[auto],
 266   [libvorbis-1.3.5],
 267   [ lib/.libs/libvorbis.a \
 268     lib/.libs/libvorbisenc.a \
 269     lib/.libs/libvorbisfile.a ],
 270   [ include . ])
 271
 272 PKG_3RD([mjpegtools],[yes],
 273   [mjpegtools-2.1.0],
 274   [ utils/mmxsse/.libs/libmmxsse.a \
 275     utils/.libs/libmjpegutils.a \
 276     lavtools/.libs/liblavfile.a \
 277     lavtools/.libs/liblavjpeg.a \
 278     mplex/.libs/libmplex2.a \
 279     yuvfilters/.libs/libyuvfilters.a \
 280     mpeg2enc/.libs/libmpeg2encpp.a ],
 281   [ .  lavtools utils ])
 282
 283 PKG_3RD([openexr],[auto],
 284   [openexr-2.2.1],
 285   [ IlmImf/.libs/libIlmImf.a \
 286     IlmImfUtil/.libs/libIlmImfUtil.a ],
 287   [ IlmImf config ])
 288
 289 #PKG_3RD([festival],[no],
 290 #  [festival],
 291 #  [],
 292 #  [])
 293 #PKG_3RD(speech_tools,[no],
 294 #  [speech_tools],
 295 #  [],
 296 #  [])
 297 #
 298 PKG_3RD([tiff],[auto],
 299   [tiff-4.0.9],
 300   [ libtiff/.libs/libtiff.a \
 301     libtiff/.libs/libtiffxx.a \
 302     port/.libs/libport.a ],[
 303    . ])
 304
 305 PKG_3RD([twolame],[auto],
 306   [twolame-0.3.13],
 307   [ libtwolame/.libs/libtwolame.a ],
 308   [  libtwolame ])
 309
 310 PKG_3RD([x264],[auto],
 311   [x264-snapshot-20180118-2245],
 312   [ libx264.a ],
 313   [ . ])
 314
 315 PKG_3RD([x265],[auto],
 316   [x265_2.7],
 317   [ libx265.a ],
 318   [ . source ])
 319
 320 PKG_3RD([libvpx],[auto],
 321   [libvpx-1.7.0],
 322   [ libvpx.a ],
 323   [ . ])
 324
 325 AC_SUBST(STATIC_PKGS)
 326
 327 AC_DEFUN([CHECK_ENABLE], [
 328 AC_ARG_ENABLE([$1],
 329   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 330   [WANT_$2=$enableval], [WANT_$2=[$4]])
 331 ])
 332
 333 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 334 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 335
 336 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 337
 338 AC_DEFUN([CHECK_PROG], [
 339  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 340 ])
 341 AC_DEFUN([REQUIRE_PROG], [
 342  CHECK_PROG([$1],[$2])
 343  if test "x$PROG_$1" = "xno"; then
 344    AC_MSG_WARN([$2 is missing and required.])
 345    FATAL_ERROR=1
 346  fi
 347 ])
 348
 349 # Checks for programs.
 350
 351 REQUIRE_PROG(NASM, [nasm])
 352 REQUIRE_PROG(YASM, [yasm])
 353 REQUIRE_PROG(OBJCOPY, [objcopy])
 354 if test "x$FATAL_ERROR" != "x"; then
 355  AC_MSG_ERROR("fatal eror.")
 356 fi
 357 CHECK_PROG(PACTL, [pactl])
 358 WANT_PACTL=$PROG_PACTL
 359
 360 # libx264 nasm fix
 361 AC_MSG_CHECKING([nasm x264 compatible])
 362 echo "vmovdqa32 [[eax]]{k1}{z}, zmm0" > conftest.asm
 363 nasm conftest.asm -o conftest.o > /dev/null 2>&1
 364 if test $? != 0 ; then
 365  AC_MSG_RESULT([no])
 366  AC_MSG_WARN([libx264 built without assembly code])
 367  X264_CFG_PARAMS="$X264_CFG_PARAMS --disable-asm"
 368 else
 369  AC_MSG_RESULT([yes])
 370 fi
 371 rm -f conftest.asm conftest.o
 372
 373 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 374 if test "$no_utf" = "yes"; then
 375   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 376 fi
 377
 378 # Checks for headers/libraries.
 379
 380 AC_DEFUN([CHECK_HEADERS], [
 381 if test "x$HAVE_$1" != "xno"; then
 382  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 383   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 384 ]])])
 385  AC_SUBST([HAVE_$1])
 386  AC_MSG_CHECKING([$2])
 387  AC_MSG_RESULT([$HAVE_$1])
 388  if test "x$HAVE_$1" = "xno"; then
 389   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 390  fi
 391 fi
 392 ])
 393
 394 AC_DEFUN([CHECK_LIB], [
 395 if test "x$HAVE_$1" != "xno"; then
 396  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 397   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 398   AC_SUBST([HAVE_$1])
 399   if test "x$HAVE_$1" = "xyes"; then
 400    if test "x$PKG_$1" = "x"; then
 401     SYSTEM_LIBS+=" -l[$2]"
 402     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 403    else
 404     SHARED_$1+=" -l[$2]"
 405     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 406    fi
 407   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 408  fi
 409 fi
 410 ])
 411
 412 CHECK_LIB([X11], [X11], [XOpenDisplay])
 413 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 414 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 415 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 416 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 417 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 418 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 419 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 420 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 421 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 422 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 423 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 424 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 425 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 426 CHECK_LIB([PNG], [png], [png_read_png])
 427 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 428 CHECK_LIB([Z], [z], [gzopen])
 429 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 430 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 431 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 432 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 433 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 434 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 435 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 436 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 437 CHECK_LIB([lame], [mp3lame], [lame_init])
 438 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 439 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 440 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 441 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 442 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 443 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 444 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 445 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 446 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 447 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 448 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 449 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 450 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 451 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 452 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 453 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 454 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 455 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 456 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 457 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 458 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 459 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 460 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 461 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 462 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 463 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 464 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 465 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 466 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 467 CHECK_LIB([a52dec], [a52], [a52_init])
 468 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 469 CHECK_LIB([encore], [encore], [encore])
 470 CHECK_HEADERS([encore], [encore headers], [encore.h])
 471 CHECK_LIB([giflib], [gif], [DGifOpen])
 472 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 473 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 474 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 475 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 476 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 477
 478 #if test "x$HAVE_mjpegtools" = "xyes"; then
 479 #CFG_CFLAGS+=" -I/usr/include/mjpegtools"
 480 #fi
 481
 482 AC_DEFUN([CHECK_WANT], [
 483 RESULT=yes
 484 AC_ARG_WITH(m4_tolower([$1]),
 485  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 486   [WANT_$1=$withval],[WANT_$1=$2])
 487 # WANT_$1
 488 if test "x$WANT_$1" != "xno" ; then
 489  m4_quote($4)
 490  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 491   echo "=== want $1 Failed."
 492   WANT_$1=no
 493  elif test "x$WANT_$1" = "xauto" ; then
 494   WANT_$1=yes
 495  fi
 496 fi
 497 CFG_WANTS+=" $1"
 498 AC_SUBST([WANT_$1])
 499 ])
 500
 501 CHECK_WANT([GL], [auto], [use opengl], [
 502  CHECK_LIB([GL], [GL], [glUseProgram])
 503  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 504  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 505
 506 CHECK_WANT([OSS], [auto], [use OSS audio], [
 507  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 508
 509 CHECK_WANT([XFT], [auto], [use libXft], [
 510  CHECK_LIB([XFT], [Xft], [XftInit])
 511  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 512
 513 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 514  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 515  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 516
 517 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 518  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 519  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 520  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 521  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 522  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 523  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 524  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 525  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 526
 527 CHECK_WANT([DV], [auto], [use dv], [
 528  CHECK_LIB([libdv], [dv], [dv_init])
 529  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 530
 531 CHECK_WANT([DVB], [auto], [use dvb], [
 532  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 533
 534 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 535  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 536
 537 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 538  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 539
 540 CHECK_WANT([ESOUND], [no], [use esd], [
 541  CHECK_LIB([esound], [esd], [esd_open_sound])
 542  CHECK_HEADERS([esound], [esound headers], [esd.h])
 543  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 544  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 545
 546 CHECK_WANT([LIBOPUS], [auto], [use libopus], [
 547  CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 548  CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])])
 549
 550 CHECK_WANT([DL], [auto], [system has libdl], [
 551  CHECK_LIB([DL], [dl], [dlopen])])
 552
 553 CHECK_WANT([EXR], [auto], [use exr], [])
 554 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 555  WANT_OPENCV="$withval"
 556 ])
 557
 558 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 559  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 560
 561 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 562  AC_MSG_CHECKING([for openexr available])
 563  saved_LIBS="$LIBS"
 564  saved_CXXFLAGS="$CXXFLAGS"
 565  # ilmbase libs
 566  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 567  CXXFLAGS="-I/usr/include/OpenEXR"
 568  AC_LANG_PUSH(C++)
 569  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 570 #include "ImfChannelList.h"
 571 #include "ImfChromaticities.h"
 572 #include "ImfCompression.h"
 573 #include "ImfIO.h"
 574 #include "ImfInputFile.h"
 575 #include "ImfOutputFile.h"
 576 #include "ImfPixelType.h"
 577 #include "ImfRgbaFile.h"
 578 #include "ImfRgbaYca.h"
 579 #include "ImfVersion.h"
 580 class EXRIStream : public Imf::IStream { public:
 581 EXRIStream() : Imf::IStream("mypath") {} };
 582 class EXROStream : public Imf::OStream { public:
 583 EXROStream() : Imf::OStream("mypath") {} };
 584 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 585  RESULT="$HAVE_OPENEXR"
 586  if test "x$RESULT" = "xyes"; then
 587    SHARED_openexr="$LIBS"
 588    CFG_CFLAGS+=" -I/usr/include/OpenEXR"
 589  fi
 590  LIBS="$saved_LIBS"
 591  CXXFLAGS="$saved_CXXFLAGS"
 592  AC_LANG_POP(C++)
 593  AC_MSG_RESULT([$HAVE_OPENEXR])
 594 ])
 595 AC_SUBST([HAVE_OPENEXR])
 596
 597 # build global_config
 598 OBJDIR=`uname -m`
 599 AC_SUBST(OBJDIR)
 600
 601 echo "AC_HELP_STRING([Reason],[Package])"
 602 echo "AC_HELP_STRING([------],[-------])"
 603
 604 AC_DEFUN([PKG_DISABLED],[
 605  PKG_$1="no"
 606  BUILD_$1=0
 607  AC_SUBST(BUILD_$1)
 608  echo "AC_HELP_STRING([disabled],[$1])"
 609 ])
 610 AC_DEFUN([PKG_SHARED],[
 611  BUILD_$1=0
 612  AC_SUBST(BUILD_$1)
 613  SHARED_LIBS+="$SHARED_$1"
 614  echo "AC_HELP_STRING([shared],[$1])"
 615 ])
 616 AC_DEFUN([PKG_STATIC],[
 617  PKG_$1="yes"
 618  BUILD_$1=1
 619  AC_SUBST(BUILD_$1)
 620  STATIC_BLDS+=" [$1]"
 621  echo "AC_HELP_STRING([$2],[$1])"
 622 ])
 623 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 624
 625 # order matters
 626 for dep in \
 627         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 628         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 ffmpeg/fdk \
 629         libiec61883/libraw1394 libavc1394/librom1394 \
 630         openexr/ilmbase ilmbase/libogg \
 631         libtheora/libogg libtheora/libvorbis ; do
 632   lib=`dirname $dep`;  needs=`basename $dep`
 633   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 634   if test "x$pkg_lib" != "xno"; then
 635     eval "PKG_$needs=yes"
 636   fi
 637 done
 638
 639 AC_DEFUN([PKG_PROVIDE],[
 640 if test "x$BUILD_$1" = "x" ; then
 641  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 642   PKG_DISABLED([$1])
 643  elif test "x$PKG_$1" = "xyes"; then
 644   PKG_FORCED([$1])
 645  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 646   PKG_STATIC([$1],[static])
 647  elif test "x$HAVE_$1" = "xyes"; then
 648   PKG_SHARED([$1])
 649  else
 650   PKG_STATIC([$1],[needed])
 651  fi
 652 fi
 653 ])
 654
 655 PKG_PROVIDE([a52dec])
 656 PKG_PROVIDE([djbfft])
 657 PKG_PROVIDE([encore])
 658 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 659 PKG_PROVIDE([esound],[$WANT_ESOUND])
 660 PKG_PROVIDE([fdk])
 661 PKG_PROVIDE([ffmpeg])
 662 PKG_PROVIDE([fftw])
 663 PKG_PROVIDE([flac])
 664 PKG_PROVIDE([giflib])
 665 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 666 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 667 PKG_PROVIDE([lame])
 668 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 669 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 670 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 671 PKG_PROVIDE([libdv],[$WANT_DV])
 672 PKG_PROVIDE([libjpeg])
 673 PKG_PROVIDE([libogg])
 674 PKG_PROVIDE([libsndfile])
 675 PKG_PROVIDE([libtheora])
 676 PKG_PROVIDE([libuuid])
 677 PKG_PROVIDE([libvorbis])
 678 PKG_PROVIDE([mjpegtools])
 679 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 680 PKG_PROVIDE([openjpeg])
 681 PKG_PROVIDE([tiff])
 682 PKG_PROVIDE([twolame])
 683 PKG_PROVIDE([x264])
 684 PKG_PROVIDE([x265])
 685 PKG_PROVIDE([libvpx])
 686 PKG_PROVIDE([opus], [$WANT_OPUS])
 687
 688 AC_SUBST(STATIC_BLDS)
 689 AC_SUBST(SHARED_LIBS)
 690
 691 for f in $SYSTEM_LIBS; do
 692   echo "AC_HELP_STRING([system],[$f])"
 693 done
 694 AC_SUBST(SYSTEM_LIBS)
 695
 696 echo ""
 697 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 698          VIDEO4LINUX2 ESOUND PACTL OPENEXR; do
 699   eval vv="\$WANT_$v"
 700   if test "x$vv" != "xno"; then
 701     CFG_CFLAGS+=" -DHAVE_$v"
 702     vv=with
 703   else
 704     vv=without
 705   fi
 706   v=`echo "$v" | tr "A-Z" "a-z"`
 707   echo "  using: $vv-$v"
 708 done
 709
 710 echo "  using: with-jobs = $WANT_JOBS"
 711 echo "  using: exec-name = $WANT_CIN"
 712 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 713 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 714 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 715 echo "  using: with-browser = $WANT_CIN_BROWSER"
 716 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 717 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 718 echo "  using: with-opencv = $WANT_OPENCV"
 719 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 720 echo ""
 721 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 722 echo "  using: static-build = $WANT_STATIC_BUILD"
 723 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 724 echo ""
 725
 726 # build extras
 727 if test "x$HAVE_tiff" = "xyes"; then
 728   if test "x$HAVE_jbig" = "xyes"; then
 729     EXTRA_LIBS+=' -ljbig'
 730   fi
 731 fi
 732 if test "x$HAVE_NUMA" = "xyes"; then
 733   EXTRA_LIBS+=' -lnuma'
 734 fi
 735 if test "x$HAVE_DL" = "xyes"; then
 736   EXTRA_LIBS+=' -ldl'
 737   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 738 fi
 739 if test "x$HAVE_opus" = "xyes"; then
 740   EXTRA_LIBS+=' -lopus'
 741   CFG_CFLAGS+=' -I/usr/include/opus'
 742   FFMPEG_EXTRA_CFG+=' --enable-libopus'
 743 fi
 744
 745 AC_SUBST(EXTRA_LIBS)
 746 AC_SUBST(FFMPEG_EXTRA_CFG)
 747 AC_SUBST(WANT_X264_HIDEPTH)
 748
 749 AC_SUBST(CFG_CFLAGS)
 750 AC_SUBST(CFG_CXXFLAGS)
 751
 752 AC_CONFIG_FILES([Makefile])
 753 AC_OUTPUT
 754
 755 exec > global_config
 756
 757 echo "SHELL := /bin/bash"
 758 echo "export SHELL"
 759 echo "WANT_JOBS := $WANT_JOBS"
 760 echo ""
 761 echo "OBJDIR := $OBJDIR"
 762 echo "BINDIR := \$(TOPDIR)/bin"
 763 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 764 echo "GUICAST := \$(TOPDIR)/guicast"
 765 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 766 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 767 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 768 echo "PLUGINS := \$(TOPDIR)/plugins"
 769 echo "TDB := \$(TOPDIR)/db"
 770 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 771 echo "EXTRA_LIBS := $EXTRA_LIBS"
 772 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 773 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 774 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 775 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 776 echo ""
 777
 778 echo "WANT_CIN := $WANT_CIN"
 779 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 780 echo ""
 781
 782 echo "ifndef CFLAGS_"
 783 echo "ifdef CFLAGS"
 784 echo "CFLAGS_ := \$(CFLAGS)"
 785 echo "else"
 786 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 787 echo "endif"
 788 echo "endif"
 789
 790 echo "CFLAGS := \$(CFLAGS_)"
 791 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 792 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 793 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 794 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 795 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 796 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 797 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 798 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 799 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 800 echo ""
 801 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 802 echo ""
 803
 804 if test  $WANT_X264_HIDEPTH = "yes" ; then
 805   X264_CFG_PARAMS="$X264_CFG_PARAMS --bit-depth=10"
 806 fi
 807
 808 for pkg in $STATIC_PKGS; do
 809   eval pkg_lib="\$PKG_$pkg"
 810   if test "x$pkg_lib" = "xno"; then continue; fi;
 811   echo "static_pkgs += $pkg"
 812 done
 813 echo ""
 814
 815 for pkg in $STATIC_BLDS; do
 816   echo "static_blds += $pkg"
 817   ver_pkg=ver_$pkg
 818   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 819   inc_pkg=inc_$pkg
 820   echo "$inc_pkg := \\"
 821   for inc in ${!inc_pkg}; do
 822     echo "  -I\$($ver_pkg)/$inc \\"
 823   done
 824   echo ""
 825   echo "static_incs += \$(inc_$pkg)"
 826   lib_pkg=lib_$pkg
 827   echo "$lib_pkg := \\"
 828   for lib in ${!lib_pkg}; do
 829     echo "  \$($ver_pkg)/$lib \\"
 830   done
 831   echo ""
 832   echo "static_libs += \$($lib_pkg)"
 833   echo ""
 834 done
 835 echo ""
 836
 837 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 838 echo ""
 839 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 840 echo "export static_pkgs static_blds shared_libs system_libs"
 841 echo ""
 842
 843 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 844 echo "libraries += -Wl,--start-group"
 845 echo "libraries += \$(thirdparty_libraries)"
 846 echo "libraries += \$(system_libs)"
 847 echo "libraries += \$(EXTRA_LIBS)"
 848 echo "libraries += -Wl,--end-group"
 849 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 850 echo "libraries += \$(thirdparty_libraries)"
 851 echo "libraries += \$(system_libs)"
 852 echo "libraries += \$(EXTRA_LIBS)"
 853 echo ""
 854 echo "export thirdparty_libraries libraries"
 855 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 856 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
 857
 858 if test "x$HAVE_tiff" = "xyes"; then
 859   if test "x$HAVE_jbig" != "xyes"; then
 860     echo "tiff.cfg_params+= --disable-jbig"
 861   fi
 862 fi
 863
 864 if test "x$WANT_GIT_FFMPEG" != "xno"; then
 865 echo "ffmpeg.git := $WANT_GIT_FFMPEG"
 866 fi
 867 if test "x$HAVE_opus" = "xyes"; then
 868 echo 'ffmpeg.cflags+=" -I/usr/include/opus"'
 869 fi
 870 if test "x$X264_CFG_PARAMS" != "x" ; then
 871   echo "x264.cfg_params :=$X264_CFG_PARAMS --enable-static --enable-pic"
 872 fi