cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall -Wno-unused-result"
  13 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  14 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  15 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  16 CFG_CFLAGS+=" -I/usr/include/freetype2"
  17
  18 AC_DEFUN([CHECK_WITH], [
  19 AC_ARG_WITH([$1],
  20   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  21   [WANT_$3=$withval], [WANT_$3='$4'])
  22 AC_SUBST([WANT_$3])
  23 ])
  24
  25 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  26 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  27 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  28 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  29 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  30 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  31 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  32 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  33 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  34
  35 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  36   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  37   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  38   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  39   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  40   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  41   sinstall=dinstall
  42   suninstall=duninstall
  43 else
  44   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  45     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  46     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  47     echo "$dir"`
  48   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  49     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  50     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  51     echo "$dir"`
  52   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  53     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  54     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  55     echo "$dir"`
  56   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  57        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  58   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  59     usrlib+="64"
  60   WANT_LOCALE_DIR="$lcldir"
  61   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  62   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  63   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  64   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  65   sinstall=cinstall
  66   suninstall=cuninstall
  67 fi
  68 AC_SUBST(sinstall)
  69 AC_SUBST(suninstall)
  70
  71 if test "x$WANT_JOBS" = "xauto"; then
  72   CPUS=`grep -c "^proc" /proc/cpuinfo`
  73   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  74 fi
  75
  76 AC_DEFUN([PKG_DEF],[
  77 STATIC_PKGS+=" [$1]"
  78 ver_$1="$2"
  79 lib_$1="$3"
  80 inc_$1="$4"
  81 ])
  82
  83 AC_DEFUN([PKG_3RD],[
  84 AC_ARG_ENABLE([$1],
  85   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  86   [PKG_$1=$enableval], [PKG_$1=$2])
  87 PKG_DEF([$1],[$3],[$4],[$5])
  88 ])
  89
  90 # thirdparty builds
  91
  92 PKG_3RD([a52dec],[yes],
  93   [a52dec-0.7.4],
  94   [ liba52/.libs/liba52.a ],
  95   [ include ])
  96
  97 PKG_3RD([djbfft],[yes],
  98   [djbfft-0.76],
  99   [ djbfft.a ],
 100   [ . ])
 101
 102 PKG_3RD([audiofile],[no],
 103   [audiofile-0.3.6],
 104   [ libaudiofile/.libs/libaudiofile.a \
 105     libaudiofile/modules/.libs/libmodules.a \
 106     libaudiofile/alac/.libs/libalac.a ],
 107   [ libaudiofile ])
 108
 109 PKG_3RD([encore],[no],
 110   [encore-5.0],
 111   [ \$(OBJDIR)/libencore.a ],
 112   [ . ])
 113
 114 PKG_3RD([esound],[no],
 115   [esound-0.2.41],
 116   [ .libs/libesd.a \
 117     .libs/libesddsp.a ],
 118   [ . ])
 119
 120 PKG_3RD([faac],[auto],
 121   [faac-1.28],
 122   [ libfaac/.libs/libfaac.a \
 123     common/mp4v2/libmp4v2.a ],
 124   [ include ])
 125
 126 PKG_3RD([faad2],[auto],
 127   [faad2-2.7],
 128   [ libfaad/.libs/libfaad.a \
 129     common/mp4ff/libmp4ff.a ],
 130   [ include ])
 131
 132 PKG_3RD([fdk],[auto],
 133   [fdk-aac-0.1.4],
 134   [ .libs/libfdk-aac.a ],
 135   [ libAACdec/include libAACenc/include libSYS/include ])
 136
 137 PKG_3RD([ffmpeg],[yes],
 138   [ffmpeg-3.0],
 139   [ libavutil/libavutil.a \
 140     libavcodec/libavcodec.a \
 141     libpostproc/libpostproc.a \
 142     libavdevice/libavdevice.a \
 143     libavformat/libavformat.a \
 144     libswscale/libswscale.a \
 145     libavfilter/libavfilter.a \
 146     libswresample/libswresample.a ],
 147   [ . ])
 148
 149 PKG_3RD([fftw],[auto],
 150   [fftw-3.3.4],
 151   [ .libs/libfftw3.a \
 152     libbench2/libbench2.a \
 153     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 154     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 155     rdft/scalar/.libs/librdft_scalar.a \
 156     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 157     rdft/.libs/librdft.a \
 158     api/.libs/libapi.a \
 159     reodft/.libs/libreodft.a \
 160     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 161     dft/scalar/.libs/libdft_scalar.a \
 162     dft/.libs/libdft.a \
 163     kernel/.libs/libkernel.a \
 164     simd-support/.libs/libsimd_support.a \
 165     simd-support/.libs/libsimd_sse2_nonportable.a ],
 166   [ api ])
 167
 168 PKG_3RD([flac],[auto],
 169   [flac-1.3.1],
 170   [ src/libFLAC/.libs/libFLAC.a \
 171     src/libFLAC++/.libs/libFLAC++.a \
 172     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 173     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 174     src/share/grabbag/.libs/libgrabbag.a \
 175     src/share/utf8/.libs/libutf8.a \
 176     src/test_libs_common/.libs/libtest_libs_common.a ],
 177   [ include ])
 178
 179 PKG_3RD([giflib],[yes],
 180   [giflib-5.1.2],
 181   [ lib/.libs/libgif.a \
 182     util/libgetarg.a ],
 183   [ lib ])
 184
 185 PKG_3RD([ilmbase],[auto],
 186   [ilmbase-2.2.0],
 187   [ Iex/.libs/libIex.a \
 188     IexMath/.libs/libIexMath.a \
 189     Half/.libs/libHalf.a \
 190     Imath/.libs/libImath.a \
 191     IlmThread/.libs/libIlmThread.a ],
 192   [ Iex Half Imath config IlmThread ])
 193
 194 PKG_DEF([ladspa], [ladspa-05182015], [], [])
 195
 196 PKG_3RD([lame],[auto],
 197   [lame-3.99.5],
 198   [ libmp3lame/.libs/libmp3lame.a \
 199     mpglib/.libs/libmpgdecoder.a ],
 200   [ include ])
 201
 202 PKG_3RD([libavc1394],[auto],
 203   [libavc1394-0.5.4],
 204   [ libavc1394/.libs/libavc1394.a \
 205     librom1394/.libs/librom1394.a \
 206     common/.libs/libraw1394util.a ],
 207   [ . ])
 208
 209 PKG_3RD([libraw1394],[auto],
 210   [libraw1394-2.0.5],
 211   [ src/.libs/libraw1394.a ],
 212   [ . ])
 213
 214 PKG_3RD([libiec61883],[auto],
 215   [libiec61883-1.2.0],
 216   [ src/.libs/libiec61883.a ],
 217   [ src ])
 218
 219 PKG_3RD([libdv],[auto],
 220   [libdv-1.0.0],
 221   [ libdv/.libs/libdv.a ],
 222   [ . ])
 223
 224 PKG_3RD([libjpeg],[auto],
 225   [libjpeg-turbo-1.4.0],
 226   [ .libs/libjpeg.a \
 227     .libs/libturbojpeg.a \
 228     simd/.libs/libsimd.a ],
 229   [ . ])
 230
 231 PKG_3RD([openjpeg],[yes],
 232   [openjpeg-2.1.0-20160221],
 233   [ bin/libopenjp2.a ],
 234   [ src/lib/openjp2 ])
 235
 236 PKG_3RD([libogg],[auto],
 237   [libogg-1.3.2],
 238   [ src/.libs/libogg.a ],
 239   [ include ])
 240
 241 PKG_3RD([libsndfile],[auto],
 242   [libsndfile-1.0.26],
 243   [ src/.libs/libsndfile.a \
 244     src/.libs/libcommon.a \
 245     src/G72x/.libs/libg72x.a \
 246     src/GSM610/.libs/libgsm.a ],
 247   [ . ])
 248
 249 PKG_3RD([libtheora],[auto],
 250   [libtheora-1.1.1],
 251   [ lib/.libs/libtheora.a \
 252     lib/.libs/libtheoradec.a \
 253     lib/.libs/libtheoraenc.a ],
 254   [ . ])
 255
 256 PKG_3RD([libuuid],[yes],
 257   [libuuid-1.0.3],
 258   [ .libs/libuuid.a ],
 259   [ . ])
 260
 261 PKG_3RD([libvorbis],[auto],
 262   [libvorbis-1.3.5],
 263   [ lib/.libs/libvorbis.a \
 264     lib/.libs/libvorbisenc.a \
 265     lib/.libs/libvorbisfile.a ],
 266   [ include . ])
 267
 268 PKG_3RD([mjpegtools],[yes],
 269   [mjpegtools-2.1.0],
 270   [ utils/mmxsse/.libs/libmmxsse.a \
 271     utils/.libs/libmjpegutils.a \
 272     lavtools/.libs/liblavfile.a \
 273     lavtools/.libs/liblavjpeg.a \
 274     mplex/.libs/libmplex2.a \
 275     yuvfilters/.libs/libyuvfilters.a \
 276     mpeg2enc/.libs/libmpeg2encpp.a ],
 277   [ .  lavtools utils ])
 278
 279 PKG_3RD([openexr],[auto],
 280   [openexr-2.2.0],
 281   [ IlmImf/.libs/libIlmImf.a \
 282     IlmImfUtil/.libs/libIlmImfUtil.a ],
 283   [ IlmImf config ])
 284
 285 #PKG_3RD([festival],[no],
 286 #  [festival],
 287 #  [],
 288 #  [])
 289 #PKG_3RD(speech_tools,[no],
 290 #  [speech_tools],
 291 #  [],
 292 #  [])
 293 #
 294 PKG_3RD([tiff],[auto],
 295   [tiff-3.8.2],
 296   [ libtiff/.libs/libtiff.a \
 297     libtiff/.libs/libtiffxx.a \
 298     port/.libs/libport.a ],[
 299    . ])
 300
 301 PKG_3RD([twolame],[auto],
 302   [twolame-0.3.13],
 303   [ libtwolame/.libs/libtwolame.a ],
 304   [  libtwolame ])
 305
 306 PKG_3RD([x264],[yes],
 307   [x264-snapshot-20160220-2245-stable],
 308   [ libx264.a ],
 309   [ . ])
 310
 311 PKG_3RD([x265],[yes],
 312   [x265_1.9],
 313   [ libx265.a ],
 314   [ . source ])
 315
 316 PKG_3RD([libvpx],[auto],
 317   [libvpx-1.5.0],
 318   [ libvpx.a ],
 319   [ . ])
 320
 321 AC_SUBST(STATIC_PKGS)
 322
 323 AC_DEFUN([CHECK_ENABLE], [
 324 AC_ARG_ENABLE([$1],
 325   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 326   [WANT_$2=$enableval], [WANT_$2=[$4]])
 327 ])
 328
 329 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 330 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 331 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10/12bit], [no])
 332
 333 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 334
 335 AC_DEFUN([CHECK_PROG], [
 336  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 337 ])
 338 AC_DEFUN([REQUIRE_PROG], [
 339  CHECK_PROG([$1],[$2])
 340  if test "x$PROG_$1" = "xno"; then
 341    AC_MSG_WARN([$2 is missing and required.])
 342    FATAL_ERROR=1
 343  fi
 344 ])
 345
 346 # Checks for programs.
 347
 348 REQUIRE_PROG(NASM, [nasm])
 349 REQUIRE_PROG(YASM, [yasm])
 350 REQUIRE_PROG(OBJCOPY, [objcopy])
 351 if test "x$FATAL_ERROR" != "x"; then
 352  AC_MSG_ERROR("fatal eror.")
 353 fi
 354 CHECK_PROG(PACTL, [pactl])
 355
 356 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 357 if test "$no_utf" = "yes"; then
 358   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 359 fi
 360
 361 # Checks for headers/libraries.
 362
 363 AC_DEFUN([CHECK_HEADERS], [
 364 if test "x$HAVE_$1" != "xno"; then
 365  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 366   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 367 ]])])
 368  AC_SUBST([HAVE_$1])
 369  AC_MSG_CHECKING([$2])
 370  AC_MSG_RESULT([$HAVE_$1])
 371  if test "x$HAVE_$1" = "xno"; then
 372   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 373  fi
 374 fi
 375 ])
 376
 377 AC_DEFUN([CHECK_LIB], [
 378 if test "x$HAVE_$1" != "xno"; then
 379  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 380   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 381   AC_SUBST([HAVE_$1])
 382   if test "x$HAVE_$1" = "xyes"; then
 383    if test "x$PKG_$1" = "x"; then
 384     SYSTEM_LIBS+=" -l[$2]"
 385     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 386    else
 387     SHARED_$1+=" -l[$2]"
 388     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 389    fi
 390   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 391  fi
 392 fi
 393 ])
 394
 395 CHECK_LIB([X11], [X11], [XOpenDisplay])
 396 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 397 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 398 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 399 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 400 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 401 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 402 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 403 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 404 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 405 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 406 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 407 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 408 CHECK_LIB([PNG], [png], [png_read_png])
 409 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 410 CHECK_LIB([Z], [z], [gzopen])
 411 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 412 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 413 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 414 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 415 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 416 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 417 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 418 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 419 CHECK_LIB([lame], [mp3lame], [lame_init])
 420 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 421 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 422 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 423 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 424 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 425 CHECK_LIB([openjpeg], [openjpeg], [opj_version])
 426 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 427 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 428 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 429 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 430 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 431 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 432 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 433 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 434 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 435 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 436 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 437 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 438 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 439 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 440 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 441 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 442 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 443 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 444 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 445 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 446 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 447 CHECK_LIB([a52dec], [a52], [a52_init])
 448 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 449 CHECK_LIB([encore], [encore], [encore])
 450 CHECK_HEADERS([encore], [encore headers], [encore.h])
 451 CHECK_LIB([faac], [faac], [faacEncOpen])
 452 CHECK_HEADERS([faac], [faac headers], [faac.h])
 453 CHECK_LIB([faad2], [faad], [faacDecInit])
 454 CHECK_HEADERS([faad2], [faad headers], [faad.h])
 455 CHECK_LIB([giflib], [gif], [DGifOpen])
 456 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 457 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 458 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 459
 460
 461 AC_DEFUN([CHECK_WANT], [
 462 RESULT=yes
 463 AC_ARG_WITH(m4_tolower([$1]),
 464  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 465   [WANT_$1=$withval],[WANT_$1=$2])
 466 # WANT_$1
 467 if test "x$WANT_$1" != "xno" ; then
 468  m4_quote($4)
 469  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 470   echo "=== want $1 Failed."
 471   WANT_$1=no
 472  else
 473   WANT_$1=yes
 474  fi
 475 fi
 476 CFG_WANTS+=" $1"
 477 AC_SUBST([WANT_$1])
 478 ])
 479
 480 CHECK_WANT([GL], [auto], [use opengl], [
 481  CHECK_LIB([GL], [GL], [glUseProgram])
 482  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 483  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 484
 485 CHECK_WANT([OSS], [auto], [use OSS audio], [
 486  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 487
 488 CHECK_WANT([XFT], [auto], [use libXft], [
 489  CHECK_LIB([XFT], [Xft], [XftInit])
 490  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 491
 492 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 493  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 494  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 495
 496 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 497  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 498  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 499  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 500  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 501  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 502  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 503  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 504  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 505
 506 CHECK_WANT([DV], [auto], [use dv], [
 507  CHECK_LIB([libdv], [dv], [dv_init])
 508  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 509
 510 CHECK_WANT([DVB], [auto], [use dvb], [
 511  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 512
 513 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 514  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 515
 516 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 517  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 518
 519 CHECK_WANT([ESOUND], [no], [use esd], [
 520  CHECK_LIB([esound], [esd], [esd_open_sound])
 521  CHECK_HEADERS([esound], [esound headers], [esd.h])
 522  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 523  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 524
 525 CHECK_WANT([DL], [auto], [system has libdl], [
 526  CHECK_LIB([DL], [dl], [dlopen])])
 527
 528 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 529  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 530
 531
 532 AC_MSG_CHECKING([for openexr available])
 533 saved_LIBS="$LIBS"
 534 saved_CXXFLAGS="$CXXFLAGS"
 535 # ilmbase libs
 536 LIBS=" -lIlmImf -lIlmThread -lIex"
 537 CXXFLAGS="-I/usr/include/OpenEXR"
 538 AC_LANG_PUSH(C++)
 539 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 540 #include "ImfChannelList.h"
 541 #include "ImfChromaticities.h"
 542 #include "ImfCompression.h"
 543 #include "ImfIO.h"
 544 #include "ImfInputFile.h"
 545 #include "ImfOutputFile.h"
 546 #include "ImfPixelType.h"
 547 #include "ImfRgbaFile.h"
 548 #include "ImfRgbaYca.h"
 549 #include "ImfVersion.h"
 550 class EXRIStream : public Imf::IStream { public:
 551 EXRIStream() : Imf::IStream("mypath") {} };
 552 class EXROStream : public Imf::OStream { public:
 553 EXROStream() : Imf::OStream("mypath") {} };
 554 ]])], [HAVE_openexr=yes], [HAVE_openexr=no])
 555 if test "x$HAVE_openexr" = "xyes"; then
 556   SHARED_openexr="$LIBS"
 557 fi
 558 LIBS="$saved_LIBS"
 559 CXXFLAGS="$saved_CXXFLAGS"
 560 AC_LANG_POP(C++)
 561 AC_MSG_RESULT([$HAVE_openexr])
 562 AC_SUBST([HAVE_openexr])
 563
 564 # build global_config
 565 OBJDIR=`uname -m`
 566 AC_SUBST(OBJDIR)
 567
 568 echo "AC_HELP_STRING([Reason],[Package])"
 569 echo "AC_HELP_STRING([------],[-------])"
 570
 571 AC_DEFUN([PKG_DISABLED],[
 572   BUILD_$1=0
 573   AC_SUBST(BUILD_$1)
 574   echo "AC_HELP_STRING([disabled],[$1])"
 575 ])
 576 AC_DEFUN([PKG_SHARED],[
 577  BUILD_$1=0
 578  AC_SUBST(BUILD_$1)
 579  SHARED_LIBS+="$SHARED_$1"
 580  echo "AC_HELP_STRING([shared],[$1])"
 581 ])
 582 AC_DEFUN([PKG_STATIC],[
 583  BUILD_$1=1
 584  AC_SUBST(BUILD_$1)
 585  STATIC_BLDS+=" [$1]"
 586  echo "AC_HELP_STRING([$2],[$1])"
 587 ])
 588 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 589
 590 # order matters
 591 for dep in \
 592         ffmpeg/faac ffmpeg/faad2 ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 593         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/fdk \
 594         libiec61883/libraw1394 libavc1394/librom1394 \
 595         openexr/ilmbase ilmbase/libogg \
 596         libtheora/libogg libtheora/libvorbis ; do
 597   lib=`dirname $dep`
 598   eval pkg_lib="\$PKG_$lib"; eval have_lib="\$HAVE_$lib";
 599   if test "x$pkg_lib" != "xno" ; then
 600     needs=`basename $dep`
 601     eval "PKG_$needs=yes"
 602   fi
 603 done
 604
 605 AC_DEFUN([PKG_PROVIDE],[
 606 if test "x$BUILD_$1" = "x" ; then
 607  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 608   PKG_DISABLED([$1])
 609  elif test "x$PKG_$1" = "xyes"; then
 610   PKG_FORCED([$1])
 611  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 612   PKG_STATIC([$1],[static])
 613  elif test "x$HAVE_$1" = "xyes"; then
 614   PKG_SHARED([$1])
 615  else
 616   PKG_STATIC([$1],[needed])
 617  fi
 618 fi
 619 ])
 620
 621 PKG_PROVIDE([a52dec])
 622 PKG_PROVIDE([djbfft])
 623 PKG_PROVIDE([encore])
 624 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 625 PKG_PROVIDE([esound],[$WANT_ESOUND])
 626 PKG_PROVIDE([faac])
 627 PKG_PROVIDE([faad2])
 628 PKG_PROVIDE([fdk])
 629 PKG_PROVIDE([ffmpeg])
 630 PKG_PROVIDE([fftw])
 631 PKG_PROVIDE([flac])
 632 PKG_PROVIDE([giflib])
 633 PKG_PROVIDE([ilmbase])
 634 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 635 PKG_PROVIDE([lame])
 636 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 637 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 638 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 639 PKG_PROVIDE([libdv],[$WANT_DV])
 640 PKG_PROVIDE([libjpeg])
 641 PKG_PROVIDE([libogg])
 642 PKG_PROVIDE([libsndfile])
 643 PKG_PROVIDE([libtheora])
 644 PKG_PROVIDE([libuuid])
 645 PKG_PROVIDE([libvorbis])
 646 PKG_PROVIDE([mjpegtools])
 647 PKG_PROVIDE([openexr])
 648 PKG_PROVIDE([openjpeg])
 649 PKG_PROVIDE([tiff])
 650 PKG_PROVIDE([twolame])
 651 PKG_PROVIDE([x264])
 652 PKG_PROVIDE([x265])
 653 PKG_PROVIDE([libvpx])
 654
 655 AC_SUBST(STATIC_BLDS)
 656 AC_SUBST(SHARED_LIBS)
 657
 658 for f in $SYSTEM_LIBS; do
 659   echo "AC_HELP_STRING([system],[$f])"
 660 done
 661 AC_SUBST(SYSTEM_LIBS)
 662
 663 echo ""
 664 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 665          VIDEO4LINUX2 ESOUND; do
 666   eval vv="\$WANT_$v"
 667   if test "x$vv" != "xno"; then
 668     CFG_CFLAGS+=" -DHAVE_$v"
 669     vv=with
 670   else
 671     vv=without
 672   fi
 673   v=`echo "$v" | tr "A-Z" "a-z"`
 674   echo "  using: $vv-$v"
 675 done
 676
 677 echo "  using: with-jobs = $WANT_JOBS"
 678 echo "  using: exec-name = $WANT_CIN"
 679 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 680 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 681 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 682 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 683 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 684 echo ""
 685 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 686 echo "  using: static-build = $WANT_STATIC_BUILD"
 687 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 688 echo ""
 689
 690 # build extras
 691 if test "x$HAVE_NUMA" = "xyes"; then
 692   EXTRA_LIBS+=' -lnuma'
 693 fi
 694 if test "x$HAVE_DL" = "xyes"; then
 695   EXTRA_LIBS+=' -ldl'
 696   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 697 fi
 698 AC_SUBST(EXTRA_LIBS)
 699 AC_SUBST(FFMPEG_EXTRA_CFG)
 700 AC_SUBST(WANT_X264_HIDEPTH)
 701 AC_SUBST(WANT_X265_HIDEPTH)
 702
 703 if test "x$BUILD_openexr" = "x0"; then
 704   CFG_CFLAGS+=" -I/usr/include/OpenEXR"
 705 fi
 706
 707 AC_SUBST(CFG_CFLAGS)
 708 AC_SUBST(CFG_CXXFLAGS)
 709
 710 AC_CONFIG_FILES([Makefile])
 711 AC_OUTPUT
 712
 713 exec > global_config
 714
 715 echo "SHELL := /bin/bash"
 716 echo "export SHELL"
 717 echo "WANT_JOBS := $WANT_JOBS"
 718 echo ""
 719 echo "OBJDIR := $OBJDIR"
 720 echo "BINDIR := \$(TOPDIR)/bin"
 721 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 722 echo "GUICAST := \$(TOPDIR)/guicast"
 723 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 724 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 725 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 726 echo "PLUGINS := \$(TOPDIR)/plugins"
 727 echo "TDB := \$(TOPDIR)/db"
 728 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 729 echo "EXTRA_LIBS := $EXTRA_LIBS"
 730 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 731 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 732 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 733 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 734 echo ""
 735
 736 echo "WANT_CIN := $WANT_CIN"
 737 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 738 echo ""
 739
 740 echo "ifndef CFLAGS_"
 741 echo "ifdef CFLAGS"
 742 echo "CFLAGS_ := \$(CFLAGS)"
 743 echo "else"
 744 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 745 echo "endif"
 746 echo "endif"
 747
 748 echo "CFLAGS := \$(CFLAGS_)"
 749 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 750 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 751 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 752 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 753 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 754 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 755 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 756 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 757 echo ""
 758 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 759 echo ""
 760
 761 if test  $WANT_X264_HIDEPTH = "yes" ; then
 762   echo "x264.cfg_params := --enable-static --bit-depth=10"
 763 fi
 764 if test  $WANT_X265_HIDEPTH = "yes" ; then
 765   echo "x265.cfg_params := -DENABLE_SHARED=no -DHIGH_BIT_DEPTH:BOOL=ON"
 766 fi
 767
 768 for pkg in $STATIC_PKGS; do echo "static_pkgs += $pkg"; done
 769 echo ""
 770 for pkg in $STATIC_BLDS; do
 771   echo "static_blds += $pkg"
 772   ver_pkg=ver_$pkg
 773   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 774   inc_pkg=inc_$pkg
 775   echo "$inc_pkg := \\"
 776   for inc in ${!inc_pkg}; do
 777     echo "  -I\$($ver_pkg)/$inc \\"
 778   done
 779   echo ""
 780   echo "static_incs += \$(inc_$pkg)"
 781   lib_pkg=lib_$pkg
 782   echo "$lib_pkg := \\"
 783   for lib in ${!lib_pkg}; do
 784     echo "  \$($ver_pkg)/$lib \\"
 785   done
 786   echo ""
 787   echo "static_libs += \$($lib_pkg)"
 788   echo ""
 789 done
 790 echo ""
 791
 792 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 793 echo ""
 794 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 795 echo "export static_pkgs static_blds shared_libs system_libs"
 796 echo ""
 797
 798 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 799 echo "libraries += -Wl,--start-group"
 800 echo "libraries += \$(thirdparty_libraries)"
 801 echo "libraries += \$(system_libs)"
 802 echo "libraries += \$(EXTRA_LIBS)"
 803 echo "libraries += -Wl,--end-group"
 804 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 805 echo "libraries += \$(thirdparty_libraries)"
 806 echo "libraries += \$(system_libs)"
 807 echo "libraries += \$(EXTRA_LIBS)"
 808 echo ""
 809 echo "export thirdparty_libraries libraries"
 810 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 811 echo "unexport CFLAGS CXXFLAGS LDFLAGS"