cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-gg.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 #  this is extra work, not a gain...
  15 CFG_CFLAGS+=" -Wno-unknown-warning"
  16 CFG_CFLAGS+=" -Wno-attributes"
  17 CFG_CFLAGS+=" -Wno-unused-result"
  18 CFG_CFLAGS+=" -Wno-stringop-overflow"
  19 CFG_CFLAGS+=" -Wno-format-truncation"
  20 CFG_CFLAGS+=" -Wno-format-overflow"
  21 CFG_CFLAGS+=" -Wno-parentheses"
  22 CFG_CFLAGS+=" -Wno-stringop-truncation"
  23 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  24 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  25 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  26 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  27 CFG_CFLAGS+=" -I/usr/include -I/usr/local/include"
  28 CFG_CFLAGS+=" -I/usr/include/freetype2 -I/usr/local/include/freetype2"
  29 CFG_CFLAGS+=" -I/usr/include/uuid -I/usr/local/include/uuid"
  30 CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
  31
  32 CFG_LDFLAGS+=" -z noexecstack"
  33
  34 AC_DEFUN([CHECK_WITH], [
  35 AC_ARG_WITH([$1],
  36   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  37   [WANT_$3=$withval], [WANT_$3='$4'])
  38 AC_SUBST([WANT_$3])
  39 ])
  40
  41 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  42 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  43 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  44 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  45 CHECK_WITH([lv2],[lv2 library support],[LV2],[yes])
  46 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  47 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  48 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  49 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  50 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  51 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  52 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  53 CHECK_WITH([noelision],[use noelision/libpthread],[NOELISION],[auto])
  54 CHECK_WITH([booby],[window lock trace booby trap],[BOOBY],[no])
  55 CHECK_WITH([libzmpeg],[build libzmpeg],[LIBZMPEG],[yes])
  56 CHECK_WITH([commercial],[enable commercial capture],[COMMERCIAL],[yes])
  57 CHECK_WITH([thirdparty],[use thirdparty build],[CIN_3RDPARTY],[yes])
  58 CHECK_WITH([shuttle],[shuttle device],[SHUTTLE],[yes])
  59 CHECK_WITH([vaapi],[video acceleration api],[VAAPI],[yes])
  60 CHECK_WITH([vdpau],[video decode+presentation api for unix],[VDPAU],[yes])
  61 CHECK_WITH([nv],[nvenc/nvdec ffnvcodec api],[NV],[yes])
  62 CHECK_WITH([cuda],[nv cuda plugins],[CUDA],[auto])
  63
  64 if test "x$WANT_LV2" != "xno"; then
  65   GTK2_LIBS=`pkg-config --libs gtk+-2.0`
  66   AC_CHECK_LIB([m], [gtk_init], [HAVE_gtk=yes], [HAVE_gtk=no], [$GTK2_LIBS])
  67   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --cflags gtk+-2.0`" && HAVE_gtk=no
  68   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --libs gtk+-2.0`" && HAVE_gtk=no
  69   if test "x$HAVE_gtk" = "xno"; then
  70     AC_MSG_ERROR([LV2 requires gtk+-2.0 support.])
  71   fi
  72 fi
  73
  74 if test "x$WANT_COMMERCIAL" = "xyes" -a "x$WANT_LIBZMPEG" != "xyes" ; then
  75   AC_MSG_ERROR([commercial requires libzmpeg support.])
  76 fi
  77
  78 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  79   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  80   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  81   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  82   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  83   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  84 else
  85   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  86     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  87     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  88     echo "$dir"`
  89   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  90     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  91     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  92     echo "$dir"`
  93   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  94     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  95     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  96     echo "$dir"`
  97   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  98        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
  99   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
 100     usrlib+="64"
 101   WANT_LOCALE_DIR="$lcldir"
 102   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
 103   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
 104   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
 105   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
 106 fi
 107
 108 CIN_INSTALLS=""
 109 CIN_UNINSTALLS=""
 110 if test "x$WANT_LIBZMPEG" = "xyes"; then
 111   CIN_INSTALLS+=" zmp_install"
 112   CIN_UNINSTALLS+=" zmp_uninstall"
 113 fi
 114 if test "x$WANT_COMMERCIAL" = "xyes"; then
 115   CIN_INSTALLS+=" com_install"
 116   CIN_UNINSTALLS+=" com_uninstall"
 117 fi
 118 if test "x$WANT_LADSPA_BUILD" = "xyes"; then
 119   CIN_INSTALLS+=" lad_install "
 120   CIN_UNINSTALLS+=" lad_uninstall "
 121 fi
 122 if test "x$WANT_LV2" = "xyes"; then
 123   CIN_INSTALLS+=" lv2_install "
 124   CIN_UNINSTALLS+=" lv2_uninstall "
 125 fi
 126 AC_SUBST(CIN_INSTALLS)
 127 AC_SUBST(CIN_UNINSTALLS)
 128
 129 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
 130   MAK_INSTALLS="dvl_install"
 131   MAK_UNINSTALLS="dvl_uninstall"
 132 else
 133   MAK_INSTALLS=" sys_install"
 134   MAK_UNINSTALLS="sys_uninstall"
 135 fi
 136 AC_SUBST(MAK_INSTALLS)
 137 AC_SUBST(MAK_UNINSTALLS)
 138
 139 if test "x$WANT_JOBS" = "xauto"; then
 140   CPUS=`grep -c "^proc" /proc/cpuinfo`
 141   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
 142 fi
 143
 144 AC_DEFUN([PKG_DEF],[
 145 STATIC_PKGS+=" [$1]"
 146 ver_$1="$2"
 147 lib_$1="$3"
 148 inc_$1="$4"
 149 ])
 150
 151 AC_DEFUN([PKG_3RD],[
 152 AC_ARG_ENABLE([$1],
 153   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
 154   [PKG_$1=$enableval], [PKG_$1=$2])
 155 PKG_DEF([$1],[$3],[$4],[$5])
 156 ])
 157
 158 # thirdparty builds
 159
 160 PKG_3RD([a52dec],[yes],
 161   [a52dec-0.7.4],
 162   [ liba52/.libs/liba52.a ],
 163   [ include ])
 164
 165 PKG_3RD([djbfft],[yes],
 166   [djbfft-0.76],
 167   [ libdjbfft.a ],
 168   [ . ])
 169
 170 PKG_3RD([audiofile],[no],
 171   [audiofile-0.3.6],
 172   [ libaudiofile/.libs/libaudiofile.a \
 173     libaudiofile/modules/.libs/libmodules.a \
 174     libaudiofile/alac/.libs/libalac.a ],
 175   [ libaudiofile ])
 176
 177 PKG_3RD([encore],[no],
 178   [encore-5.0],
 179   [ \$(OBJDIR)/libencore.a ],
 180   [ . ])
 181
 182 PKG_3RD([esound],[no],
 183   [esound-0.2.41],
 184   [ .libs/libesd.a \
 185     .libs/libesddsp.a ],
 186   [ . ])
 187
 188 PKG_3RD([ffmpeg],[yes],
 189   [ffmpeg-4.2],
 190   [ libavutil/libavutil.a \
 191     libavcodec/libavcodec.a \
 192     libpostproc/libpostproc.a \
 193     libavdevice/libavdevice.a \
 194     libavformat/libavformat.a \
 195     libswscale/libswscale.a \
 196     libavfilter/libavfilter.a \
 197     libswresample/libswresample.a ],
 198   [ . ])
 199
 200 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 201   ver_ffmpeg="ffmpeg.git"
 202 fi
 203
 204 PKG_3RD([fftw],[auto],
 205   [fftw-3.3.8],
 206   [ .libs/libfftw3.a \
 207     libbench2/libbench2.a \
 208     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 209     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 210     rdft/scalar/.libs/librdft_scalar.a \
 211     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 212     rdft/.libs/librdft.a \
 213     api/.libs/libapi.a \
 214     reodft/.libs/libreodft.a \
 215     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 216     dft/scalar/.libs/libdft_scalar.a \
 217     dft/.libs/libdft.a \
 218     kernel/.libs/libkernel.a \
 219     simd-support/.libs/libsimd_support.a ],
 220   [ api ])
 221
 222 PKG_3RD([flac],[auto],
 223   [flac-1.3.2],
 224   [ src/libFLAC/.libs/libFLAC.a \
 225     src/libFLAC++/.libs/libFLAC++.a \
 226     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 227     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 228     src/share/grabbag/.libs/libgrabbag.a \
 229     src/share/utf8/.libs/libutf8.a \
 230     src/test_libs_common/.libs/libtest_libs_common.a ],
 231   [ include ])
 232
 233 PKG_3RD([giflib],[yes],
 234   [giflib-5.1.6],
 235   [ libgif.a ],
 236   [ . ])
 237
 238 PKG_3RD([ilmbase],[auto],
 239   [ilmbase-2.2.1],
 240   [ Iex/.libs/libIex.a \
 241     IexMath/.libs/libIexMath.a \
 242     Half/.libs/libHalf.a \
 243     Imath/.libs/libImath.a \
 244     IlmThread/.libs/libIlmThread.a ],
 245   [ Iex Half Imath config IlmThread ])
 246
 247 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 248
 249 PKG_3RD([lame],[auto],
 250   [lame-3.100],
 251   [ libmp3lame/.libs/libmp3lame.a \
 252     mpglib/.libs/libmpgdecoder.a ],
 253   [ include ])
 254
 255 PKG_3RD([libavc1394],[auto],
 256   [libavc1394-0.5.4],
 257   [ libavc1394/.libs/libavc1394.a \
 258     librom1394/.libs/librom1394.a \
 259     common/.libs/libraw1394util.a ],
 260   [ . ])
 261
 262 PKG_3RD([libraw1394],[auto],
 263   [libraw1394-2.1.2],
 264   [ src/.libs/libraw1394.a ],
 265   [ . ])
 266
 267 PKG_3RD([libiec61883],[auto],
 268   [libiec61883-1.2.0],
 269   [ src/.libs/libiec61883.a ],
 270   [ src ])
 271
 272 PKG_3RD([libdv],[auto],
 273   [libdv-1.0.0],
 274   [ libdv/.libs/libdv.a ],
 275   [ . ])
 276
 277 PKG_3RD([libjpeg],[auto],
 278   [libjpeg-turbo-1.5.1],
 279   [ .libs/libjpeg.a \
 280     .libs/libturbojpeg.a \
 281     simd/.libs/libsimd.a ],
 282   [ . ])
 283
 284 PKG_3RD([opus],[auto],
 285   [opus-1.3],
 286   [ .libs/libopus.a ],
 287   [ include ])
 288
 289 PKG_3RD([openjpeg],[auto],
 290   [openjpeg-2.3.0],
 291   [ bin/libopenjp2.a ],
 292   [ src/lib/openjp2 ])
 293
 294 PKG_3RD([libogg],[auto],
 295   [libogg-1.3.3],
 296   [ src/.libs/libogg.a ],
 297   [ include ])
 298
 299 PKG_3RD([libsndfile],[auto],
 300   [libsndfile-1.0.28],
 301   [ src/.libs/libsndfile.a \
 302     src/.libs/libcommon.a \
 303     src/G72x/.libs/libg72x.a \
 304     src/GSM610/.libs/libgsm.a ],
 305   [ . ])
 306
 307 PKG_3RD([libtheora],[auto],
 308   [libtheora-1.1.1],
 309   [ lib/.libs/libtheora.a \
 310     lib/.libs/libtheoradec.a \
 311     lib/.libs/libtheoraenc.a ],
 312   [ . ])
 313
 314 PKG_3RD([libuuid],[yes],
 315   [libuuid-1.0.3],
 316   [ .libs/libuuid.a ],
 317   [ . ])
 318
 319 PKG_3RD([libvorbis],[auto],
 320   [libvorbis-1.3.6],
 321   [ lib/.libs/libvorbis.a \
 322     lib/.libs/libvorbisenc.a \
 323     lib/.libs/libvorbisfile.a ],
 324   [ include . ])
 325
 326 PKG_3RD([mjpegtools],[yes],
 327   [mjpegtools-2.1.0],
 328   [ utils/mmxsse/.libs/libmmxsse.a \
 329     utils/.libs/libmjpegutils.a \
 330     lavtools/.libs/liblavfile.a \
 331     lavtools/.libs/liblavjpeg.a \
 332     mplex/.libs/libmplex2.a \
 333     yuvfilters/.libs/libyuvfilters.a \
 334     mpeg2enc/.libs/libmpeg2encpp.a ],
 335   [ .  lavtools utils ])
 336
 337 PKG_3RD([openexr],[auto],
 338   [openexr-2.2.1],
 339   [ IlmImf/.libs/libIlmImf.a \
 340     IlmImfUtil/.libs/libIlmImfUtil.a ],
 341   [ IlmImf config ])
 342
 343 #PKG_3RD([festival],[no],
 344 #  [festival],
 345 #  [],
 346 #  [])
 347 #PKG_3RD(speech_tools,[no],
 348 #  [speech_tools],
 349 #  [],
 350 #  [])
 351 #
 352 PKG_3RD([tiff],[auto],
 353   [tiff-4.0.10],
 354   [ libtiff/.libs/libtiff.a \
 355     libtiff/.libs/libtiffxx.a \
 356     port/.libs/libport.a ],[
 357    . ])
 358
 359 PKG_3RD([twolame],[auto],
 360   [twolame-0.3.13],
 361   [ libtwolame/.libs/libtwolame.a ],
 362   [  libtwolame ])
 363
 364 PKG_3RD([x264],[auto],
 365   [x264-snapshot-20190117-2245-stable],
 366   [ libx264.a ],
 367   [ . ])
 368
 369 PKG_3RD([x265],[auto],
 370   [x265_3.0],
 371   [ libx265.a ],
 372   [ . source ])
 373
 374 PKG_3RD([libvpx],[auto],
 375   [libvpx-1.8.0],
 376   [ libvpx.a ],
 377   [ . ])
 378
 379 PKG_3RD([lv2],[auto],
 380   [lv2-1.16.0],
 381   [ ],
 382   [ usr/local/include usr/local/lib64/lv2 usr/local/lib/lv2 ])
 383
 384 PKG_3RD([sratom],[auto],
 385   [sratom-0.6.2],
 386   [ usr/local/lib/libsratom-0.a ],
 387   [ usr/local/include ])
 388
 389 PKG_3RD([serd],[auto],
 390   [serd-0.30.0],
 391   [ usr/local/lib/libserd-0.a ],
 392   [ usr/local/include ])
 393
 394 PKG_3RD([sord],[auto],
 395   [sord-0.16.2],
 396   [ usr/local/lib/libsord-0.a ],
 397   [ usr/local/include ])
 398
 399 PKG_3RD([lilv],[auto],
 400   [lilv-0.24.4],
 401   [ usr/local/lib/liblilv-0.a ],
 402   [ usr/local/include ])
 403
 404 PKG_3RD([suil],[auto],
 405   [suil-0.10.2],
 406   [ usr/local/lib/libsuil-0.a ],
 407   [ usr/local/include ])
 408
 409 PKG_3RD([libaom],[auto],
 410   [libaom-v1.0.0],
 411   [ usr/local/lib*/libaom*.a ],
 412   [ usr/local/include ])
 413
 414 PKG_3RD([dav1d],[auto],
 415   [dav1d-0.4.0],
 416   [ usr/local/lib*/libdav1d*.a ],
 417   [ usr/local/include ])
 418
 419 PKG_3RD([libwebp],[auto],
 420   [libwebp-1.0.2],
 421   [ usr/local/lib*/libwebp*.a ],
 422   [ usr/local/include ])
 423
 424 PKG_3RD([ffnvcodec],[auto],
 425   [ffnvcodec],
 426   [ ],
 427   [ . ])
 428
 429 AC_SUBST(STATIC_PKGS)
 430
 431 AC_DEFUN([CHECK_ENABLE], [
 432 AC_ARG_ENABLE([$1],
 433   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 434   [WANT_$2=$enableval], [WANT_$2=[$4]])
 435 ])
 436
 437 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 438 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 439 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10bit], [no])
 440
 441 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 442
 443 AC_DEFUN([CHECK_PROG], [
 444  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 445 ])
 446 AC_DEFUN([REQUIRE_PROG], [
 447  CHECK_PROG([$1],[$2])
 448  if test "x$PROG_$1" = "xno"; then
 449    AC_MSG_WARN([$2 is missing and required.])
 450    FATAL_ERROR=1
 451  fi
 452 ])
 453
 454 ## arch dep tests
 455 ARCH=[`uname -m`]
 456 I86=[`expr "x$ARCH" : 'xi[346]86.*'`]
 457 X86=[`expr "x$ARCH" : 'x..._64*'`]
 458
 459 if test "x$I86$X86" != "x00" ; then
 460   # Checks for ix86 programs.
 461   REQUIRE_PROG(NASM, [nasm])
 462   # libx264 nasm fix
 463   AC_MSG_CHECKING([nasm x264 compatible])
 464   echo "vmovdqa32 [[eax]]{k1}{z}, zmm0" > conftest.asm
 465   nasm conftest.asm -o conftest.o > /dev/null 2>&1
 466   if test $? != 0 ; then
 467    AC_MSG_RESULT([no])
 468    AC_MSG_WARN([libx264 built without assembly code])
 469    X264_CFG_PARAMS="$X264_CFG_PARAMS --disable-asm"
 470   else
 471    AC_MSG_RESULT([yes])
 472   fi
 473   rm -f conftest.asm conftest.o
 474   REQUIRE_PROG(YASM, [yasm])
 475 fi
 476 ## end arch dep tests
 477
 478 REQUIRE_PROG(OBJCOPY, [objcopy])
 479 if test "x$FATAL_ERROR" != "x"; then
 480  AC_MSG_ERROR("fatal eror.")
 481 fi
 482 CHECK_PROG(PACTL, [pactl])
 483 WANT_PACTL=$PROG_PACTL
 484
 485 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 486 if test "$no_utf" = "yes"; then
 487   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 488 fi
 489
 490 # Checks for headers/libraries.
 491
 492 AC_DEFUN([CHECK_HEADERS], [
 493 if test "x$HAVE_$1" != "xno"; then
 494  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 495   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 496 ]])])
 497  AC_SUBST([HAVE_$1])
 498  AC_MSG_CHECKING([$2])
 499  AC_MSG_RESULT([$HAVE_$1])
 500  if test "x$HAVE_$1" = "xno"; then
 501   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 502  fi
 503 fi
 504 ])
 505
 506 AC_DEFUN([CHECK_LIB], [
 507 if test "x$HAVE_$1" != "xno"; then
 508  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno" -a "x$PKG_$1" = "xauto"; then
 509   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 510   AC_SUBST([HAVE_$1])
 511   if test "x$WANT_$1" != "xno"; then
 512    if test "x$HAVE_$1" = "xyes"; then
 513     if test "x$PKG_$1" = "x"; then
 514      SYSTEM_LIBS+=" -l[$2]"
 515      for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 516     else
 517      SHARED_$1+=" -l[$2]"
 518      for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 519     fi
 520    elif test "x$PKG_$1" = "x"; then
 521     RESULT=no
 522    fi
 523   fi
 524  fi
 525 fi
 526 ])
 527
 528 CHECK_LIB([X11], [X11], [XOpenDisplay])
 529 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 530 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 531 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 532 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 533 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 534 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 535 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 536 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 537 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 538 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 539 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 540 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 541 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 542 CHECK_LIB([PNG], [png], [png_read_png])
 543 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 544 CHECK_LIB([Z], [z], [gzopen])
 545 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 546 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 547 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 548 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 549 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 550 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 551 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 552 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 553 CHECK_LIB([lame], [mp3lame], [lame_init])
 554 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 555 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 556 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 557 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 558 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 559 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 560 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 561 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 562 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 563 CHECK_LIB([ilmbase], [IlmImf], [ImfOpenInputFile])
 564 CHECK_HEADERS([ilmbase], [IlmImf headers], [OpenEXR/ImfCRgbaFile.h])
 565 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 566 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 567 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 568 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 569 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 570 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 571 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 572 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 573 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 574 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 575 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 576 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 577 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 578 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 579 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 580 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 581 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 582 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 583 CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 584 CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])
 585 CHECK_LIB([libaom], [aom], [aom_codec_version])
 586 CHECK_HEADERS([libaom], [libaom headers], [aom/aom.h])
 587 CHECK_LIB([dav1d], [dav1d], [dav1d_version])
 588 CHECK_HEADERS([dav1d], [libdav1d headers], [dav1d/dav1d.h])
 589 CHECK_LIB([libwebp], [webp], [WebPGetEncoderVersion])
 590 CHECK_HEADERS([libwebp], [libwebp headers], [webp/encode.h])
 591 CHECK_LIB([a52dec], [a52], [a52_init])
 592 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 593 CHECK_LIB([encore], [encore], [encore])
 594 CHECK_HEADERS([encore], [encore headers], [encore.h])
 595 CHECK_LIB([giflib], [gif], [DGifOpen])
 596 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 597 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 598 CHECK_LIB([VDPAU], [vdpau], [vdp_device_create_x11])
 599 CHECK_LIB([VAAPI], [va], [vaInitialize])
 600 if test "x$WANT_VAAPI" != "xno" -a "x$HAVE_VAAPI" = "xyes"; then
 601   CHECK_HEADERS([vaapi_x11], [va x11 headers], [va/va_x11.h])
 602   CHECK_LIB([vaapi_x11], [va-x11], [vaGetDisplay])
 603   CHECK_HEADERS([vaapi_drm], [va drm headers], [va/va_drm.h])
 604   CHECK_LIB([vaapi_drm], [va-drm], [vaGetDisplayDRM])
 605 fi
 606 #CHECK_LIB([NVENC], [nvidia-encode], [NvEncodeAPICreateInstance])
 607
 608 #if test "x$HAVE_mjpegtools" = "xyes"; then
 609 #CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
 610 #fi
 611
 612 AC_DEFUN([CHECK_WANT], [
 613 RESULT=yes
 614 # WANT_$1
 615 if test "x$WANT_$1" != "xno" ; then
 616 AC_ARG_WITH(m4_tolower([$1]),
 617  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 618   [WANT_$1=$withval],[WANT_$1=$2])
 619  m4_quote($4)
 620  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 621   if test "x$WANT_$1" = "xyes" ; then
 622     AC_MSG_ERROR([required for $1 support.])
 623   fi
 624   WANT_$1=no
 625  elif test "x$WANT_$1" = "xauto" ; then
 626   WANT_$1=yes
 627  fi
 628 fi
 629 CFG_WANTS+=" $1"
 630 AC_SUBST([WANT_$1])
 631 ])
 632
 633 CHECK_WANT([GL], [auto], [use opengl], [
 634  CHECK_LIB([GL], [GL], [glUseProgram])
 635  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 636  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 637
 638 CHECK_WANT([OSS], [auto], [use OSS audio], [
 639  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 640
 641 CHECK_WANT([XFT], [auto], [use libXft], [
 642  CHECK_LIB([XFT], [Xft], [XftInit])
 643  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 644
 645 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 646  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 647  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 648
 649 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 650  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 651  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 652  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 653  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 654  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 655  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 656  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 657  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 658
 659 CHECK_WANT([DV], [auto], [use dv], [
 660  CHECK_LIB([libdv], [dv], [dv_init])
 661  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 662
 663 CHECK_WANT([DVB], [auto], [use dvb], [
 664  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 665
 666 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 667  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 668
 669 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 670  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 671
 672 CHECK_WANT([ESOUND], [no], [use esd], [
 673  CHECK_LIB([esound], [esd], [esd_open_sound])
 674  CHECK_HEADERS([esound], [esound headers], [esd.h])
 675  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 676  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 677
 678 CHECK_WANT([SHUTTLE], [yes], [shuttle dev support], [
 679  CHECK_HEADERS([keysyms], [x11 keysym defs], [X11/keysymdef.h])])
 680 if test "x$WANT_SHUTTLE" = "xno"; then
 681  WANT_SHUTTLE_USB="no"
 682 fi
 683 CHECK_WANT([SHUTTLE_USB], [yes], [use libusb-1.0], [
 684  CHECK_LIB([libusbx], [usb-1.0], [libusb_init])
 685  CHECK_HEADERS([libusbx], [libusb headers], [libusb-1.0/libusb.h])])
 686
 687 CHECK_WANT([LV2], [auto], [use lv2], [
 688  saved_CFLAGS="$CFLAGS"
 689  CHECK_LIB([lilv], [lilv-0], [lilv_world_new])
 690  CHECK_LIB([sord], [sord-0], [sord_world_new])
 691  CHECK_LIB([serd], [serd-0], [serd_reader_new])
 692  CHECK_LIB([sratom], [sratom-0], [sratom_new])
 693  CFLAGS="-I/usr/include/lilv-0 -I/usr/local/include/lilv-0"
 694  CHECK_HEADERS([lv2], [lilv headers], [lilv/lilv.h])
 695  CHECK_LIB([suil], [suil-0], [suil_instance_new])
 696  CFLAGS="-I/usr/include/suil-0 -I/usr/local/include/suil-0"
 697  CHECK_HEADERS([lv2], [suil headers], [suil/suil.h])
 698  CFLAGS="$saved_CFLAGS"])
 699
 700 CHECK_WANT([CUDA], [auto], [build cuda plugins], [
 701   CHECK_HEADERS([CUDA], [cuda sdk], [${CUDA_PATH:-/usr/local/cuda}/include/cuda.h])])
 702
 703 CHECK_WANT([DL], [auto], [system has libdl], [
 704  CHECK_LIB([DL], [dl], [dlopen])])
 705
 706 CHECK_WANT([EXR], [auto], [use exr], [])
 707
 708 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 709 ])
 710
 711 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 712  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 713
 714 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 715  AC_MSG_CHECKING([for openexr available])
 716  saved_LIBS="$LIBS"
 717  saved_CXXFLAGS="$CXXFLAGS"
 718  # ilmbase libs
 719  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 720  CXXFLAGS="-I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 721  AC_LANG_PUSH(C++)
 722  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 723 #include "ImfChannelList.h"
 724 #include "ImfChromaticities.h"
 725 #include "ImfCompression.h"
 726 #include "ImfIO.h"
 727 #include "ImfInputFile.h"
 728 #include "ImfOutputFile.h"
 729 #include "ImfPixelType.h"
 730 #include "ImfRgbaFile.h"
 731 #include "ImfRgbaYca.h"
 732 #include "ImfVersion.h"
 733 class EXRIStream : public Imf::IStream { public:
 734 EXRIStream() : Imf::IStream("mypath") {} };
 735 class EXROStream : public Imf::OStream { public:
 736 EXROStream() : Imf::OStream("mypath") {} };
 737 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 738  RESULT="$HAVE_OPENEXR"
 739  if test "x$RESULT" = "xyes"; then
 740    SHARED_openexr="$LIBS"
 741    CFG_CFLAGS+=" -I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 742  fi
 743  LIBS="$saved_LIBS"
 744  CXXFLAGS="$saved_CXXFLAGS"
 745  AC_LANG_POP(C++)
 746  AC_MSG_RESULT([$HAVE_OPENEXR])
 747 ])
 748 AC_SUBST([HAVE_OPENEXR])
 749
 750 # build global_config
 751 OBJDIR=`uname -m`
 752 AC_SUBST(OBJDIR)
 753
 754 echo "AC_HELP_STRING([Reason],[Package])"
 755 echo "AC_HELP_STRING([------],[-------])"
 756
 757 AC_DEFUN([PKG_DISABLED],[
 758  PKG_$1="no"
 759  BUILD_$1=0
 760  AC_SUBST(BUILD_$1)
 761  echo "AC_HELP_STRING([disabled],[$1])"
 762 ])
 763 AC_DEFUN([PKG_SHARED],[
 764  BUILD_$1=0
 765  AC_SUBST(BUILD_$1)
 766  SHARED_LIBS+="$SHARED_$1"
 767 ])
 768
 769 AC_DEFUN([PKG_STATIC],[
 770  if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 771   PKG_$1="yes"
 772   BUILD_$1=1
 773   AC_SUBST(BUILD_$1)
 774   STATIC_BLDS+=" [$1]"
 775   echo "AC_HELP_STRING([$2],[$1])"
 776  fi
 777 ])
 778
 779 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 780
 781 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 782 # order matters
 783 for dep in \
 784         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 785         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 \
 786         libiec61883/libraw1394 libavc1394/librom1394 \
 787         openexr/ilmbase ilmbase/libogg \
 788         libtheora/libogg libtheora/libvorbis ; do
 789   lib=`dirname $dep`;  needs=`basename $dep`
 790   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 791   if test "x$pkg_lib" != "xno"; then
 792     eval "PKG_$needs=yes"
 793   fi
 794 done
 795 fi
 796
 797 AC_DEFUN([PKG_PROVIDE],[
 798 if test "x$BUILD_$1" = "x" ; then
 799  if test "x$PKG_$1" = "xyes"; then
 800   PKG_FORCED([$1])
 801  elif test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 802   PKG_DISABLED([$1])
 803  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 804   PKG_STATIC([$1],[static])
 805  elif test "x$HAVE_$1" = "xyes"; then
 806   PKG_SHARED([$1])
 807  else
 808   PKG_STATIC([$1],[needed])
 809  fi
 810 fi
 811 ])
 812
 813 PKG_PROVIDE([a52dec])
 814 PKG_PROVIDE([djbfft])
 815 PKG_PROVIDE([encore])
 816 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 817 PKG_PROVIDE([esound],[$WANT_ESOUND])
 818 PKG_PROVIDE([ffmpeg])
 819 PKG_PROVIDE([fftw])
 820 PKG_PROVIDE([flac])
 821 PKG_PROVIDE([giflib])
 822 PKG_PROVIDE([ilmbase], [$WANT_OPENEXR])
 823 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 824 PKG_PROVIDE([lame])
 825 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 826 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 827 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 828 PKG_PROVIDE([libdv],[$WANT_DV])
 829 PKG_PROVIDE([libjpeg])
 830 PKG_PROVIDE([libogg])
 831 PKG_PROVIDE([libsndfile])
 832 PKG_PROVIDE([libtheora])
 833 PKG_PROVIDE([libuuid])
 834 PKG_PROVIDE([libvorbis])
 835 PKG_PROVIDE([mjpegtools])
 836 PKG_PROVIDE([libaom])
 837 PKG_PROVIDE([dav1d])
 838 PKG_PROVIDE([libwebp])
 839 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 840 PKG_PROVIDE([openjpeg])
 841 PKG_PROVIDE([tiff])
 842 PKG_PROVIDE([twolame])
 843 PKG_PROVIDE([x264])
 844 PKG_PROVIDE([x265])
 845 PKG_PROVIDE([libvpx])
 846 PKG_PROVIDE([opus])
 847 PKG_PROVIDE([lv2], [$WANT_LV2])
 848 PKG_PROVIDE([lilv], [$WANT_LV2])
 849 PKG_PROVIDE([sratom], [$WANT_LV2])
 850 PKG_PROVIDE([serd], [$WANT_LV2])
 851 PKG_PROVIDE([sord], [$WANT_LV2])
 852 PKG_PROVIDE([suil], [$WANT_LV2])
 853 PKG_PROVIDE([ffnvcodec], [$WANT_NV])
 854
 855 if test "x$WANT_LV2" = "xyes"; then
 856   if test "x$HAVE_lv2" = "xyes" -a "x$BUILD_lilv" = "x0"; then
 857     CFG_CFLAGS+=' -I/usr/include/lilv-0 -I/usr/local/include/lilv-0'
 858     CFG_CFLAGS+=' -I/usr/include/suil-0 -I/usr/local/include/suil-0'
 859   fi
 860 fi
 861
 862 AC_SUBST(STATIC_BLDS)
 863 for f in $SHARED_LIBS; do
 864   echo "AC_HELP_STRING([shared],[$f])"
 865 done
 866 AC_SUBST(SHARED_LIBS)
 867 for f in $SYSTEM_LIBS; do
 868   echo "AC_HELP_STRING([system],[$f])"
 869 done
 870 AC_SUBST(SYSTEM_LIBS)
 871
 872 echo ""
 873 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 874   CFG_CFLAGS+=" -DHAVE_CIN_3RDPARTY"
 875 fi
 876 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 877          VIDEO4LINUX2 ESOUND PACTL OPENEXR LV2 \
 878          COMMERCIAL LIBZMPEG SHUTTLE SHUTTLE_USB \
 879          VAAPI VDPAU CUDA NV; do
 880   eval vv="\$WANT_$v"
 881   if test "x$vv" != "xno"; then
 882     CFG_CFLAGS+=" -DHAVE_$v"
 883     vv=with
 884   else
 885     vv=without
 886   fi
 887   v=`echo "$v" | tr "A-Z" "a-z"`
 888   echo "  using: $vv-$v"
 889 done
 890
 891 echo "  using: with-jobs = $WANT_JOBS"
 892 echo "  using: exec-name = $WANT_CIN"
 893 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 894 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 895 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 896 echo "  using: with-browser = $WANT_CIN_BROWSER"
 897 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 898 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 899 echo "  using: with-opencv = $WANT_OPENCV"
 900 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 901 echo "  using: with-noelision = $WANT_NOELISION"
 902 echo "  using: with-booby = $WANT_BOOBY"
 903 echo "  using: with-libzmpeg = $WANT_LIBZMPEG"
 904 echo "  using: with-commerical = $WANT_COMMERCIAL"
 905 echo "  using: with-vaapi = $WANT_VAAPI"
 906 echo "  using: with-vdpau = $WANT_VDPAU"
 907 echo "  using: with-nv = $WANT_NV"
 908 echo "  using: with-cuda = $WANT_CUDA"
 909 echo ""
 910 echo "  using: thirdparty build = $WANT_CIN_3RDPARTY"
 911 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 912 echo "  using: static-build = $WANT_STATIC_BUILD"
 913 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 914 echo ""
 915
 916 # build extras
 917 if test "x$HAVE_tiff" = "xyes"; then
 918   if test "x$HAVE_jbig" = "xyes"; then
 919     EXTRA_LIBS+=' -ljbig'
 920   fi
 921 fi
 922 if test "x$HAVE_NUMA" = "xyes"; then
 923   EXTRA_LIBS+=' -lnuma'
 924 fi
 925
 926 FFMPEG_EXTRA_LDFLAGS=""
 927 if test "x$WANT_VAAPI" != "xno" -a "x$HAVE_VAAPI" = "xyes"; then
 928   FFMPEG_EXTRA_LDFLAGS+=' -lva'
 929   EXTRA_LIBS+=' -lva'
 930   WANT_VAPPI="yes"
 931   CFG_WANTS+=" VAAPI"
 932   if test "x$HAVE_vaapi_x11" = "xyes"; then
 933     FFMPEG_EXTRA_LDFLAGS+=' -lva-x11'
 934     EXTRA_LIBS+=' -lva-x11'
 935   fi
 936   if test "x$HAVE_vaapi_drm" = "xyes"; then
 937     FFMPEG_EXTRA_LDFLAGS+=' -lva-drm'
 938     EXTRA_LIBS+=' -lva-drm'
 939   fi
 940 fi
 941 if test "x$WANT_VDPAU" != "xno" -a "x$HAVE_VDPAU" = "xyes"; then
 942   WANT_VDPAU="yes"
 943   CFG_WANTS+=" VDPAU"
 944 fi
 945 if test "x$WANT_NV" != "xno"; then
 946   WANT_NV="yes"
 947   CFG_WANTS+=" NV"
 948 fi
 949
 950 if test "x$HAVE_DL" = "xyes"; then
 951   EXTRA_LIBS+=' -ldl'
 952   FFMPEG_EXTRA_LDFLAGS+=' -ldl'
 953 fi
 954 if test "x$FFMPEG_EXTRA_LDFLAGS" != "x"; then
 955   FFMPEG_EXTRA_CFG+=' --extra-ldflags="'$FFMPEG_EXTRA_LDFLAGS'"'
 956 fi
 957
 958 if test "x$WANT_BOOBY" != "xno"; then
 959   CFG_CFLAGS+=" -DBOOBY"
 960 fi
 961
 962 # intel lock elision bugs
 963 if test "x$WANT_NOELISION" != "xno"; then
 964   CFG_RPATH=`ls -1fd 2> /dev/null \
 965  /usr/lib/noelision \
 966  /lib/noelision \
 967  /usr/lib64/noelision \
 968  /lib64/noelision \
 969   | tail -1`
 970 fi
 971
 972 AC_SUBST(WANT_CIN_3RDPARTY)
 973 AC_SUBST(EXTRA_LIBS)
 974 AC_SUBST(FFMPEG_EXTRA_CFG)
 975 AC_SUBST(WANT_X264_HIDEPTH)
 976 AC_SUBST(WANT_X265_HIDEPTH)
 977
 978 AC_SUBST(CFG_CFLAGS)
 979 AC_SUBST(CFG_CXXFLAGS)
 980
 981 AC_CONFIG_FILES([Makefile])
 982 AC_OUTPUT
 983
 984 exec > global_config
 985
 986 echo "SHELL := /bin/bash"
 987 echo "export SHELL"
 988 echo "WANT_JOBS := $WANT_JOBS"
 989 echo ""
 990 echo "OBJDIR := $OBJDIR"
 991 echo "BINDIR := \$(TOPDIR)/bin"
 992 echo "CINELERRA := \$(TOPDIR)/cinelerra"
 993 echo "GUICAST := \$(TOPDIR)/guicast"
 994 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
 995 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
 996 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
 997 echo "PLUGINS := \$(TOPDIR)/plugins"
 998 echo "TDB := \$(TOPDIR)/db"
 999 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
1000 echo "EXTRA_LIBS := $EXTRA_LIBS"
1001 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
1002 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
1003 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
1004 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
1005 echo ""
1006
1007 echo "WANT_CIN := $WANT_CIN"
1008 CFG_WANTS+=" CIN_3RDPARTY LIBZMPEG COMMERCIAL"
1009 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
1010 echo ""
1011
1012 echo "ifndef CFLAGS_"
1013 echo "ifdef CFLAGS"
1014 echo "CFLAGS_ := \$(CFLAGS)"
1015 echo "else"
1016 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
1017 echo "endif"
1018 echo "endif"
1019 echo "ifndef CXXFLAGS_"
1020 echo "ifdef CXXFLAGS"
1021 echo "CXXFLAGS_ := \$(CXXFLAGS)"
1022 echo "endif"
1023 echo "endif"
1024 echo "ifndef LDFLAGS_"
1025 echo "ifdef LDFLAGS"
1026 echo "LDFLAGS_ := \$(LDFLAGS)"
1027 echo "endif"
1028 echo "endif"
1029
1030 echo "CFLAGS := \$(CFLAGS_)"
1031 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
1032 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
1033 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
1034 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
1035 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
1036 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
1037 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
1038 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
1039 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
1040 echo ""
1041 if test "x$CFG_CXXFLAGS" != "x"; then
1042   for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
1043   echo ""
1044 fi
1045 if test "x$CFG_LDFLAGS" != "x" ; then
1046   echo "LDFLAGS +=$CFG_LDFLAGS"
1047   echo ""
1048 fi
1049
1050 if test "x$WANT_X264_HIDEPTH" = "xyes" ; then
1051   X264_CFG_PARAMS="$X264_CFG_PARAMS --bit-depth=10"
1052 fi
1053 if test "x$WANT_X265_HIDEPTH" = "xyes" ; then
1054   X265_CFG_PARAMS="$X265_CFG_PARAMS -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
1055 fi
1056
1057 for pkg in $STATIC_PKGS; do
1058   eval pkg_lib="\$PKG_$pkg"
1059   if test "x$pkg_lib" = "xno"; then continue; fi;
1060   echo "static_pkgs += $pkg"
1061 done
1062 echo ""
1063
1064 for pkg in $STATIC_BLDS; do
1065   echo "static_blds += $pkg"
1066   ver_pkg=ver_$pkg
1067   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
1068   inc_pkg=inc_$pkg
1069   echo "$inc_pkg := \\"
1070   for inc in ${!inc_pkg}; do
1071     echo "  -I\$($ver_pkg)/$inc \\"
1072   done
1073   echo ""
1074   echo "static_incs += \$(inc_$pkg)"
1075   lib_pkg=lib_$pkg
1076   echo "$lib_pkg := \\"
1077   for lib in ${!lib_pkg}; do
1078     echo "  \$($ver_pkg)/$lib \\"
1079   done
1080   echo ""
1081   echo "static_libs += \$($lib_pkg)"
1082   echo ""
1083 done
1084 echo ""
1085
1086 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
1087 echo ""
1088 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
1089 echo "export static_pkgs static_blds shared_libs system_libs"
1090 echo ""
1091
1092 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
1093
1094 if test "x$CFG_RPATH" != "x"; then
1095   echo "libraries+= -Wl,-rpath=$CFG_RPATH"
1096 fi
1097
1098 echo "libraries += -Wl,--start-group"
1099 echo "libraries += \$(thirdparty_libraries)"
1100 echo "libraries += \$(system_libs)"
1101 echo "libraries += \$(EXTRA_LIBS)"
1102 echo "libraries += -Wl,--end-group"
1103 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
1104 echo "libraries += \$(thirdparty_libraries)"
1105 echo "libraries += \$(system_libs)"
1106 echo "libraries += \$(EXTRA_LIBS)"
1107 echo ""
1108 echo "export thirdparty_libraries libraries"
1109 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
1110 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
1111
1112 if test "x$HAVE_tiff" = "xyes"; then
1113   if test "x$HAVE_jbig" != "xyes"; then
1114     echo "tiff.cfg_params+= --disable-jbig"
1115   fi
1116 fi
1117
1118 if test "x$WANT_GIT_FFMPEG" != "xno"; then
1119   echo "ffmpeg.git := $WANT_GIT_FFMPEG"
1120 fi
1121 if test "x$X264_CFG_PARAMS" != "x" ; then
1122   echo "x264.cfg_params :=$X264_CFG_PARAMS --enable-static --enable-pic"
1123 fi
1124 if test "x$X265_CFG_PARAMS" != "x" ; then
1125   echo "x265.cfg_params :=$X265_CFG_PARAMS -DENABLE_SHARED=no"
1126 fi