cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-gg.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 CFG_CFLAGS+=" -Wno-unknown-warning"
  15 CFG_CFLAGS+=" -Wno-unused-result"
  16 CFG_CFLAGS+=" -Wno-stringop-overflow"
  17 CFG_CFLAGS+=" -Wno-format-truncation"
  18 CFG_CFLAGS+=" -Wno-format-overflow"
  19 CFG_CFLAGS+=" -Wno-parentheses"
  20 CFG_CFLAGS+=" -Wno-stringop-truncation"
  21 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  22 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  23 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  24 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  25 CFG_CFLAGS+=" -I/usr/include -I/usr/local/include"
  26 CFG_CFLAGS+=" -I/usr/include/freetype2 -I/usr/local/include/freetype2"
  27 CFG_CFLAGS+=" -I/usr/include/uuid -I/usr/local/include/uuid"
  28 CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
  29
  30 AC_DEFUN([CHECK_WITH], [
  31 AC_ARG_WITH([$1],
  32   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  33   [WANT_$3=$withval], [WANT_$3='$4'])
  34 AC_SUBST([WANT_$3])
  35 ])
  36
  37 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  38 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  39 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  40 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  41 CHECK_WITH([lv2],[lv2 library support],[LV2],[yes])
  42 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  43 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  44 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  45 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  46 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  47 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  48 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  49 CHECK_WITH([noelision],[use noelision/libpthread],[NOELISION],[auto])
  50 CHECK_WITH([booby],[window lock trace booby trap],[BOOBY],[no])
  51 CHECK_WITH([libzmpeg],[build libzmpeg],[LIBZMPEG],[yes])
  52 CHECK_WITH([commercial],[enable commercial capture],[COMMERCIAL],[yes])
  53 CHECK_WITH([thirdparty],[use thirdparty build],[CIN_3RDPARTY],[yes])
  54
  55 if test "x$WANT_LV2" != "xno"; then
  56   GTK2_LIBS=`pkg-config --libs gtk+-2.0`
  57   AC_CHECK_LIB([m], [gtk_init], [HAVE_gtk=yes], [HAVE_gtk=no], [$GTK2_LIBS])
  58   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --cflags gtk+-2.0`" && HAVE_gtk=no
  59   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --libs gtk+-2.0`" && HAVE_gtk=no
  60   if test "x$HAVE_gtk" = "xno"; then
  61     AC_MSG_ERROR([LV2 requires gtk+-2.0 support.])
  62   fi
  63 fi
  64
  65 if test "x$WANT_COMMERCIAL" = "xyes" -a "x$WANT_LIBZMPEG" != "xyes" ; then
  66   AC_MSG_ERROR([commercial requires libzmpeg support.])
  67 fi
  68
  69 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  70   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  71   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  72   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  73   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  74   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  75 else
  76   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  77     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  78     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  79     echo "$dir"`
  80   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  81     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  82     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  83     echo "$dir"`
  84   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  85     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  86     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  87     echo "$dir"`
  88   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  89        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  90   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
  91     usrlib+="64"
  92   WANT_LOCALE_DIR="$lcldir"
  93   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
  94   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
  95   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
  96   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
  97 fi
  98
  99 CIN_INSTALLS=""
 100 CIN_UNINSTALLS=""
 101 if test "x$WANT_LIBZMPEG" = "xyes"; then
 102   CIN_INSTALLS+=" zmp_install"
 103   CIN_UNINSTALLS+=" zmp_uninstall"
 104 fi
 105 if test "x$WANT_COMMERCIAL" = "xyes"; then
 106   CIN_INSTALLS+=" com_install"
 107   CIN_UNINSTALLS+=" com_uninstall"
 108 fi
 109 if test "x$WANT_LADSPA_BUILD" = "xyes"; then
 110   CIN_INSTALLS+=" lad_install "
 111   CIN_UNINSTALLS+=" lad_uninstall "
 112 fi
 113 if test "x$WANT_LV2" = "xyes"; then
 114   CIN_INSTALLS+=" lv2_install "
 115   CIN_UNINSTALLS+=" lv2_uninstall "
 116 fi
 117 AC_SUBST(CIN_INSTALLS)
 118 AC_SUBST(CIN_UNINSTALLS)
 119
 120 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
 121   MAK_INSTALLS="dvl_install"
 122   MAK_UNINSTALLS="dvl_uninstall"
 123 else
 124   MAK_INSTALLS=" sys_install"
 125   MAK_UNINSTALLS="sys_uninstall"
 126 fi
 127 AC_SUBST(MAK_INSTALLS)
 128 AC_SUBST(MAK_UNINSTALLS)
 129
 130 if test "x$WANT_JOBS" = "xauto"; then
 131   CPUS=`grep -c "^proc" /proc/cpuinfo`
 132   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
 133 fi
 134
 135 AC_DEFUN([PKG_DEF],[
 136 STATIC_PKGS+=" [$1]"
 137 ver_$1="$2"
 138 lib_$1="$3"
 139 inc_$1="$4"
 140 ])
 141
 142 AC_DEFUN([PKG_3RD],[
 143 AC_ARG_ENABLE([$1],
 144   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
 145   [PKG_$1=$enableval], [PKG_$1=$2])
 146 PKG_DEF([$1],[$3],[$4],[$5])
 147 ])
 148
 149 # thirdparty builds
 150
 151 PKG_3RD([a52dec],[yes],
 152   [a52dec-0.7.4],
 153   [ liba52/.libs/liba52.a ],
 154   [ include ])
 155
 156 PKG_3RD([djbfft],[yes],
 157   [djbfft-0.76],
 158   [ libdjbfft.a ],
 159   [ . ])
 160
 161 PKG_3RD([audiofile],[no],
 162   [audiofile-0.3.6],
 163   [ libaudiofile/.libs/libaudiofile.a \
 164     libaudiofile/modules/.libs/libmodules.a \
 165     libaudiofile/alac/.libs/libalac.a ],
 166   [ libaudiofile ])
 167
 168 PKG_3RD([encore],[no],
 169   [encore-5.0],
 170   [ \$(OBJDIR)/libencore.a ],
 171   [ . ])
 172
 173 PKG_3RD([esound],[no],
 174   [esound-0.2.41],
 175   [ .libs/libesd.a \
 176     .libs/libesddsp.a ],
 177   [ . ])
 178
 179 PKG_3RD([ffmpeg],[yes],
 180   [ffmpeg-4.1],
 181   [ libavutil/libavutil.a \
 182     libavcodec/libavcodec.a \
 183     libpostproc/libpostproc.a \
 184     libavdevice/libavdevice.a \
 185     libavformat/libavformat.a \
 186     libswscale/libswscale.a \
 187     libavfilter/libavfilter.a \
 188     libswresample/libswresample.a ],
 189   [ . ])
 190
 191 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 192   ver_ffmpeg="ffmpeg.git"
 193 fi
 194
 195 PKG_3RD([fftw],[auto],
 196   [fftw-3.3.7],
 197   [ .libs/libfftw3.a \
 198     libbench2/libbench2.a \
 199     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 200     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 201     rdft/scalar/.libs/librdft_scalar.a \
 202     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 203     rdft/.libs/librdft.a \
 204     api/.libs/libapi.a \
 205     reodft/.libs/libreodft.a \
 206     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 207     dft/scalar/.libs/libdft_scalar.a \
 208     dft/.libs/libdft.a \
 209     kernel/.libs/libkernel.a \
 210     simd-support/.libs/libsimd_support.a ],
 211   [ api ])
 212
 213 PKG_3RD([flac],[auto],
 214   [flac-1.3.2],
 215   [ src/libFLAC/.libs/libFLAC.a \
 216     src/libFLAC++/.libs/libFLAC++.a \
 217     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 218     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 219     src/share/grabbag/.libs/libgrabbag.a \
 220     src/share/utf8/.libs/libutf8.a \
 221     src/test_libs_common/.libs/libtest_libs_common.a ],
 222   [ include ])
 223
 224 PKG_3RD([giflib],[yes],
 225   [giflib-5.1.4],
 226   [ lib/.libs/libgif.a \
 227     util/libgetarg.a ],
 228   [ lib ])
 229
 230 PKG_3RD([ilmbase],[auto],
 231   [ilmbase-2.2.1],
 232   [ Iex/.libs/libIex.a \
 233     IexMath/.libs/libIexMath.a \
 234     Half/.libs/libHalf.a \
 235     Imath/.libs/libImath.a \
 236     IlmThread/.libs/libIlmThread.a ],
 237   [ Iex Half Imath config IlmThread ])
 238
 239 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 240
 241 PKG_3RD([lame],[auto],
 242   [lame-3.100],
 243   [ libmp3lame/.libs/libmp3lame.a \
 244     mpglib/.libs/libmpgdecoder.a ],
 245   [ include ])
 246
 247 PKG_3RD([libavc1394],[auto],
 248   [libavc1394-0.5.4],
 249   [ libavc1394/.libs/libavc1394.a \
 250     librom1394/.libs/librom1394.a \
 251     common/.libs/libraw1394util.a ],
 252   [ . ])
 253
 254 PKG_3RD([libraw1394],[auto],
 255   [libraw1394-2.1.2],
 256   [ src/.libs/libraw1394.a ],
 257   [ . ])
 258
 259 PKG_3RD([libiec61883],[auto],
 260   [libiec61883-1.2.0],
 261   [ src/.libs/libiec61883.a ],
 262   [ src ])
 263
 264 PKG_3RD([libdv],[auto],
 265   [libdv-1.0.0],
 266   [ libdv/.libs/libdv.a ],
 267   [ . ])
 268
 269 PKG_3RD([libjpeg],[auto],
 270   [libjpeg-turbo-1.5.1],
 271   [ .libs/libjpeg.a \
 272     .libs/libturbojpeg.a \
 273     simd/.libs/libsimd.a ],
 274   [ . ])
 275
 276 PKG_3RD([opus],[auto],
 277   [opus-1.2.1],
 278   [ .libs/libopus.a ],
 279   [ include ])
 280
 281 PKG_3RD([openjpeg],[auto],
 282   [openjpeg-2.3.0],
 283   [ bin/libopenjp2.a ],
 284   [ src/lib/openjp2 ])
 285
 286 PKG_3RD([libogg],[auto],
 287   [libogg-1.3.2],
 288   [ src/.libs/libogg.a ],
 289   [ include ])
 290
 291 PKG_3RD([libsndfile],[auto],
 292   [libsndfile-1.0.28],
 293   [ src/.libs/libsndfile.a \
 294     src/.libs/libcommon.a \
 295     src/G72x/.libs/libg72x.a \
 296     src/GSM610/.libs/libgsm.a ],
 297   [ . ])
 298
 299 PKG_3RD([libtheora],[auto],
 300   [libtheora-1.1.1],
 301   [ lib/.libs/libtheora.a \
 302     lib/.libs/libtheoradec.a \
 303     lib/.libs/libtheoraenc.a ],
 304   [ . ])
 305
 306 PKG_3RD([libuuid],[yes],
 307   [libuuid-1.0.3],
 308   [ .libs/libuuid.a ],
 309   [ . ])
 310
 311 PKG_3RD([libvorbis],[auto],
 312   [libvorbis-1.3.5],
 313   [ lib/.libs/libvorbis.a \
 314     lib/.libs/libvorbisenc.a \
 315     lib/.libs/libvorbisfile.a ],
 316   [ include . ])
 317
 318 PKG_3RD([mjpegtools],[yes],
 319   [mjpegtools-2.1.0],
 320   [ utils/mmxsse/.libs/libmmxsse.a \
 321     utils/.libs/libmjpegutils.a \
 322     lavtools/.libs/liblavfile.a \
 323     lavtools/.libs/liblavjpeg.a \
 324     mplex/.libs/libmplex2.a \
 325     yuvfilters/.libs/libyuvfilters.a \
 326     mpeg2enc/.libs/libmpeg2encpp.a ],
 327   [ .  lavtools utils ])
 328
 329 PKG_3RD([openexr],[auto],
 330   [openexr-2.2.1],
 331   [ IlmImf/.libs/libIlmImf.a \
 332     IlmImfUtil/.libs/libIlmImfUtil.a ],
 333   [ IlmImf config ])
 334
 335 #PKG_3RD([festival],[no],
 336 #  [festival],
 337 #  [],
 338 #  [])
 339 #PKG_3RD(speech_tools,[no],
 340 #  [speech_tools],
 341 #  [],
 342 #  [])
 343 #
 344 PKG_3RD([tiff],[auto],
 345   [tiff-4.0.9],
 346   [ libtiff/.libs/libtiff.a \
 347     libtiff/.libs/libtiffxx.a \
 348     port/.libs/libport.a ],[
 349    . ])
 350
 351 PKG_3RD([twolame],[auto],
 352   [twolame-0.3.13],
 353   [ libtwolame/.libs/libtwolame.a ],
 354   [  libtwolame ])
 355
 356 PKG_3RD([x264],[auto],
 357   [x264-snapshot-20180118-2245],
 358   [ libx264.a ],
 359   [ . ])
 360
 361 PKG_3RD([x265],[auto],
 362   [x265_2.8],
 363   [ libx265.a ],
 364   [ . source ])
 365
 366 PKG_3RD([libvpx],[auto],
 367   [libvpx-1.7.0],
 368   [ libvpx.a ],
 369   [ . ])
 370
 371 PKG_3RD([lv2],[auto],
 372   [lv2-1.14.0],
 373   [ ],
 374   [ usr/local/include usr/local/lib64/lv2 usr/local/lib/lv2 ])
 375
 376 PKG_3RD([sratom],[auto],
 377   [sratom-0.6.0],
 378   [ usr/local/lib/libsratom-0.a ],
 379   [ usr/local/include ])
 380
 381 PKG_3RD([serd],[auto],
 382   [serd-0.28.0],
 383   [ usr/local/lib/libserd-0.a ],
 384   [ usr/local/include ])
 385
 386 PKG_3RD([sord],[auto],
 387   [sord-0.16.0],
 388   [ usr/local/lib/libsord-0.a ],
 389   [ usr/local/include ])
 390
 391 PKG_3RD([lilv],[auto],
 392   [lilv-0.24.2],
 393   [ usr/local/lib/liblilv-0.a ],
 394   [ usr/local/include ])
 395
 396 PKG_3RD([suil],[auto],
 397   [suil-0.8.4],
 398   [ usr/local/lib/libsuil-0.a ],
 399   [ usr/local/include ])
 400
 401 AC_SUBST(STATIC_PKGS)
 402
 403 AC_DEFUN([CHECK_ENABLE], [
 404 AC_ARG_ENABLE([$1],
 405   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 406   [WANT_$2=$enableval], [WANT_$2=[$4]])
 407 ])
 408
 409 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 410 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 411 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10bit], [no])
 412
 413 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 414
 415 AC_DEFUN([CHECK_PROG], [
 416  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 417 ])
 418 AC_DEFUN([REQUIRE_PROG], [
 419  CHECK_PROG([$1],[$2])
 420  if test "x$PROG_$1" = "xno"; then
 421    AC_MSG_WARN([$2 is missing and required.])
 422    FATAL_ERROR=1
 423  fi
 424 ])
 425
 426 # Checks for programs.
 427
 428 REQUIRE_PROG(NASM, [nasm])
 429 REQUIRE_PROG(YASM, [yasm])
 430 REQUIRE_PROG(OBJCOPY, [objcopy])
 431 if test "x$FATAL_ERROR" != "x"; then
 432  AC_MSG_ERROR("fatal eror.")
 433 fi
 434 CHECK_PROG(PACTL, [pactl])
 435 WANT_PACTL=$PROG_PACTL
 436
 437 # libx264 nasm fix
 438 AC_MSG_CHECKING([nasm x264 compatible])
 439 echo "vmovdqa32 [[eax]]{k1}{z}, zmm0" > conftest.asm
 440 nasm conftest.asm -o conftest.o > /dev/null 2>&1
 441 if test $? != 0 ; then
 442  AC_MSG_RESULT([no])
 443  AC_MSG_WARN([libx264 built without assembly code])
 444  X264_CFG_PARAMS="$X264_CFG_PARAMS --disable-asm"
 445 else
 446  AC_MSG_RESULT([yes])
 447 fi
 448 rm -f conftest.asm conftest.o
 449
 450 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 451 if test "$no_utf" = "yes"; then
 452   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 453 fi
 454
 455 # Checks for headers/libraries.
 456
 457 AC_DEFUN([CHECK_HEADERS], [
 458 if test "x$HAVE_$1" != "xno"; then
 459  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 460   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 461 ]])])
 462  AC_SUBST([HAVE_$1])
 463  AC_MSG_CHECKING([$2])
 464  AC_MSG_RESULT([$HAVE_$1])
 465  if test "x$HAVE_$1" = "xno"; then
 466   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 467  fi
 468 fi
 469 ])
 470
 471 AC_DEFUN([CHECK_LIB], [
 472 if test "x$HAVE_$1" != "xno"; then
 473  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno"; then
 474   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 475   AC_SUBST([HAVE_$1])
 476   if test "x$HAVE_$1" = "xyes"; then
 477    if test "x$PKG_$1" = "x"; then
 478     SYSTEM_LIBS+=" -l[$2]"
 479     for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 480    else
 481     SHARED_$1+=" -l[$2]"
 482     for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 483    fi
 484   elif test "x$PKG_$1" = "x"; then RESULT=no; fi
 485  fi
 486 fi
 487 ])
 488
 489 CHECK_LIB([X11], [X11], [XOpenDisplay])
 490 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 491 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 492 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 493 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 494 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 495 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 496 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 497 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 498 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 499 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 500 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 501 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 502 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 503 CHECK_LIB([PNG], [png], [png_read_png])
 504 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 505 CHECK_LIB([Z], [z], [gzopen])
 506 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 507 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 508 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 509 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 510 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 511 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 512 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 513 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 514 CHECK_LIB([lame], [mp3lame], [lame_init])
 515 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 516 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 517 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 518 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 519 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 520 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 521 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 522 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 523 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 524 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 525 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 526 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 527 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 528 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 529 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 530 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 531 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 532 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 533 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 534 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 535 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 536 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 537 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 538 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 539 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 540 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 541 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 542 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 543 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 544 CHECK_LIB([a52dec], [a52], [a52_init])
 545 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 546 CHECK_LIB([encore], [encore], [encore])
 547 CHECK_HEADERS([encore], [encore headers], [encore.h])
 548 CHECK_LIB([giflib], [gif], [DGifOpen])
 549 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 550 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 551 CHECK_LIB([vdpau], [vdpau], [vdp_device_create_x11])
 552
 553 #if test "x$HAVE_mjpegtools" = "xyes"; then
 554 #CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
 555 #fi
 556
 557 AC_DEFUN([CHECK_WANT], [
 558 RESULT=yes
 559 # WANT_$1
 560 if test "x$WANT_$1" != "xyes" -a "x$WANT_$1" != "xno" ; then
 561 AC_ARG_WITH(m4_tolower([$1]),
 562  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 563   [WANT_$1=$withval],[WANT_$1=$2])
 564  m4_quote($4)
 565  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 566   echo "=== want $1 Failed."
 567   WANT_$1=no
 568  elif test "x$WANT_$1" = "xauto" ; then
 569   WANT_$1=yes
 570  fi
 571 fi
 572 CFG_WANTS+=" $1"
 573 AC_SUBST([WANT_$1])
 574 ])
 575
 576 CHECK_WANT([GL], [auto], [use opengl], [
 577  CHECK_LIB([GL], [GL], [glUseProgram])
 578  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 579  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 580
 581 CHECK_WANT([OSS], [auto], [use OSS audio], [
 582  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 583
 584 CHECK_WANT([XFT], [auto], [use libXft], [
 585  CHECK_LIB([XFT], [Xft], [XftInit])
 586  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 587
 588 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 589  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 590  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 591
 592 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 593  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 594  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 595  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 596  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 597  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 598  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 599  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 600  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 601
 602 CHECK_WANT([DV], [auto], [use dv], [
 603  CHECK_LIB([libdv], [dv], [dv_init])
 604  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 605
 606 CHECK_WANT([DVB], [auto], [use dvb], [
 607  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 608
 609 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 610  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 611
 612 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 613  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 614
 615 CHECK_WANT([ESOUND], [no], [use esd], [
 616  CHECK_LIB([esound], [esd], [esd_open_sound])
 617  CHECK_HEADERS([esound], [esound headers], [esd.h])
 618  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 619  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 620
 621 CHECK_WANT([OPUS], [auto], [use libopus], [
 622  CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 623  CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])])
 624
 625 CHECK_WANT([LV2], [auto], [use lv2], [
 626  saved_CFLAGS="$CFLAGS"
 627  CHECK_LIB([lilv], [lilv-0], [lilv_world_new])
 628  CHECK_LIB([sord], [sord-0], [sord_world_new])
 629  CHECK_LIB([serd], [serd-0], [serd_reader_new])
 630  CHECK_LIB([sratom], [sratom-0], [sratom_new])
 631  CFLAGS="-I/usr/include/lilv-0 -I/usr/local/include/lilv-0"
 632  CHECK_HEADERS([lv2], [lilv headers], [lilv/lilv.h])
 633  CHECK_LIB([suil], [suil-0], [suil_instance_new])
 634  CFLAGS="-I/usr/include/suil-0 -I/usr/local/include/suil-0"
 635  CHECK_HEADERS([lv2], [suil headers], [suil/suil.h])
 636  CFLAGS="$saved_CFLAGS"])
 637
 638 CHECK_WANT([DL], [auto], [system has libdl], [
 639  CHECK_LIB([DL], [dl], [dlopen])])
 640
 641 CHECK_WANT([EXR], [auto], [use exr], [])
 642
 643 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 644 ])
 645
 646 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 647  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 648
 649 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 650  AC_MSG_CHECKING([for openexr available])
 651  saved_LIBS="$LIBS"
 652  saved_CXXFLAGS="$CXXFLAGS"
 653  # ilmbase libs
 654  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 655  CXXFLAGS="-I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 656  AC_LANG_PUSH(C++)
 657  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 658 #include "ImfChannelList.h"
 659 #include "ImfChromaticities.h"
 660 #include "ImfCompression.h"
 661 #include "ImfIO.h"
 662 #include "ImfInputFile.h"
 663 #include "ImfOutputFile.h"
 664 #include "ImfPixelType.h"
 665 #include "ImfRgbaFile.h"
 666 #include "ImfRgbaYca.h"
 667 #include "ImfVersion.h"
 668 class EXRIStream : public Imf::IStream { public:
 669 EXRIStream() : Imf::IStream("mypath") {} };
 670 class EXROStream : public Imf::OStream { public:
 671 EXROStream() : Imf::OStream("mypath") {} };
 672 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 673  RESULT="$HAVE_OPENEXR"
 674  if test "x$RESULT" = "xyes"; then
 675    SHARED_openexr="$LIBS"
 676    CFG_CFLAGS+=" -I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 677  fi
 678  LIBS="$saved_LIBS"
 679  CXXFLAGS="$saved_CXXFLAGS"
 680  AC_LANG_POP(C++)
 681  AC_MSG_RESULT([$HAVE_OPENEXR])
 682 ])
 683 AC_SUBST([HAVE_OPENEXR])
 684
 685 # build global_config
 686 OBJDIR=`uname -m`
 687 AC_SUBST(OBJDIR)
 688
 689 echo "AC_HELP_STRING([Reason],[Package])"
 690 echo "AC_HELP_STRING([------],[-------])"
 691
 692 AC_DEFUN([PKG_DISABLED],[
 693  PKG_$1="no"
 694  BUILD_$1=0
 695  AC_SUBST(BUILD_$1)
 696  echo "AC_HELP_STRING([disabled],[$1])"
 697 ])
 698 AC_DEFUN([PKG_SHARED],[
 699  BUILD_$1=0
 700  AC_SUBST(BUILD_$1)
 701  SHARED_LIBS+="$SHARED_$1"
 702  echo "AC_HELP_STRING([shared],[$1])"
 703 ])
 704
 705 AC_DEFUN([PKG_STATIC],[
 706  if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 707   PKG_$1="yes"
 708   BUILD_$1=1
 709   AC_SUBST(BUILD_$1)
 710   STATIC_BLDS+=" [$1]"
 711   echo "AC_HELP_STRING([$2],[$1])"
 712  fi
 713 ])
 714
 715 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 716
 717 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 718 # order matters
 719 for dep in \
 720         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 721         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 \
 722         libiec61883/libraw1394 libavc1394/librom1394 \
 723         openexr/ilmbase ilmbase/libogg \
 724         libtheora/libogg libtheora/libvorbis ; do
 725   lib=`dirname $dep`;  needs=`basename $dep`
 726   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 727   if test "x$pkg_lib" != "xno"; then
 728     eval "PKG_$needs=yes"
 729   fi
 730 done
 731 fi
 732
 733 AC_DEFUN([PKG_PROVIDE],[
 734 if test "x$BUILD_$1" = "x" ; then
 735  if test "x$PKG_$1" = "xyes"; then
 736   PKG_FORCED([$1])
 737  elif test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 738   PKG_DISABLED([$1])
 739  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 740   PKG_STATIC([$1],[static])
 741  elif test "x$HAVE_$1" = "xyes"; then
 742   PKG_SHARED([$1])
 743  else
 744   PKG_STATIC([$1],[needed])
 745  fi
 746 fi
 747 ])
 748
 749 PKG_PROVIDE([a52dec])
 750 PKG_PROVIDE([djbfft])
 751 PKG_PROVIDE([encore])
 752 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 753 PKG_PROVIDE([esound],[$WANT_ESOUND])
 754 PKG_PROVIDE([ffmpeg])
 755 PKG_PROVIDE([fftw])
 756 PKG_PROVIDE([flac])
 757 PKG_PROVIDE([giflib])
 758 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 759 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 760 PKG_PROVIDE([lame])
 761 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 762 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 763 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 764 PKG_PROVIDE([libdv],[$WANT_DV])
 765 PKG_PROVIDE([libjpeg])
 766 PKG_PROVIDE([libogg])
 767 PKG_PROVIDE([libsndfile])
 768 PKG_PROVIDE([libtheora])
 769 PKG_PROVIDE([libuuid])
 770 PKG_PROVIDE([libvorbis])
 771 PKG_PROVIDE([mjpegtools])
 772 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 773 PKG_PROVIDE([openjpeg])
 774 PKG_PROVIDE([tiff])
 775 PKG_PROVIDE([twolame])
 776 PKG_PROVIDE([x264])
 777 PKG_PROVIDE([x265])
 778 PKG_PROVIDE([libvpx])
 779 PKG_PROVIDE([opus], [$WANT_OPUS])
 780 PKG_PROVIDE([lv2], [$WANT_LV2])
 781 PKG_PROVIDE([lilv], [$WANT_LV2])
 782 PKG_PROVIDE([sratom], [$WANT_LV2])
 783 PKG_PROVIDE([serd], [$WANT_LV2])
 784 PKG_PROVIDE([sord], [$WANT_LV2])
 785 PKG_PROVIDE([suil], [$WANT_LV2])
 786
 787 if test "x$WANT_LV2" = "xyes"; then
 788   if test "x$HAVE_lv2" = "xyes" -a "x$BUILD_lilv" = "x0"; then
 789     CFG_CFLAGS+=' -I/usr/include/lilv-0 -I/usr/local/include/lilv-0'
 790     CFG_CFLAGS+=' -I/usr/include/suil-0 -I/usr/local/include/suil-0'
 791   fi
 792 fi
 793
 794 AC_SUBST(STATIC_BLDS)
 795 AC_SUBST(SHARED_LIBS)
 796
 797 for f in $SYSTEM_LIBS; do
 798   echo "AC_HELP_STRING([system],[$f])"
 799 done
 800 AC_SUBST(SYSTEM_LIBS)
 801
 802 echo ""
 803 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 804   CFG_CFLAGS+=" -DHAVE_CIN_3RDPARTY"
 805 fi
 806 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 807          VIDEO4LINUX2 ESOUND PACTL OPENEXR LV2 \
 808          COMMERCIAL LIBZMPEG; do
 809   eval vv="\$WANT_$v"
 810   if test "x$vv" != "xno"; then
 811     CFG_CFLAGS+=" -DHAVE_$v"
 812     vv=with
 813   else
 814     vv=without
 815   fi
 816   v=`echo "$v" | tr "A-Z" "a-z"`
 817   echo "  using: $vv-$v"
 818 done
 819
 820 echo "  using: with-jobs = $WANT_JOBS"
 821 echo "  using: exec-name = $WANT_CIN"
 822 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 823 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 824 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 825 echo "  using: with-browser = $WANT_CIN_BROWSER"
 826 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 827 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 828 echo "  using: with-opencv = $WANT_OPENCV"
 829 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 830 echo "  using: with-noelision = $WANT_NOELISION"
 831 echo "  using: with-booby = $WANT_BOOBY"
 832 echo "  using: with-libzmpeg = $WANT_LIBZMPEG"
 833 echo "  using: with-commerical = $WANT_COMMERCIAL"
 834 echo ""
 835 echo "  using: thirdparty build = $WANT_CIN_3RDPARTY"
 836 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 837 echo "  using: static-build = $WANT_STATIC_BUILD"
 838 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 839 echo ""
 840
 841 # build extras
 842 if test "x$HAVE_tiff" = "xyes"; then
 843   if test "x$HAVE_jbig" = "xyes"; then
 844     EXTRA_LIBS+=' -ljbig'
 845   fi
 846 fi
 847 if test "x$HAVE_NUMA" = "xyes"; then
 848   EXTRA_LIBS+=' -lnuma'
 849 fi
 850 if test "x$HAVE_DL" = "xyes"; then
 851   EXTRA_LIBS+=' -ldl'
 852   FFMPEG_EXTRA_CFG+=' --extra-ldflags="-ldl"'
 853 fi
 854 if test "x$WANT_OPUS" = "xyes"; then
 855   FFMPEG_EXTRA_CFG+=' --enable-libopus'
 856   if test "x$HAVE_opus" = "xyes" -a "x$BUILD_opus" = "x0"; then
 857     EXTRA_LIBS+=' -lopus'
 858     CFG_CFLAGS+=' -I/usr/include/opus -I/usr/local/include/opus'
 859   fi
 860 fi
 861 if test "x$WANT_BOOBY" != "xno"; then
 862   CFG_CFLAGS+=" -DBOOBY"
 863 fi
 864
 865 # intel lock elision bugs
 866 if test "x$WANT_NOELISION" != "xno"; then
 867   CFG_RPATH=`ls -1fd 2> /dev/null \
 868  /usr/lib/noelision \
 869  /lib/noelision \
 870  /usr/lib64/noelision \
 871  /lib64/noelision \
 872   | tail -1`
 873 fi
 874
 875 AC_SUBST(WANT_CIN_3RDPARTY)
 876 AC_SUBST(EXTRA_LIBS)
 877 AC_SUBST(FFMPEG_EXTRA_CFG)
 878 AC_SUBST(WANT_X264_HIDEPTH)
 879 AC_SUBST(WANT_X265_HIDEPTH)
 880
 881 AC_SUBST(CFG_CFLAGS)
 882 AC_SUBST(CFG_CXXFLAGS)
 883
 884 AC_CONFIG_FILES([Makefile])
 885 AC_OUTPUT
 886
 887 exec > global_config
 888
 889 echo "SHELL := /bin/bash"
 890 echo "export SHELL"
 891 echo "WANT_JOBS := $WANT_JOBS"
 892 echo ""
 893 echo "OBJDIR := $OBJDIR"
 894 echo "BINDIR := \$(TOPDIR)/bin"
 895 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 896 echo "GUICAST := \$(TOPDIR)/guicast"
 897 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 898 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 899 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 900 echo "PLUGINS := \$(TOPDIR)/plugins"
 901 echo "TDB := \$(TOPDIR)/db"
 902 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
 903 echo "EXTRA_LIBS := $EXTRA_LIBS"
 904 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
 905 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
 906 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
 907 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
 908 echo ""
 909
 910 echo "WANT_CIN := $WANT_CIN"
 911 CFG_WANTS+=" CIN_3RDPARTY LIBZMPEG COMMERCIAL"
 912 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
 913 echo ""
 914
 915 echo "ifndef CFLAGS_"
 916 echo "ifdef CFLAGS"
 917 echo "CFLAGS_ := \$(CFLAGS)"
 918 echo "else"
 919 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
 920 echo "endif"
 921 echo "endif"
 922
 923 echo "CFLAGS := \$(CFLAGS_)"
 924 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
 925 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
 926 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
 927 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
 928 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
 929 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
 930 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
 931 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
 932 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
 933 echo ""
 934 for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
 935 echo ""
 936
 937 if test "x$WANT_X264_HIDEPTH" = "xyes" ; then
 938   X264_CFG_PARAMS="$X264_CFG_PARAMS --bit-depth=10"
 939 fi
 940 if test "x$WANT_X265_HIDEPTH" = "xyes" ; then
 941   X265_CFG_PARAMS="$X265_CFG_PARAMS -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
 942 fi
 943
 944 for pkg in $STATIC_PKGS; do
 945   eval pkg_lib="\$PKG_$pkg"
 946   if test "x$pkg_lib" = "xno"; then continue; fi;
 947   echo "static_pkgs += $pkg"
 948 done
 949 echo ""
 950
 951 for pkg in $STATIC_BLDS; do
 952   echo "static_blds += $pkg"
 953   ver_pkg=ver_$pkg
 954   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
 955   inc_pkg=inc_$pkg
 956   echo "$inc_pkg := \\"
 957   for inc in ${!inc_pkg}; do
 958     echo "  -I\$($ver_pkg)/$inc \\"
 959   done
 960   echo ""
 961   echo "static_incs += \$(inc_$pkg)"
 962   lib_pkg=lib_$pkg
 963   echo "$lib_pkg := \\"
 964   for lib in ${!lib_pkg}; do
 965     echo "  \$($ver_pkg)/$lib \\"
 966   done
 967   echo ""
 968   echo "static_libs += \$($lib_pkg)"
 969   echo ""
 970 done
 971 echo ""
 972
 973 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
 974 echo ""
 975 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
 976 echo "export static_pkgs static_blds shared_libs system_libs"
 977 echo ""
 978
 979 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
 980
 981 if test "x$CFG_RPATH" != "x"; then
 982   echo "libraries+= -Wl,-rpath=$CFG_RPATH"
 983 fi
 984
 985 echo "libraries += -Wl,--start-group"
 986 echo "libraries += \$(thirdparty_libraries)"
 987 echo "libraries += \$(system_libs)"
 988 echo "libraries += \$(EXTRA_LIBS)"
 989 echo "libraries += -Wl,--end-group"
 990 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
 991 echo "libraries += \$(thirdparty_libraries)"
 992 echo "libraries += \$(system_libs)"
 993 echo "libraries += \$(EXTRA_LIBS)"
 994 echo ""
 995 echo "export thirdparty_libraries libraries"
 996 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
 997 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
 998
 999 if test "x$HAVE_tiff" = "xyes"; then
1000   if test "x$HAVE_jbig" != "xyes"; then
1001     echo "tiff.cfg_params+= --disable-jbig"
1002   fi
1003 fi
1004
1005 if test "x$WANT_GIT_FFMPEG" != "xno"; then
1006   echo "ffmpeg.git := $WANT_GIT_FFMPEG"
1007 fi
1008 if test "x$WANT_OPUS" = "xyes" -a "x$BUILD_opus" = "x0"; then
1009   echo 'ffmpeg.cflags+=" -I/usr/include/opus -I/usr/local/include/opus"'
1010 fi
1011 if test "x$X264_CFG_PARAMS" != "x" ; then
1012   echo "x264.cfg_params :=$X264_CFG_PARAMS --enable-static --enable-pic"
1013 fi
1014 if test "x$X265_CFG_PARAMS" != "x" ; then
1015   echo "x265.cfg_params :=$X265_CFG_PARAMS -DENABLE_SHARED=no"
1016 fi