cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-cv.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 CFG_CFLAGS+=" -Wno-unused-result"
  15 CFG_CFLAGS+=" -Wno-stringop-truncation"
  16 CFG_CFLAGS+=" -Wno-stringop-overflow"
  17 CFG_CFLAGS+=" -Wno-format-truncation"
  18 CFG_CFLAGS+=" -Wno-format-overflow"
  19 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  20 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  21 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  22 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  23 CFG_CFLAGS+=" -I/usr/include/freetype2"
  24
  25 AC_DEFUN([CHECK_WITH], [
  26 AC_ARG_WITH([$1],
  27   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  28   [WANT_$3=$withval], [WANT_$3='$4'])
  29 AC_SUBST([WANT_$3])
  30 ])
  31
  32 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  33 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  34 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  35 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  36 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  37 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  38 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  39 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  40 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  41 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  42 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  43
  44 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  45   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  46   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  47   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  48   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  49   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  50   sinstall=dinstall
  51   suninstall=duninstall
  52 else
  53   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  54     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  55     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  56     echo "$dir"`
  57   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  58     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  59     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  60     echo "$dir"`
  61   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  62     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  63     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  64     echo "$dir"`
  65   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  66        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  67   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  68     usrlib+="64"
  69   WANT_LOCALE_DIR="$lcldir"
  70   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  71   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  72   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  73   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  74   sinstall=cinstall
  75   suninstall=cuninstall
  76 fi
  77 AC_SUBST(sinstall)
  78 AC_SUBST(suninstall)
  79
  80 if test "x$WANT_JOBS" = "xauto"; then
  81   CPUS=`grep -c "^proc" /proc/cpuinfo`
  82   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
  83 fi
  84
  85 AC_DEFUN([PKG_DEF],[
  86 STATIC_PKGS+=" [$1]"
  87 ver_$1="$2"
  88 lib_$1="$3"
  89 inc_$1="$4"
  90 ])
  91
  92 AC_DEFUN([PKG_3RD],[
  93 AC_ARG_ENABLE([$1],
  94   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
  95   [PKG_$1=$enableval], [PKG_$1=$2])
  96 PKG_DEF([$1],[$3],[$4],[$5])
  97 ])
  98
  99 # thirdparty builds
 100
 101 PKG_3RD([a52dec],[yes],
 102   [a52dec-0.7.4],
 103   [ liba52/.libs/liba52.a ],
 104   [ include ])
 105
 106 PKG_3RD([djbfft],[yes],
 107   [djbfft-0.76],
 108   [ libdjbfft.a ],
 109   [ . ])
 110
 111 PKG_3RD([audiofile],[no],
 112   [audiofile-0.3.6],
 113   [ libaudiofile/.libs/libaudiofile.a \
 114     libaudiofile/modules/.libs/libmodules.a \
 115     libaudiofile/alac/.libs/libalac.a ],
 116   [ libaudiofile ])
 117
 118 PKG_3RD([encore],[no],
 119   [encore-5.0],
 120   [ \$(OBJDIR)/libencore.a ],
 121   [ . ])
 122
 123 PKG_3RD([esound],[no],
 124   [esound-0.2.41],
 125   [ .libs/libesd.a \
 126     .libs/libesddsp.a ],
 127   [ . ])
 128
 129 PKG_3RD([fdk],[auto],
 130   [fdk-aac-0.1.5],
 131   [ .libs/libfdk-aac.a ],
 132   [ libAACdec/include libAACenc/include libSYS/include ])
 133
 134 PKG_3RD([ffmpeg],[yes],
 135   [ffmpeg-3.4.1],
 136   [ libavutil/libavutil.a \
 137     libavcodec/libavcodec.a \
 138     libpostproc/libpostproc.a \
 139     libavdevice/libavdevice.a \
 140     libavformat/libavformat.a \
 141     libswscale/libswscale.a \
 142     libavfilter/libavfilter.a \
 143     libswresample/libswresample.a ],
 144   [ . ])
 145
 146 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 147   ver_ffmpeg="ffmpeg.git"
 148 fi
 149
 150 PKG_3RD([fftw],[auto],
 151   [fftw-3.3.7],
 152   [ .libs/libfftw3.a \
 153     libbench2/libbench2.a \
 154     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 155     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 156     rdft/scalar/.libs/librdft_scalar.a \
 157     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 158     rdft/.libs/librdft.a \
 159     api/.libs/libapi.a \
 160     reodft/.libs/libreodft.a \
 161     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 162     dft/scalar/.libs/libdft_scalar.a \
 163     dft/.libs/libdft.a \
 164     kernel/.libs/libkernel.a \
 165     simd-support/.libs/libsimd_support.a ],
 166   [ api ])
 167
 168 PKG_3RD([flac],[auto],
 169   [flac-1.3.2],
 170   [ src/libFLAC/.libs/libFLAC.a \
 171     src/libFLAC++/.libs/libFLAC++.a \
 172     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 173     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 174     src/share/grabbag/.libs/libgrabbag.a \
 175     src/share/utf8/.libs/libutf8.a \
 176     src/test_libs_common/.libs/libtest_libs_common.a ],
 177   [ include ])
 178
 179 PKG_3RD([giflib],[yes],
 180   [giflib-5.1.4],
 181   [ lib/.libs/libgif.a \
 182     util/libgetarg.a ],
 183   [ lib ])
 184
 185 PKG_3RD([ilmbase],[auto],
 186   [ilmbase-2.2.1],
 187   [ Iex/.libs/libIex.a \
 188     IexMath/.libs/libIexMath.a \
 189     Half/.libs/libHalf.a \
 190     Imath/.libs/libImath.a \
 191     IlmThread/.libs/libIlmThread.a ],
 192   [ Iex Half Imath config IlmThread ])
 193
 194 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 195
 196 PKG_3RD([lame],[auto],
 197   [lame-3.100],
 198   [ libmp3lame/.libs/libmp3lame.a \
 199     mpglib/.libs/libmpgdecoder.a ],
 200   [ include ])
 201
 202 PKG_3RD([libavc1394],[auto],
 203   [libavc1394-0.5.4],
 204   [ libavc1394/.libs/libavc1394.a \
 205     librom1394/.libs/librom1394.a \
 206     common/.libs/libraw1394util.a ],
 207   [ . ])
 208
 209 PKG_3RD([libraw1394],[auto],
 210   [libraw1394-2.1.2],
 211   [ src/.libs/libraw1394.a ],
 212   [ . ])
 213
 214 PKG_3RD([libiec61883],[auto],
 215   [libiec61883-1.2.0],
 216   [ src/.libs/libiec61883.a ],
 217   [ src ])
 218
 219 PKG_3RD([libdv],[auto],
 220   [libdv-1.0.0],
 221   [ libdv/.libs/libdv.a ],
 222   [ . ])
 223
 224 PKG_3RD([libjpeg],[auto],
 225   [libjpeg-turbo-1.5.1],
 226   [ .libs/libjpeg.a \
 227     .libs/libturbojpeg.a \
 228     simd/.libs/libsimd.a ],
 229   [ . ])
 230
 231 PKG_3RD([opus],[auto],
 232   [opus-1.2.1],
 233   [ .libs/libopus.a ],
 234   [ include ])
 235
 236 PKG_3RD([openjpeg],[auto],
 237   [openjpeg-2.1.0-20160221],
 238   [ bin/libopenjp2.a ],
 239   [ src/lib/openjp2 ])
 240
 241 PKG_3RD([libogg],[auto],
 242   [libogg-1.3.2],
 243   [ src/.libs/libogg.a ],
 244   [ include ])
 245
 246 PKG_3RD([libsndfile],[auto],
 247   [libsndfile-1.0.28],
 248   [ src/.libs/libsndfile.a \
 249     src/.libs/libcommon.a \
 250     src/G72x/.libs/libg72x.a \
 251     src/GSM610/.libs/libgsm.a ],
 252   [ . ])
 253
 254 PKG_3RD([libtheora],[auto],
 255   [libtheora-1.1.1],
 256   [ lib/.libs/libtheora.a \
 257     lib/.libs/libtheoradec.a \
 258     lib/.libs/libtheoraenc.a ],
 259   [ . ])
 260
 261 PKG_3RD([libuuid],[yes],
 262   [libuuid-1.0.3],
 263   [ .libs/libuuid.a ],
 264   [ . ])
 265
 266 PKG_3RD([libvorbis],[auto],
 267   [libvorbis-1.3.5],
 268   [ lib/.libs/libvorbis.a \
 269     lib/.libs/libvorbisenc.a \
 270     lib/.libs/libvorbisfile.a ],
 271   [ include . ])
 272
 273 PKG_3RD([mjpegtools],[yes],
 274   [mjpegtools-2.1.0],
 275   [ utils/mmxsse/.libs/libmmxsse.a \
 276     utils/.libs/libmjpegutils.a \
 277     lavtools/.libs/liblavfile.a \
 278     lavtools/.libs/liblavjpeg.a \
 279     mplex/.libs/libmplex2.a \
 280     yuvfilters/.libs/libyuvfilters.a \
 281     mpeg2enc/.libs/libmpeg2encpp.a ],
 282   [ .  lavtools utils ])
 283
 284 PKG_3RD([openexr],[auto],
 285   [openexr-2.2.1],
 286   [ IlmImf/.libs/libIlmImf.a \
 287     IlmImfUtil/.libs/libIlmImfUtil.a ],
 288   [ IlmImf config ])
 289
 290 #PKG_3RD([festival],[no],
 291 #  [festival],
 292 #  [],
 293 #  [])
 294 #PKG_3RD(speech_tools,[no],
 295 #  [speech_tools],
 296 #  [],
 297 #  [])
 298 #
 299 PKG_3RD([tiff],[auto],
 300   [tiff-4.0.9],
 301   [ libtiff/.libs/libtiff.a \
 302     libtiff/.libs/libtiffxx.a \
 303     port/.libs/libport.a ],[
 304    . ])
 305
 306 PKG_3RD([twolame],[auto],
 307   [twolame-0.3.13],
 308   [ libtwolame/.libs/libtwolame.a ],
 309   [  libtwolame ])
 310
 311 PKG_3RD([x264],[auto],
 312   [x264-snapshot-20180118-2245],
 313   [ libx264.a ],
 314   [ . ])
 315
 316 PKG_3RD([x265],[auto],
 317   [x265_v2.6],
 318   [ libx265.a ],
 319   [ . source ])
 320
 321 PKG_3RD([libvpx],[auto],
 322   [libvpx-1.6.1],
 323   [ libvpx.a ],
 324   [ . ])
 325
 326 AC_SUBST(STATIC_PKGS)
 327
 328 AC_DEFUN([CHECK_ENABLE], [
 329 AC_ARG_ENABLE([$1],
 330   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 331   [WANT_$2=$enableval], [WANT_$2=[$4]])
 332 ])
 333
 334 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 335 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 336 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10/12bit], [no])
 337
 338 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 339
 340 AC_DEFUN([CHECK_PROG], [
 341  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 342 ])
 343 AC_DEFUN([REQUIRE_PROG], [
 344  CHECK_PROG([$1],[$2])
 345  if test "x$PROG_$1" = "xno"; then
 346    AC_MSG_WARN([$2 is missing and required.])
 347    FATAL_ERROR=1
 348  fi
 349 ])
 350
 351 # Checks for programs.
 352
 353 REQUIRE_PROG(NASM, [nasm])
 354 REQUIRE_PROG(YASM, [yasm])
 355 REQUIRE_PROG(OBJCOPY, [objcopy])
 356 if test "x$FATAL_ERROR" != "x"; then
 357  AC_MSG_ERROR("fatal eror.")
 358 fi
 359 CHECK_PROG(PACTL, [pactl])
 360 WANT_PACTL=$PROG_PACTL
 361
 362 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 363 if test "$no_utf" = "yes"; then
 364   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 365 fi
 366
 367 # Checks for headers/libraries.
 368
 369 AC_DEFUN([CHECK_HEADERS], [
 370 if test "x$HAVE_$1" != "xno"; then
 371  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 372   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 373 ]])])
 374  AC_SUBST([HAVE_$1])
 375  AC_MSG_CHECKING([$2])
 376  AC_MSG_RESULT([$HAVE_$1])
 377  if test "x$HAVE_$1" = "xno"; then
 378   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 379  fi
 380 fi
 381 ])
 382
 383 AC_DEFUN([CHECK_LIB], [
 384 if test "x$HAVE_$1" != "xno"; then
 385  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 386   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 387   AC_SUBST([HAVE_$1])
 388   if test "x$HAVE_$1" = "xyes"; then
 389    if test "x$PKG_$1" = "x"; then
 390     SYSTEM_LIBS+=" -l[$2]"
 391     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 392    else
 393     SHARED_$1+=" -l[$2]"
 394     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 395    fi
 396   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 397  fi
 398 fi
 399 ])
 400
 401 CHECK_LIB([X11], [X11], [XOpenDisplay])
 402 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 403 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 404 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 405 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 406 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 407 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 408 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 409 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 410 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 411 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 412 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 413 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 414 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 415 CHECK_LIB([PNG], [png], [png_read_png])
 416 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 417 CHECK_LIB([Z], [z], [gzopen])
 418 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 419 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 420 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 421 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 422 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 423 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 424 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 425 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 426 CHECK_LIB([lame], [mp3lame], [lame_init])
 427 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 428 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 429 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 430 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 431 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 432 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 433 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 434 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 435 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 436 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 437 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 438 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 439 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 440 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 441 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 442 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 443 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 444 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 445 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 446 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 447 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 448 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 449 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 450 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 451 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 452 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 453 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 454 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 455 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 456 CHECK_LIB([a52dec], [a52], [a52_init])
 457 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 458 CHECK_LIB([encore], [encore], [encore])
 459 CHECK_HEADERS([encore], [encore headers], [encore.h])
 460 CHECK_LIB([giflib], [gif], [DGifOpen])
 461 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 462 CHECK_LIB([fdk], [fdk-aac], [faacDecInit])
 463 CHECK_HEADERS([fdk], [fdk headers], [fdk-aac/genericStds.h])
 464 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 465 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 466
 467 #if test "x$HAVE_mjpegtools" = "xyes"; then
 468 #CFG_CFLAGS+=" -I/usr/include/mjpegtools"
 469 #fi
 470
 471 AC_DEFUN([CHECK_WANT], [
 472 RESULT=yes
 473 AC_ARG_WITH(m4_tolower([$1]),
 474  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 475   [WANT_$1=$withval],[WANT_$1=$2])
 476 # WANT_$1
 477 if test "x$WANT_$1" != "xno" ; then
 478  m4_quote($4)
 479  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 480   echo "=== want $1 Failed."
 481   WANT_$1=no
 482  elif test "x$WANT_$1" = "xauto" ; then
 483   WANT_$1=yes
 484  fi
 485 fi
 486 CFG_WANTS+=" $1"
 487 AC_SUBST([WANT_$1])
 488 ])
 489
 490 CHECK_WANT([GL], [auto], [use opengl], [
 491  CHECK_LIB([GL], [GL], [glUseProgram])
 492  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 493  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 494
 495 CHECK_WANT([OSS], [auto], [use OSS audio], [
 496  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 497
 498 CHECK_WANT([XFT], [auto], [use libXft], [
 499  CHECK_LIB([XFT], [Xft], [XftInit])
 500  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 501
 502 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 503  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 504  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 505
 506 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 507  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 508  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 509  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 510  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 511  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 512  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 513  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 514  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 515
 516 CHECK_WANT([DV], [auto], [use dv], [
 517  CHECK_LIB([libdv], [dv], [dv_init])
 518  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 519
 520 CHECK_WANT([DVB], [auto], [use dvb], [
 521  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 522
 523 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 524  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 525
 526 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 527  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 528
 529 CHECK_WANT([ESOUND], [no], [use esd], [
 530  CHECK_LIB([esound], [esd], [esd_open_sound])
 531  CHECK_HEADERS([esound], [esound headers], [esd.h])
 532  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 533  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 534
 535 CHECK_WANT([LIBOPUS], [auto], [use libopus], [
 536  CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 537  CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])])
 538
 539 CHECK_WANT([DL], [auto], [system has libdl], [
 540  CHECK_LIB([DL], [dl], [dlopen])])
 541
 542 CHECK_WANT([EXR], [auto], [use exr], [])
 543 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 544  WANT_OPENCV="$withval"
 545 ])
 546
 547 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 548  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 549
 550 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 551  AC_MSG_CHECKING([for openexr available])
 552  saved_LIBS="$LIBS"
 553  saved_CXXFLAGS="$CXXFLAGS"
 554  # ilmbase libs
 555  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 556  CXXFLAGS="-I/usr/include/OpenEXR"
 557  AC_LANG_PUSH(C++)
 558  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 559 #include "ImfChannelList.h"
 560 #include "ImfChromaticities.h"
 561 #include "ImfCompression.h"
 562 #include "ImfIO.h"
 563 #include "ImfInputFile.h"
 564 #include "ImfOutputFile.h"
 565 #include "ImfPixelType.h"
 566 #include "ImfRgbaFile.h"
 567 #include "ImfRgbaYca.h"
 568 #include "ImfVersion.h"
 569 class EXRIStream : public Imf::IStream { public:
 570 EXRIStream() : Imf::IStream("mypath") {} };
 571 class EXROStream : public Imf::OStream { public:
 572 EXROStream() : Imf::OStream("mypath") {} };
 573 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 574  RESULT="$HAVE_OPENEXR"
 575  if test "x$RESULT" = "xyes"; then
 576    SHARED_openexr="$LIBS"
 577    CFG_CFLAGS+=" -I/usr/include/OpenEXR"
 578  fi
 579  LIBS="$saved_LIBS"
 580  CXXFLAGS="$saved_CXXFLAGS"
 581  AC_LANG_POP(C++)
 582  AC_MSG_RESULT([$HAVE_OPENEXR])
 583 ])
 584 AC_SUBST([HAVE_OPENEXR])
 585
 586 # build global_config
 587 OBJDIR=`uname -m`
 588 AC_SUBST(OBJDIR)
 589
 590 echo "AC_HELP_STRING([Reason],[Package])"
 591 echo "AC_HELP_STRING([------],[-------])"
 592
 593 AC_DEFUN([PKG_DISABLED],[
 594  PKG_$1="no"
 595  BUILD_$1=0
 596  AC_SUBST(BUILD_$1)
 597  echo "AC_HELP_STRING([disabled],[$1])"
 598 ])
 599 AC_DEFUN([PKG_SHARED],[
 600  BUILD_$1=0
 601  AC_SUBST(BUILD_$1)
 602  SHARED_LIBS+="$SHARED_$1"
 603  echo "AC_HELP_STRING([shared],[$1])"
 604 ])
 605 AC_DEFUN([PKG_STATIC],[
 606  PKG_$1="yes"
 607  BUILD_$1=1
 608  AC_SUBST(BUILD_$1)
 609  STATIC_BLDS+=" [$1]"
 610  echo "AC_HELP_STRING([$2],[$1])"
 611 ])
 612 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 613
 614 # order matters
 615 for dep in \
 616         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 617         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 ffmpeg/fdk \
 618         libiec61883/libraw1394 libavc1394/librom1394 \
 619         openexr/ilmbase ilmbase/libogg \
 620         libtheora/libogg libtheora/libvorbis ; do
 621   lib=`dirname $dep`;  needs=`basename $dep`
 622   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 623   if test "x$pkg_lib" != "xno"; then
 624     eval "PKG_$needs=yes"
 625   fi
 626 done
 627
 628 AC_DEFUN([PKG_PROVIDE],[
 629 if test "x$BUILD_$1" = "x" ; then
 630  if test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 631   PKG_DISABLED([$1])
 632  elif test "x$PKG_$1" = "xyes"; then
 633   PKG_FORCED([$1])
 634  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 635   PKG_STATIC([$1],[static])
 636  elif test "x$HAVE_$1" = "xyes"; then
 637   PKG_SHARED([$1])
 638  else
 639   PKG_STATIC([$1],[needed])
 640  fi
 641 fi
 642 ])
 643
 644 PKG_PROVIDE([a52dec])
 645 PKG_PROVIDE([djbfft])
 646 PKG_PROVIDE([encore])
 647 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 648 PKG_PROVIDE([esound],[$WANT_ESOUND])
 649 PKG_PROVIDE([fdk])
 650 PKG_PROVIDE([ffmpeg])
 651 PKG_PROVIDE([fftw])
 652 PKG_PROVIDE([flac])
 653 PKG_PROVIDE([giflib])
 654 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 655 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 656 PKG_PROVIDE([lame])
 657 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 658 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 659 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 660 PKG_PROVIDE([libdv],[$WANT_DV])
 661 PKG_PROVIDE([libjpeg])
 662 PKG_PROVIDE([libogg])
 663 PKG_PROVIDE([libsndfile])
 664 PKG_PROVIDE([libtheora])
 665 PKG_PROVIDE([libuuid])
 666 PKG_PROVIDE([libvorbis])
 667 PKG_PROVIDE([mjpegtools])
 668 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 669 PKG_PROVIDE([openjpeg])
 670 PKG_PROVIDE([tiff])
 671 PKG_PROVIDE([twolame])
 672 PKG_PROVIDE([x264])
 673 PKG_PROVIDE([x265])
 674 PKG_PROVIDE([libvpx])
 675 PKG_PROVIDE([opus], [$WANT_OPUS])
 676
 677 AC_SUBST(STATIC_BLDS)
 678 AC_SUBST(SHARED_LIBS)
 679
 680 for f in $SYSTEM_LIBS; do
 681   echo "AC_HELP_STRING([system],[$f])"
 682 done
 683 AC_SUBST(SYSTEM_LIBS)
 684
 685 echo ""
 686 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 687          VIDEO4LINUX2 ESOUND PACTL OPENEXR; do
 688   eval vv="\$WANT_$v"
 689   if test "x$vv" != "xno"; then
 690     CFG_CFLAGS+=" -DHAVE_$v"
 691     vv=with
 692   else
 693     vv=without
 694   fi
 695   v=`echo "$v" | tr "A-Z" "a-z"`
 696   echo "  using: $vv-$v"
 697 done
 698
 699 echo "  using: with-jobs = $WANT_JOBS"
 700 echo "  using: exec-name = $WANT_CIN"
 701 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 702 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 703 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 704 echo "  using: with-browser = $WANT_CIN_BROWSER"
 705 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 706 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 707 echo "  using: with-opencv = $WANT_OPENCV"
 708 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 709 echo ""
 710 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 711 echo "  using: static-build = $WANT_STATIC_BUILD"
 712 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 713 echo ""
 714
 715 # build extras
 716 if test "x$HAVE_tiff" = "xyes"; then
 717   if test "x$HAVE_jbig" = "xyes"; then
 718     EXTRA_LIBS+=' -ljbig'
 719   fi
 720 fi
 721 if test "x$HAVE_NUMA" = "xyes"; then
 722   EXTRA_LIBS+=' -lnuma'
 723 fi
 724 if test "x$HAVE_DL" = "xyes"; then
 725   EXTRA_LIBS+=' -ldl'
 726   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 727 fi
 728 if test "x$HAVE_opus" = "xyes"; then
 729   EXTRA_LIBS+=' -lopus'
 730   CFG_CFLAGS+=' -I/usr/include/opus'
 731   FFMPEG_EXTRA_CFG+=' --enable-libopus'
 732 fi
 733
 734 AC_SUBST(EXTRA_LIBS)
 735 AC_SUBST(FFMPEG_EXTRA_CFG)
 736 AC_SUBST(WANT_X264_HIDEPTH)
 737 AC_SUBST(WANT_X265_HIDEPTH)
 738
 739 AC_SUBST(CFG_CFLAGS)
 740 AC_SUBST(CFG_CXXFLAGS)
 741
 742 AC_CONFIG_FILES([Makefile])
 743 AC_OUTPUT
 744
 745 exec > global_config
 746
 747 echo "SHELL := /bin/bash"
 748 echo "export SHELL"
 749 echo "WANT_JOBS := $WANT_JOBS"
 750 echo ""
 751 echo "OBJDIR := $OBJDIR"
 752 echo "BINDIR := \$(TOPDIR)/bin"
 753 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 754 echo "GUICAST := \$(TOPDIR)/guicast"
 755 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 756 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 757 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 758 echo "PLUGINS := \$(TOPDIR)/plugins"
 759 echo "TDB := \$(TOPDIR)/db"
 760 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 761 echo "EXTRA_LIBS := $EXTRA_LIBS"
 762 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 763 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 764 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 765 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 766 echo ""
 767
 768 echo "WANT_CIN := $WANT_CIN"
 769 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 770 echo ""
 771
 772 echo "ifndef CFLAGS_"
 773 echo "ifdef CFLAGS"
 774 echo "CFLAGS_ := \$(CFLAGS)"
 775 echo "else"
 776 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 777 echo "endif"
 778 echo "endif"
 779
 780 echo "CFLAGS := \$(CFLAGS_)"
 781 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 782 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 783 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 784 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 785 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 786 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 787 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 788 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 789 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 790 echo ""
 791 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 792 echo ""
 793
 794 if test  $WANT_X264_HIDEPTH = "yes" ; then
 795   echo "x264.cfg_params := --enable-static --bit-depth=10"
 796 fi
 797 if test  $WANT_X265_HIDEPTH = "yes" ; then
 798   echo "x265.cfg_params := -DENABLE_SHARED=no -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
 799 fi
 800
 801 for pkg in $STATIC_PKGS; do
 802   eval pkg_lib="\$PKG_$pkg"
 803   if test "x$pkg_lib" = "xno"; then continue; fi;
 804   echo "static_pkgs += $pkg"
 805 done
 806 echo ""
 807
 808 for pkg in $STATIC_BLDS; do
 809   echo "static_blds += $pkg"
 810   ver_pkg=ver_$pkg
 811   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 812   inc_pkg=inc_$pkg
 813   echo "$inc_pkg := \\"
 814   for inc in ${!inc_pkg}; do
 815     echo "  -I\$($ver_pkg)/$inc \\"
 816   done
 817   echo ""
 818   echo "static_incs += \$(inc_$pkg)"
 819   lib_pkg=lib_$pkg
 820   echo "$lib_pkg := \\"
 821   for lib in ${!lib_pkg}; do
 822     echo "  \$($ver_pkg)/$lib \\"
 823   done
 824   echo ""
 825   echo "static_libs += \$($lib_pkg)"
 826   echo ""
 827 done
 828 echo ""
 829
 830 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 831 echo ""
 832 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 833 echo "export static_pkgs static_blds shared_libs system_libs"
 834 echo ""
 835
 836 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 837 echo "libraries += -Wl,--start-group"
 838 echo "libraries += \$(thirdparty_libraries)"
 839 echo "libraries += \$(system_libs)"
 840 echo "libraries += \$(EXTRA_LIBS)"
 841 echo "libraries += -Wl,--end-group"
 842 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 843 echo "libraries += \$(thirdparty_libraries)"
 844 echo "libraries += \$(system_libs)"
 845 echo "libraries += \$(EXTRA_LIBS)"
 846 echo ""
 847 echo "export thirdparty_libraries libraries"
 848 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 849 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
 850
 851 if test "x$HAVE_tiff" = "xyes"; then
 852   if test "x$HAVE_jbig" != "xyes"; then
 853     echo "tiff.cfg_params+= --disable-jbig"
 854   fi
 855 fi
 856
 857 if test "x$WANT_GIT_FFMPEG" != "xno"; then
 858 echo "ffmpeg.git := $WANT_GIT_FFMPEG"
 859 fi
 860 if test "x$HAVE_opus" = "xyes"; then
 861 echo 'ffmpeg.cflags+=" -I/usr/include/opus"'
 862 fi