cinelerra-5.1/configure.ac

   1
   2 AC_PREREQ([2.69])
   3 AC_INIT([cinelerra], [5.1], [mail@lists.cinelerra-gg.org])
   4 AM_INIT_AUTOMAKE([foreign])
   5
   6 AM_PROG_AS
   7 AC_LANG_CPLUSPLUS
   8 AC_LANG_C
   9 AC_PROG_CXX
  10
  11 CFG_CFLAGS+=" -fno-omit-frame-pointer -fno-math-errno -fno-signed-zeros"
  12 CFG_CFLAGS+=" -pthread -Wall"
  13 # misguided pedantic warnings
  14 #  this is extra work, not a gain...
  15 CFG_CFLAGS+=" -Wno-unknown-warning-option"
  16 CFG_CFLAGS+=" -Wno-attributes"
  17 CFG_CFLAGS+=" -Wno-unused-result"
  18 CFG_CFLAGS+=" -Wno-stringop-overflow"
  19 CFG_CFLAGS+=" -Wno-format-truncation"
  20 CFG_CFLAGS+=" -Wno-format-overflow"
  21 CFG_CFLAGS+=" -Wno-parentheses"
  22 CFG_CFLAGS+=" -Wno-stringop-truncation"
  23 CFG_CFLAGS+=" -D__STDC_CONSTANT_MACROS"
  24 CFG_CFLAGS+=" -D__STDC_LIMIT_MACROS"
  25 CFG_CFLAGS+=" -DPNG_SKIP_SETJMP_CHECK=1"
  26 CFG_CFLAGS+=" -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
  27 CFG_CFLAGS+=" -I/usr/include -I/usr/local/include"
  28 CFG_CFLAGS+=" -I/usr/include/freetype2 -I/usr/local/include/freetype2"
  29 CFG_CFLAGS+=" -I/usr/include/uuid -I/usr/local/include/uuid"
  30 CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
  31
  32 CFG_LDFLAGS+=" -z noexecstack"
  33
  34 AC_DEFUN([CHECK_WITH], [
  35 AC_ARG_WITH([$1],
  36   AC_HELP_STRING([--with-[$1]], [$2 ($4)]),
  37   [WANT_$3=$withval], [WANT_$3='$4'])
  38 AC_SUBST([WANT_$3])
  39 ])
  40
  41 CHECK_WITH([jobs],[parallel build jobs],[JOBS],[auto])
  42 CHECK_WITH([exec-name],[binary executable name],[CIN],[cin])
  43 CHECK_WITH([single-user],[to install cin in bin],[CINBIN_BUILD],[no])
  44 CHECK_WITH([ladspa-build],[build ladspa library],[LADSPA_BUILD],[yes])
  45 CHECK_WITH([lv2],[lv2 library support],[LV2],[yes])
  46 CHECK_WITH([cinlib],[cinelerra library path],[CINLIB_DIR],[auto])
  47 CHECK_WITH([cindat],[cinelerra share path],[CINDAT_DIR],[auto])
  48 CHECK_WITH([plugin-dir],[plugin install dir],[PLUGIN_DIR],[auto])
  49 CHECK_WITH([ladspa-dir],[ladspa install dir],[LADSPA_DIR],[auto])
  50 CHECK_WITH([config-dir],[.bcast config dir],[CONFIG_DIR],[$$HOME/.bcast5])
  51 CHECK_WITH([browser],[cin_browser path],[CIN_BROWSER],[firefox])
  52 CHECK_WITH([git-ffmpeg],[git ffmpeg using url],[GIT_FFMPEG],[no])
  53 CHECK_WITH([noelision],[use noelision/libpthread],[NOELISION],[auto])
  54 CHECK_WITH([booby],[window lock trace booby trap],[BOOBY],[no])
  55 CHECK_WITH([libzmpeg],[build libzmpeg],[LIBZMPEG],[yes])
  56 CHECK_WITH([commercial],[enable commercial capture],[COMMERCIAL],[yes])
  57 CHECK_WITH([thirdparty],[use thirdparty build],[CIN_3RDPARTY],[yes])
  58 CHECK_WITH([shuttle],[shuttle device],[SHUTTLE],[yes])
  59 CHECK_WITH([vaapi],[video acceleration api],[VAAPI],[yes])
  60 CHECK_WITH([vdpau],[video decode+presentation api for unix],[VDPAU],[yes])
  61 CHECK_WITH([nv],[nvenc/nvdec ffnvcodec api],[NV],[yes])
  62 CHECK_WITH([cuda],[nv cuda plugins],[CUDA],[auto])
  63 CHECK_WITH([clang],[use clang instead of gcc/g++],[CLANG],[no])
  64
  65 if test "x$WANT_LV2" != "xno"; then
  66   GTK2_LIBS=`pkg-config --libs gtk+-2.0`
  67   AC_CHECK_LIB([m], [gtk_init], [HAVE_gtk=yes], [HAVE_gtk=no], [$GTK2_LIBS])
  68   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --cflags gtk+-2.0`" && HAVE_gtk=no
  69   test "x$HAVE_gtk" != "xno" && test -z "`pkg-config --libs gtk+-2.0`" && HAVE_gtk=no
  70   if test "x$HAVE_gtk" = "xno"; then
  71     AC_MSG_ERROR([LV2 requires gtk+-2.0 support.])
  72   fi
  73 fi
  74
  75 if test "x$WANT_COMMERCIAL" = "xyes" -a "x$WANT_LIBZMPEG" != "xyes" ; then
  76   AC_MSG_ERROR([commercial requires libzmpeg support.])
  77 fi
  78
  79 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
  80   WANT_LOCALE_DIR='$$CIN_LIB/locale'
  81   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR='$$CIN_PATH'
  82   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR='$$CIN_PATH'
  83   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR='$$CIN_LIB/plugins'
  84   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR='$$CIN_LIB/ladspa'
  85 else
  86   lcldir=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  87     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  88     eval "dir=\"$localedir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  89     echo "$dir"`
  90   usrdat=`test "x$prefix" = "xNONE" && prefix=$ac_default_prefix; \
  91     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  92     eval "dir=\"$datadir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  93     echo "$dir"`
  94   usrlib=`test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"; \
  95     test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"; \
  96     eval "dir=\"$libdir\""; eval "dir=\"$dir\""; eval "dir=\"$dir\""; \
  97     echo "$dir"`
  98   test "x$usrlib" = "x/lib" -o "x$usrlib" = "x/usr/lib" -o \
  99        "x$usrlib" = "x/usr/local/lib" -a -e "/usr/lib64" && \
 100   test ! -e "/usr/lib" -o `ls -1 /usr/lib64 | wc -l` -gt `ls -1 /usr/lib | wc -l` && \
 101     usrlib+="64"
 102   WANT_LOCALE_DIR="$lcldir"
 103   test "x$WANT_CINDAT_DIR" = "xauto" && WANT_CINDAT_DIR="$usrdat/$WANT_CIN"
 104   test "x$WANT_CINLIB_DIR" = "xauto" && WANT_CINLIB_DIR="$usrlib/$WANT_CIN"
 105   test "x$WANT_PLUGIN_DIR" = "xauto" && WANT_PLUGIN_DIR="$WANT_CINLIB_DIR/plugins"
 106   test "x$WANT_LADSPA_DIR" = "xauto" && WANT_LADSPA_DIR="$WANT_CINLIB_DIR/ladspa"
 107 fi
 108
 109 CIN_INSTALLS=""
 110 CIN_UNINSTALLS=""
 111 if test "x$WANT_LIBZMPEG" = "xyes"; then
 112   CIN_INSTALLS+=" zmp_install"
 113   CIN_UNINSTALLS+=" zmp_uninstall"
 114 fi
 115 if test "x$WANT_COMMERCIAL" = "xyes"; then
 116   CIN_INSTALLS+=" com_install"
 117   CIN_UNINSTALLS+=" com_uninstall"
 118 fi
 119 if test "x$WANT_LADSPA_BUILD" = "xyes"; then
 120   CIN_INSTALLS+=" lad_install "
 121   CIN_UNINSTALLS+=" lad_uninstall "
 122 fi
 123 if test "x$WANT_LV2" = "xyes"; then
 124   CIN_INSTALLS+=" lv2_install "
 125   CIN_UNINSTALLS+=" lv2_uninstall "
 126 fi
 127 AC_SUBST(CIN_INSTALLS)
 128 AC_SUBST(CIN_UNINSTALLS)
 129
 130 if test "x$WANT_CINBIN_BUILD" = "xyes"; then
 131   MAK_INSTALLS="dvl_install"
 132   MAK_UNINSTALLS="dvl_uninstall"
 133 else
 134   MAK_INSTALLS=" sys_install"
 135   MAK_UNINSTALLS="sys_uninstall"
 136 fi
 137 AC_SUBST(MAK_INSTALLS)
 138 AC_SUBST(MAK_UNINSTALLS)
 139
 140 if test "x$WANT_JOBS" = "xauto"; then
 141   CPUS=`grep -c "^proc" /proc/cpuinfo`
 142   WANT_JOBS=`expr $CPUS + $CPUS / 2 + 2`
 143 fi
 144
 145 AC_DEFUN([PKG_DEF],[
 146 STATIC_PKGS+=" [$1]"
 147 ver_$1="$2"
 148 lib_$1="$3"
 149 inc_$1="$4"
 150 ])
 151
 152 AC_DEFUN([PKG_3RD],[
 153 AC_ARG_ENABLE([$1],
 154   AC_HELP_STRING([--enable-$1],[build $1 ($2)]),
 155   [PKG_$1=$enableval], [PKG_$1=$2])
 156 PKG_DEF([$1],[$3],[$4],[$5])
 157 ])
 158
 159 # thirdparty builds
 160
 161 PKG_3RD([a52dec],[yes],
 162   [a52dec-0.7.4],
 163   [ liba52/.libs/liba52.a ],
 164   [ include ])
 165
 166 PKG_3RD([djbfft],[yes],
 167   [djbfft-0.76],
 168   [ libdjbfft.a ],
 169   [ . ])
 170
 171 PKG_3RD([audiofile],[no],
 172   [audiofile-0.3.6],
 173   [ libaudiofile/.libs/libaudiofile.a \
 174     libaudiofile/modules/.libs/libmodules.a \
 175     libaudiofile/alac/.libs/libalac.a ],
 176   [ libaudiofile ])
 177
 178 PKG_3RD([encore],[no],
 179   [encore-5.0],
 180   [ \$(OBJDIR)/libencore.a ],
 181   [ . ])
 182
 183 PKG_3RD([esound],[no],
 184   [esound-0.2.41],
 185   [ .libs/libesd.a \
 186     .libs/libesddsp.a ],
 187   [ . ])
 188
 189 PKG_3RD([ffmpeg],[yes],
 190   [ffmpeg-4.2],
 191   [ libavutil/libavutil.a \
 192     libavcodec/libavcodec.a \
 193     libpostproc/libpostproc.a \
 194     libavdevice/libavdevice.a \
 195     libavformat/libavformat.a \
 196     libswscale/libswscale.a \
 197     libavfilter/libavfilter.a \
 198     libswresample/libswresample.a ],
 199   [ . ])
 200
 201 if test "x$WANT_GIT_FFMPEG" != "xno" ; then
 202   ver_ffmpeg="ffmpeg.git"
 203 fi
 204
 205 PKG_3RD([fftw],[auto],
 206   [fftw-3.3.8],
 207   [ .libs/libfftw3.a \
 208     libbench2/libbench2.a \
 209     rdft/scalar/r2cb/.libs/librdft_scalar_r2cb.a \
 210     rdft/scalar/r2r/.libs/librdft_scalar_r2r.a \
 211     rdft/scalar/.libs/librdft_scalar.a \
 212     rdft/scalar/r2cf/.libs/librdft_scalar_r2cf.a \
 213     rdft/.libs/librdft.a \
 214     api/.libs/libapi.a \
 215     reodft/.libs/libreodft.a \
 216     dft/scalar/codelets/.libs/libdft_scalar_codelets.a \
 217     dft/scalar/.libs/libdft_scalar.a \
 218     dft/.libs/libdft.a \
 219     kernel/.libs/libkernel.a \
 220     simd-support/.libs/libsimd_support.a ],
 221   [ api ])
 222
 223 PKG_3RD([flac],[auto],
 224   [flac-1.3.2],
 225   [ src/libFLAC/.libs/libFLAC.a \
 226     src/libFLAC++/.libs/libFLAC++.a \
 227     src/share/replaygain_analysis/.libs/libreplaygain_analysis.a \
 228     src/share/replaygain_synthesis/.libs/libreplaygain_synthesis.a \
 229     src/share/grabbag/.libs/libgrabbag.a \
 230     src/share/utf8/.libs/libutf8.a \
 231     src/test_libs_common/.libs/libtest_libs_common.a ],
 232   [ include ])
 233
 234 PKG_3RD([giflib],[yes],
 235   [giflib-5.1.6],
 236   [ libgif.a ],
 237   [ . ])
 238
 239 PKG_DEF([ladspa], [ladspa-0.4.17], [], [])
 240
 241 PKG_3RD([lame],[auto],
 242   [lame-3.100],
 243   [ libmp3lame/.libs/libmp3lame.a \
 244     mpglib/.libs/libmpgdecoder.a ],
 245   [ include ])
 246
 247 PKG_3RD([libavc1394],[auto],
 248   [libavc1394-0.5.4],
 249   [ libavc1394/.libs/libavc1394.a \
 250     librom1394/.libs/librom1394.a \
 251     common/.libs/libraw1394util.a ],
 252   [ . ])
 253
 254 PKG_3RD([libraw1394],[auto],
 255   [libraw1394-2.1.2],
 256   [ src/.libs/libraw1394.a ],
 257   [ . ])
 258
 259 PKG_3RD([libiec61883],[auto],
 260   [libiec61883-1.2.0],
 261   [ src/.libs/libiec61883.a ],
 262   [ src ])
 263
 264 PKG_3RD([libdv],[auto],
 265   [libdv-1.0.0],
 266   [ libdv/.libs/libdv.a ],
 267   [ . ])
 268
 269 PKG_3RD([libjpeg],[auto],
 270   [libjpeg-turbo-1.5.1],
 271   [ .libs/libjpeg.a \
 272     .libs/libturbojpeg.a \
 273     simd/.libs/libsimd.a ],
 274   [ . ])
 275
 276 PKG_3RD([opus],[auto],
 277   [opus-1.3],
 278   [ .libs/libopus.a ],
 279   [ include ])
 280
 281 PKG_3RD([openjpeg],[auto],
 282   [openjpeg-2.3.0],
 283   [ bin/libopenjp2.a ],
 284   [ src/lib/openjp2 ])
 285
 286 PKG_3RD([libogg],[auto],
 287   [libogg-1.3.3],
 288   [ src/.libs/libogg.a ],
 289   [ include ])
 290
 291 PKG_3RD([libsndfile],[auto],
 292   [libsndfile-1.0.28],
 293   [ src/.libs/libsndfile.a \
 294     src/.libs/libcommon.a \
 295     src/G72x/.libs/libg72x.a \
 296     src/GSM610/.libs/libgsm.a ],
 297   [ . ])
 298
 299 PKG_3RD([libtheora],[auto],
 300   [libtheora-1.1.1],
 301   [ lib/.libs/libtheora.a \
 302     lib/.libs/libtheoradec.a \
 303     lib/.libs/libtheoraenc.a ],
 304   [ . ])
 305
 306 PKG_3RD([libuuid],[yes],
 307   [libuuid-1.0.3],
 308   [ .libs/libuuid.a ],
 309   [ . ])
 310
 311 PKG_3RD([libvorbis],[auto],
 312   [libvorbis-1.3.6],
 313   [ lib/.libs/libvorbis.a \
 314     lib/.libs/libvorbisenc.a \
 315     lib/.libs/libvorbisfile.a ],
 316   [ include . ])
 317
 318 PKG_3RD([mjpegtools],[yes],
 319   [mjpegtools-2.1.0],
 320   [ utils/mmxsse/.libs/libmmxsse.a \
 321     utils/.libs/libmjpegutils.a \
 322     lavtools/.libs/liblavfile.a \
 323     lavtools/.libs/liblavjpeg.a \
 324     mplex/.libs/libmplex2.a \
 325     yuvfilters/.libs/libyuvfilters.a \
 326     mpeg2enc/.libs/libmpeg2encpp.a ],
 327   [ .  lavtools utils ])
 328
 329 PKG_3RD([openexr],[auto],
 330   [openexr-2.4.0],
 331   [ build/usr/local/lib/libIlmImfUtil.a \
 332     build/usr/local/lib/libIlmImf.a \
 333     build/usr/local/lib/libIlmThread.a \
 334     build/usr/local/lib/libImath.a \
 335     build/usr/local/lib/libIexMath.a \
 336     build/usr/local/lib/libIex.a \
 337     build/usr/local/lib/libHalf.a ],
 338   [ build/usr/local/include ])
 339
 340 #PKG_3RD([festival],[no],
 341 #  [festival],
 342 #  [],
 343 #  [])
 344 #PKG_3RD(speech_tools,[no],
 345 #  [speech_tools],
 346 #  [],
 347 #  [])
 348 #
 349 PKG_3RD([tiff],[auto],
 350   [tiff-4.0.10],
 351   [ libtiff/.libs/libtiff.a \
 352     libtiff/.libs/libtiffxx.a \
 353     port/.libs/libport.a ],[
 354    . ])
 355
 356 PKG_3RD([twolame],[auto],
 357   [twolame-0.3.13],
 358   [ libtwolame/.libs/libtwolame.a ],
 359   [  libtwolame ])
 360
 361 PKG_3RD([x264],[auto],
 362   [x264-snapshot-20190117-2245-stable],
 363   [ libx264.a ],
 364   [ . ])
 365
 366 PKG_3RD([x265],[auto],
 367   [x265_3.1.2],
 368   [ libx265.a ],
 369   [ . source ])
 370
 371 PKG_3RD([libvpx],[auto],
 372   [libvpx-1.8.1],
 373   [ libvpx.a ],
 374   [ . ])
 375
 376 PKG_3RD([lv2],[auto],
 377   [lv2-1.16.0],
 378   [ ],
 379   [ usr/local/include usr/local/lib64/lv2 usr/local/lib/lv2 ])
 380
 381 PKG_3RD([sratom],[auto],
 382   [sratom-0.6.2],
 383   [ usr/local/lib/libsratom-0.a ],
 384   [ usr/local/include ])
 385
 386 PKG_3RD([serd],[auto],
 387   [serd-0.30.0],
 388   [ usr/local/lib/libserd-0.a ],
 389   [ usr/local/include ])
 390
 391 PKG_3RD([sord],[auto],
 392   [sord-0.16.2],
 393   [ usr/local/lib/libsord-0.a ],
 394   [ usr/local/include ])
 395
 396 PKG_3RD([lilv],[auto],
 397   [lilv-0.24.4],
 398   [ usr/local/lib/liblilv-0.a ],
 399   [ usr/local/include ])
 400
 401 PKG_3RD([suil],[auto],
 402   [suil-0.10.2],
 403   [ usr/local/lib/libsuil-0.a ],
 404   [ usr/local/include ])
 405
 406 PKG_3RD([libaom],[auto],
 407   [libaom-v1.0.0],
 408   [ usr/local/lib*/libaom*.a ],
 409   [ usr/local/include ])
 410
 411 PKG_3RD([dav1d],[auto],
 412   [dav1d-0.4.0],
 413   [ usr/local/lib*/libdav1d*.a ],
 414   [ usr/local/include ])
 415
 416 PKG_3RD([libwebp],[auto],
 417   [libwebp-1.0.2],
 418   [ usr/local/lib*/libwebp*.a ],
 419   [ usr/local/include ])
 420
 421 PKG_3RD([ffnvcodec],[auto],
 422   [ffnvcodec],
 423   [ ],
 424   [ . ])
 425
 426 AC_SUBST(STATIC_PKGS)
 427
 428 AC_DEFUN([CHECK_ENABLE], [
 429 AC_ARG_ENABLE([$1],
 430   AC_HELP_STRING([--enable-[$1]], [$3 ([$4])]),
 431   [WANT_$2=$enableval], [WANT_$2=[$4]])
 432 ])
 433
 434 CHECK_ENABLE([static-build], [STATIC_BUILD], [build static], [auto])
 435 CHECK_ENABLE([x264_hidepth], [X264_HIDEPTH], [build x264 10bit], [no])
 436 CHECK_ENABLE([x265_hidepth], [X265_HIDEPTH], [build x265 10bit], [no])
 437
 438 test "x$WANT_STATIC_BUILD" = "xauto" && WANT_STATIC_BUILD=$WANT_CINBIN_BUILD
 439
 440 AC_DEFUN([CHECK_PROG], [
 441  AC_CHECK_PROG([PROG_$1], [$2], [yes],[no])
 442 ])
 443 AC_DEFUN([REQUIRE_PROG], [
 444  CHECK_PROG([$1],[$2])
 445  if test "x$PROG_$1" = "xno"; then
 446    AC_MSG_WARN([$2 is missing and required.])
 447    FATAL_ERROR=1
 448  fi
 449 ])
 450
 451 ## arch dep tests
 452 ARCH=[`uname -m`]
 453 I86=[`expr "x$ARCH" : 'xi[346]86.*'`]
 454 X86=[`expr "x$ARCH" : 'x..._64*'`]
 455
 456 if test "x$I86$X86" != "x00" ; then
 457   # Checks for ix86 programs.
 458   REQUIRE_PROG(NASM, [nasm])
 459   # libx264 nasm fix
 460   AC_MSG_CHECKING([nasm x264 compatible])
 461   echo "vmovdqa32 [[eax]]{k1}{z}, zmm0" > conftest.asm
 462   nasm conftest.asm -o conftest.o > /dev/null 2>&1
 463   if test $? != 0 ; then
 464    AC_MSG_RESULT([no])
 465    AC_MSG_WARN([libx264 built without assembly code])
 466    X264_CFG_PARAMS="$X264_CFG_PARAMS --disable-asm"
 467   else
 468    AC_MSG_RESULT([yes])
 469   fi
 470   rm -f conftest.asm conftest.o
 471   REQUIRE_PROG(YASM, [yasm])
 472 fi
 473
 474 ## end arch dep tests
 475
 476 REQUIRE_PROG(OBJCOPY, [objcopy])
 477 if test "x$FATAL_ERROR" != "x"; then
 478  AC_MSG_ERROR("fatal eror.")
 479 fi
 480 CHECK_PROG(PACTL, [pactl])
 481 WANT_PACTL=$PROG_PACTL
 482
 483 AC_CHECK_DECL([X_HAVE_UTF8_STRING],,[no_utf=yes],[#include <X11/Xlib.h>])
 484 if test "$no_utf" = "yes"; then
 485   AC_MSG_ERROR([Cinelerra requires utf8 support in X Windows.])
 486 fi
 487
 488 # Checks for headers/libraries.
 489
 490 AC_DEFUN([CHECK_HEADERS], [
 491 if test "x$HAVE_$1" != "xno"; then
 492  AC_CHECK_HEADER(m4_apply([m4_car],m4_split([$3])), [HAVE_$1=yes], [HAVE_$1=no],
 493   [m4_foreach([i], m4_split([$3]), [[#include "]i["
 494 ]])])
 495  AC_SUBST([HAVE_$1])
 496  AC_MSG_CHECKING([$2])
 497  AC_MSG_RESULT([$HAVE_$1])
 498  if test "x$HAVE_$1" = "xno"; then
 499   if test "x$PKG_$1" = "x"; then RESULT=no; fi
 500  fi
 501 fi
 502 ])
 503
 504 AC_DEFUN([CHECK_LIB], [
 505 if test "x$HAVE_$1" != "xno"; then
 506  if test "x$PKG_$1" = "x" -o "x$WANT_STATIC_BUILD" = "xno" -a "x$PKG_$1" = "xauto"; then
 507   AC_CHECK_LIB([$2], [$3], [HAVE_$1=yes], [HAVE_$1=no], [$4])
 508   AC_SUBST([HAVE_$1])
 509   if test "x$WANT_$1" != "xno"; then
 510    if test "x$HAVE_$1" = "xyes"; then
 511     if test "x$PKG_$1" = "x"; then
 512      SYSTEM_LIBS+=" -l[$2]"
 513      for lib in [$4]; do SYSTEM_LIBS+=" $lib"; done
 514     else
 515      SHARED_$1+=" -l[$2]"
 516      for lib in [$4]; do SHARED_LIBS+=" $lib"; done
 517     fi
 518    elif test "x$PKG_$1" = "x"; then
 519     RESULT=no
 520    fi
 521   fi
 522  fi
 523 fi
 524 ])
 525
 526 CHECK_LIB([X11], [X11], [XOpenDisplay])
 527 CHECK_HEADERS([X11], [X11 headers], [X11/X.h X11/Xlib.h X11/Xutil.h X11/cursorfont.h])
 528 CHECK_HEADERS([X11], [X11 headers], [X11/keysym.h X11/Sunkeysym.h X11/Xatom.h X11/XF86keysym.h])
 529 CHECK_LIB([XEXT], [Xext], [XShmQueryExtension])
 530 CHECK_HEADERS([XEXT], [Xlib XShm extention], [X11/Xlib.h X11/extensions/XShm.h X11/extensions/shape.h])
 531 CHECK_LIB([XINERAMA], [Xinerama], [XineramaQueryExtension])
 532 CHECK_HEADERS([XINERAMA], [Xinerama headers], [X11/extensions/Xinerama.h])
 533 CHECK_LIB([XV], [Xv], [XvQueryExtension])
 534 CHECK_HEADERS([XV], [Xlib Xv extention], [X11/Xlib.h X11/extensions/Xvlib.h])
 535 CHECK_LIB([XFIXES], [Xfixes], [XFixesQueryVersion])
 536 CHECK_LIB([BZ2], [bz2], [BZ2_bzDecompress])
 537 CHECK_LIB([FONTCONFIG], [fontconfig], [FcInit])
 538 CHECK_LIB([FREETYPE], [freetype], [FT_Init_FreeType])
 539 CHECK_LIB([LZMA], [lzma], [lzma_version_number])
 540 CHECK_LIB([PNG], [png], [png_read_png])
 541 CHECK_LIB([PTHREAD], [pthread], [pthread_create])
 542 CHECK_LIB([Z], [z], [gzopen])
 543 CHECK_LIB([fftw], [fftw3], [fftw_execute])
 544 CHECK_HEADERS([fftw], [fftw headers], [fftw3.h])
 545 CHECK_LIB([libuuid], [uuid], [uuid_clear])
 546 CHECK_HEADERS([libuuid], [uuid headers], [uuid/uuid.h])
 547 CHECK_HEADERS([LINUX_CDROM], [linux cdrom headers], [linux/cdrom.h linux/futex.h])
 548 CHECK_HEADERS([LINUX_SYS], [linux sys], [sys/ioctl.h sys/stat.h sys/types.h sys/time.h sys/syscall.h])
 549 CHECK_LIB([flac], [FLAC], [FLAC__stream_decoder_new])
 550 CHECK_HEADERS([flac], [FLAC headers], [FLAC/stream_decoder.h])
 551 CHECK_LIB([lame], [mp3lame], [lame_init])
 552 CHECK_HEADERS([lame], [lame headers], [lame/lame.h])
 553 CHECK_LIB([libjpeg], [jpeg], [jpeg_start_decompress])
 554 CHECK_HEADERS([libjpeg], [jpeg headers], [stdio.h jpeglib.h])
 555 CHECK_LIB([libogg], [ogg], [ogg_stream_init])
 556 CHECK_HEADERS([libogg], [ogg headers], [ogg/ogg.h])
 557 CHECK_LIB([openjpeg], [openjp2], [opj_version])
 558 CHECK_HEADERS([openjpeg], [openjpeg headers], [openjpeg.h])
 559 CHECK_LIB([libsndfile], [sndfile], [sf_open])
 560 CHECK_HEADERS([libsndfile], [sndfile headers], [sndfile.h])
 561 CHECK_LIB([libtheora], [theora], [theora_info_init], [-ltheoraenc -ltheoradec -logg])
 562 CHECK_HEADERS([libtheora], [threora headers], [theora/theoraenc.h])
 563 CHECK_LIB([libvorbis], [vorbisenc], [vorbis_encode_init], [-lvorbis -lvorbisfile -logg])
 564 CHECK_HEADERS([libvorbis], [vorbis encoders headers], [vorbis/vorbisenc.h])
 565 CHECK_LIB([libvorbis], [vorbisfile], [ov_open])
 566 CHECK_HEADERS([libvorbis], [vorbis file headers], [vorbis/vorbisfile.h])
 567 CHECK_LIB([libvpx], [vpx], [vpx_codec_decode])
 568 CHECK_HEADERS([libvpx], [vpx headers], [vpx/vpx_decoder.h])
 569 CHECK_LIB([mjpegtools], [mjpegutils], [mjpeg_info])
 570 CHECK_HEADERS([mjpegtools], [mjpegtools headers], [mjpegtools/mjpeg_types.h])
 571 CHECK_LIB([tiff], [tiff], [TIFFOpen])
 572 CHECK_HEADERS([tiff], [tiff headers], [tiff.h tiffio.h])
 573 CHECK_LIB([twolame], [twolame], [twolame_encode_buffer_float32_interleaved])
 574 CHECK_HEADERS([twolame], [twolame headers], [twolame.h])
 575 CHECK_LIB([x264], [x264], [x264_encoder_encode])
 576 CHECK_HEADERS([x264], [x264 headers], [stdint.h x264.h])
 577 CHECK_LIB([x265], [x265], [x265_encoder_encode])
 578 CHECK_HEADERS([x265], [x265 headers], [x265.h])
 579 CHECK_LIB([opus], [opus], [opus_multistream_decoder_create])
 580 CHECK_HEADERS([opus], [libopus headers], [opus/opus_multistream.h])
 581 CHECK_LIB([libaom], [aom], [aom_codec_version])
 582 CHECK_HEADERS([libaom], [libaom headers], [aom/aom.h])
 583 CHECK_LIB([dav1d], [dav1d], [dav1d_version])
 584 CHECK_HEADERS([dav1d], [libdav1d headers], [dav1d/dav1d.h])
 585 CHECK_LIB([libwebp], [webp], [WebPGetEncoderVersion])
 586 CHECK_HEADERS([libwebp], [libwebp headers], [webp/encode.h])
 587 CHECK_LIB([a52dec], [a52], [a52_init])
 588 CHECK_HEADERS([a52dec], [a52 headers], [a52.h])
 589 CHECK_LIB([encore], [encore], [encore])
 590 CHECK_HEADERS([encore], [encore headers], [encore.h])
 591 CHECK_LIB([giflib], [gif], [DGifOpen])
 592 CHECK_HEADERS([giflib], [gif lib headers], [gif_lib.h])
 593 CHECK_LIB([jbig], [jbig], [jbg_dec_init])
 594
 595 CHECK_LIB([VDPAU], [vdpau], [vdp_device_create_x11])
 596 if test "x$HAVE_VDPAU" != "xyes" -a "x$WANT_VDPAU" = "xyes"; then
 597   AC_MSG_ERROR([requires vdpau support.])
 598 fi
 599
 600 CHECK_LIB([VAAPI], [va], [vaInitialize])
 601 if test "x$HAVE_VAAPI" = "xyes" -a "x$WANT_VAAPI" != "xno"; then
 602   CHECK_HEADERS([vaapi_x11], [va x11 headers], [va/va_x11.h])
 603   CHECK_LIB([vaapi_x11], [va-x11], [vaGetDisplay])
 604   CHECK_HEADERS([vaapi_drm], [va drm headers], [va/va_drm.h])
 605   CHECK_LIB([vaapi_drm], [va-drm], [vaGetDisplayDRM])
 606 fi
 607 if test "x$HAVE_VAAPI" != "xyes" -a "x$WANT_VAAPI" = "xyes"; then
 608   AC_MSG_ERROR([requires vappi support.])
 609 fi
 610
 611 #CHECK_LIB([NVENC], [nvidia-encode], [NvEncodeAPICreateInstance])
 612
 613 #if test "x$HAVE_mjpegtools" = "xyes"; then
 614 #CFG_CFLAGS+=" -I/usr/include/mjpegtools -I/usr/local/include/mjpegtools"
 615 #fi
 616
 617 AC_DEFUN([CHECK_WANT], [
 618 RESULT=yes
 619 # WANT_$1
 620 if test "x$WANT_$1" != "xno" ; then
 621 AC_ARG_WITH(m4_tolower([$1]),
 622  AC_HELP_STRING([m4_join([-],[--with],m4_tolower([$1]))], [$3] (auto)),
 623   [WANT_$1=$withval],[WANT_$1=$2])
 624  m4_quote($4)
 625  if test "x$RESULT" = "xno" -a "x$PKG_$1" = "x"; then
 626   if test "x$WANT_$1" = "xyes" ; then
 627     AC_MSG_ERROR([required for $1 support.])
 628   fi
 629   WANT_$1=no
 630  elif test "x$WANT_$1" = "xauto" ; then
 631   WANT_$1=yes
 632  fi
 633 fi
 634 CFG_WANTS+=" $1"
 635 AC_SUBST([WANT_$1])
 636 ])
 637
 638 CHECK_WANT([GL], [auto], [use opengl], [
 639  CHECK_LIB([GL], [GL], [glUseProgram])
 640  CHECK_LIB([GL], [GLU], [gluOrtho2D])
 641  CHECK_HEADERS([GL], [opengl headers], [GL/gl.h GL/glext.h GL/glu.h GL/glx.h])])
 642
 643 CHECK_WANT([OSS], [auto], [use OSS audio], [
 644  CHECK_HEADERS([OSS], [oss headers], [sys/soundcard.h])])
 645
 646 CHECK_WANT([XFT], [auto], [use libXft], [
 647  CHECK_LIB([XFT], [Xft], [XftInit])
 648  CHECK_HEADERS([XFT], [Xft/freetype headers], [X11/Xlib.h X11/Xft/Xft.h])])
 649
 650 CHECK_WANT([ALSA], [auto], [use libasound/alsa], [
 651  CHECK_LIB([ALSA], [asound], [snd_pcm_open])
 652  CHECK_HEADERS([ALSA], [asound headers], [alsa/asoundlib.h])])
 653
 654 CHECK_WANT([FIREWIRE], [auto], [use firewire], [
 655  CHECK_LIB([libavc1394], [avc1394], [avc1394_init_target])
 656  CHECK_HEADERS([libavc1394], [libavc1394 headers], [libavc1394/avc1394.h])
 657  CHECK_LIB([libavc1394], [rom1394], [rom1394_get_bus_id])
 658  CHECK_HEADERS([libavc1394], [librom1394 headers], [libavc1394/rom1394.h])
 659  CHECK_LIB([libiec61883], [iec61883], [iec61883_mpeg2_recv_init])
 660  CHECK_HEADERS([libiec61883], [libiec61883 headers], [libiec61883/iec61883.h])
 661  CHECK_LIB([libraw1394], [raw1394], [raw1394_iso_recv_init])
 662  CHECK_HEADERS([libraw1394], [libraw1394 headers], [libraw1394/raw1394.h])])
 663
 664 CHECK_WANT([DV], [auto], [use dv], [
 665  CHECK_LIB([libdv], [dv], [dv_init])
 666  CHECK_HEADERS([libdv], [libdv headers], [libdv/dv.h])])
 667
 668 CHECK_WANT([DVB], [auto], [use dvb], [
 669  CHECK_HEADERS([DVB], [dvb device headers], [linux/dvb/dmx.h linux/dvb/frontend.h])])
 670
 671 CHECK_WANT([VIDEO4LINUX2], [auto], [use v4l2], [
 672  CHECK_HEADERS([VIDEO4LINUX2], [v4l2 system headers], [linux/kernel.h linux/types.h linux/videodev2.h])])
 673
 674 CHECK_WANT([XXF86VM], [auto], [use xf86vmode], [
 675  CHECK_HEADERS([XXF86VM], [XF86VM headers], [X11/Xlib.h X11/extensions/xf86vmode.h])])
 676
 677 CHECK_WANT([ESOUND], [no], [use esd], [
 678  CHECK_LIB([esound], [esd], [esd_open_sound])
 679  CHECK_HEADERS([esound], [esound headers], [esd.h])
 680  CHECK_LIB([audiofile], [audiofile], [afOpenFile])
 681  CHECK_HEADERS([audiofile], [audiofile headers], [audiofile.h])])
 682
 683 CHECK_WANT([SHUTTLE], [yes], [shuttle dev support], [
 684  CHECK_HEADERS([keysyms], [x11 keysym defs], [X11/keysymdef.h])])
 685 if test "x$WANT_SHUTTLE" = "xno"; then
 686  WANT_SHUTTLE_USB="no"
 687 fi
 688 CHECK_WANT([SHUTTLE_USB], [yes], [use libusb-1.0], [
 689  CHECK_LIB([libusbx], [usb-1.0], [libusb_init])
 690  CHECK_HEADERS([libusbx], [libusb headers], [libusb-1.0/libusb.h])])
 691
 692 CHECK_WANT([LV2], [auto], [use lv2], [
 693  saved_CFLAGS="$CFLAGS"
 694  CHECK_LIB([lilv], [lilv-0], [lilv_world_new])
 695  CHECK_LIB([sord], [sord-0], [sord_world_new])
 696  CHECK_LIB([serd], [serd-0], [serd_reader_new])
 697  CHECK_LIB([sratom], [sratom-0], [sratom_new])
 698  CFLAGS="-I/usr/include/lilv-0 -I/usr/local/include/lilv-0"
 699  CHECK_HEADERS([lv2], [lilv headers], [lilv/lilv.h])
 700  CHECK_LIB([suil], [suil-0], [suil_instance_new])
 701  CFLAGS="-I/usr/include/suil-0 -I/usr/local/include/suil-0"
 702  CHECK_HEADERS([lv2], [suil headers], [suil/suil.h])
 703  CFLAGS="$saved_CFLAGS"])
 704
 705 CHECK_WANT([CUDA], [auto], [build cuda plugins], [
 706   CHECK_HEADERS([CUDA], [cuda sdk], [${CUDA_PATH:-/usr/local/cuda}/include/cuda.h])])
 707
 708 CHECK_WANT([DL], [auto], [system has libdl], [
 709  CHECK_LIB([DL], [dl], [dlopen])])
 710
 711 CHECK_WANT([OPENCV], [no], [opencv=sys/sta/dyn,git/tar=url], [
 712 ])
 713
 714 CHECK_WANT([NUMA], [auto], [system has libnuma], [
 715  CHECK_LIB([NUMA], [numa], [numa_alloc])])
 716
 717 CHECK_WANT([OPENEXR], [auto], [use openexr], [
 718  AC_MSG_CHECKING([for openexr available])
 719  saved_LIBS="$LIBS"
 720  saved_CXXFLAGS="$CXXFLAGS"
 721  LIBS=" -lIlmImf -lIlmThread -lIex -lpthread"
 722  CXXFLAGS="-I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 723  AC_LANG_PUSH(C++)
 724  AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 725 #include "ImfChannelList.h"
 726 #include "ImfChromaticities.h"
 727 #include "ImfCompression.h"
 728 #include "ImfIO.h"
 729 #include "ImfInputFile.h"
 730 #include "ImfOutputFile.h"
 731 #include "ImfPixelType.h"
 732 #include "ImfRgbaFile.h"
 733 #include "ImfRgbaYca.h"
 734 #include "ImfVersion.h"
 735 class EXRIStream : public Imf::IStream { public:
 736 EXRIStream() : Imf::IStream("mypath") {} };
 737 class EXROStream : public Imf::OStream { public:
 738 EXROStream() : Imf::OStream("mypath") {} };
 739 ]])], [HAVE_OPENEXR=yes], [HAVE_OPENEXR=no])
 740  HAVE_openexr="$HAVE_OPENEXR"
 741  RESULT="$HAVE_OPENEXR"
 742  if test "x$RESULT" = "xyes" -a "x$WANT_STATIC_BUILD" = "xno"; then
 743    SHARED_openexr="$LIBS"
 744    CFG_CFLAGS+=" -I/usr/include/OpenEXR -I/usr/local/include/OpenEXR"
 745  fi
 746  LIBS="$saved_LIBS"
 747  CXXFLAGS="$saved_CXXFLAGS"
 748  AC_LANG_POP(C++)
 749  AC_MSG_RESULT([$HAVE_OPENEXR])
 750 ])
 751 AC_SUBST([HAVE_OPENEXR])
 752
 753 # build global_config
 754 OBJDIR=`uname -m`
 755 AC_SUBST(OBJDIR)
 756
 757 echo "AC_HELP_STRING([Reason],[Package])"
 758 echo "AC_HELP_STRING([------],[-------])"
 759
 760 AC_DEFUN([PKG_DISABLED],[
 761  PKG_$1="no"
 762  BUILD_$1=0
 763  AC_SUBST(BUILD_$1)
 764  echo "AC_HELP_STRING([disabled],[$1])"
 765 ])
 766 AC_DEFUN([PKG_SHARED],[
 767  PKG_$1="shared"
 768  BUILD_$1=0
 769  AC_SUBST(BUILD_$1)
 770  SHARED_LIBS+="$SHARED_$1"
 771 ])
 772
 773 AC_DEFUN([PKG_STATIC],[
 774  if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 775   PKG_$1="yes"
 776   BUILD_$1=1
 777   AC_SUBST(BUILD_$1)
 778   STATIC_BLDS+=" [$1]"
 779   echo "AC_HELP_STRING([$2],[$1])"
 780  fi
 781 ])
 782
 783 AC_DEFUN([PKG_FORCED],[PKG_STATIC([$1],[forced])])
 784
 785 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 786 # order matters
 787 for dep in \
 788         ffmpeg/twolame ffmpeg/lame ffmpeg/openjpeg \
 789         ffmpeg/libvorbis ffmpeg/libtheora ffmpeg/x264 ffmpeg/x265 \
 790         libiec61883/libraw1394 libavc1394/librom1394 \
 791         libtheora/libogg libtheora/libvorbis ; do
 792   lib=`dirname $dep`;  needs=`basename $dep`
 793   eval pkg_lib="\$PKG_$lib"; eval needs_lib="\$HAVE_$needs";
 794   if test "x$pkg_lib" != "xno"; then
 795     eval "PKG_$needs=yes"
 796   fi
 797 done
 798 fi
 799
 800 AC_DEFUN([PKG_PROVIDE],[
 801 if test "x$BUILD_$1" = "x" ; then
 802  if test "x$PKG_$1" = "xyes"; then
 803   PKG_FORCED([$1])
 804  elif test "x$2" = "xno" -o "x$PKG_$1" = "xno"; then
 805   PKG_DISABLED([$1])
 806  elif test "x$WANT_STATIC_BUILD" = "xyes"; then
 807   PKG_STATIC([$1],[static])
 808  elif test "x$HAVE_$1" = "xyes"; then
 809   PKG_SHARED([$1])
 810  else
 811   PKG_STATIC([$1],[needed])
 812  fi
 813 fi
 814 ])
 815
 816 PKG_PROVIDE([a52dec])
 817 PKG_PROVIDE([djbfft])
 818 PKG_PROVIDE([encore])
 819 PKG_PROVIDE([audiofile],[$WANT_ESOUND])
 820 PKG_PROVIDE([esound],[$WANT_ESOUND])
 821 PKG_PROVIDE([ffmpeg])
 822 PKG_PROVIDE([fftw])
 823 PKG_PROVIDE([flac])
 824 PKG_PROVIDE([giflib])
 825 PKG_PROVIDE([ladspa],[$WANT_LADSPA_BUILD])
 826 PKG_PROVIDE([lame])
 827 PKG_PROVIDE([libavc1394],[$WANT_FIREWIRE])
 828 PKG_PROVIDE([libraw1394],[$WANT_FIREWIRE])
 829 PKG_PROVIDE([libiec61883],[$WANT_FIREWIRE])
 830 PKG_PROVIDE([libdv],[$WANT_DV])
 831 PKG_PROVIDE([libjpeg])
 832 PKG_PROVIDE([libogg])
 833 PKG_PROVIDE([libsndfile])
 834 PKG_PROVIDE([libtheora])
 835 PKG_PROVIDE([libuuid])
 836 PKG_PROVIDE([libvorbis])
 837 PKG_PROVIDE([mjpegtools])
 838 PKG_PROVIDE([libaom])
 839 PKG_PROVIDE([dav1d])
 840 PKG_PROVIDE([libwebp])
 841 PKG_PROVIDE([openexr], [$WANT_OPENEXR])
 842 PKG_PROVIDE([openjpeg])
 843 PKG_PROVIDE([tiff])
 844 PKG_PROVIDE([twolame])
 845 PKG_PROVIDE([x264])
 846 PKG_PROVIDE([x265])
 847 PKG_PROVIDE([libvpx])
 848 PKG_PROVIDE([opus])
 849 PKG_PROVIDE([lv2], [$WANT_LV2])
 850 PKG_PROVIDE([lilv], [$WANT_LV2])
 851 PKG_PROVIDE([sratom], [$WANT_LV2])
 852 PKG_PROVIDE([serd], [$WANT_LV2])
 853 PKG_PROVIDE([sord], [$WANT_LV2])
 854 PKG_PROVIDE([suil], [$WANT_LV2])
 855 PKG_PROVIDE([ffnvcodec], [$WANT_NV])
 856
 857 if test "x$WANT_LV2" = "xyes"; then
 858   if test "x$HAVE_lv2" = "xyes" -a "x$BUILD_lilv" = "x0"; then
 859     CFG_CFLAGS+=' -I/usr/include/lilv-0 -I/usr/local/include/lilv-0'
 860     CFG_CFLAGS+=' -I/usr/include/suil-0 -I/usr/local/include/suil-0'
 861   fi
 862 fi
 863
 864 AC_SUBST(STATIC_BLDS)
 865 for f in $SHARED_LIBS; do
 866   echo "AC_HELP_STRING([shared],[$f])"
 867 done
 868 AC_SUBST(SHARED_LIBS)
 869 for f in $SYSTEM_LIBS; do
 870   echo "AC_HELP_STRING([system],[$f])"
 871 done
 872 AC_SUBST(SYSTEM_LIBS)
 873
 874 echo ""
 875 if test "x$WANT_CIN_3RDPARTY" != "xno"; then
 876   CFG_CFLAGS+=" -DHAVE_CIN_3RDPARTY"
 877 fi
 878 for v in GL XFT XXF86VM OSS ALSA FIREWIRE DV DVB \
 879          VIDEO4LINUX2 ESOUND PACTL OPENEXR LV2 \
 880          COMMERCIAL LIBZMPEG SHUTTLE SHUTTLE_USB \
 881          VAAPI VDPAU CUDA NV; do
 882   eval vv="\$WANT_$v"
 883   if test "x$vv" != "xno"; then
 884     CFG_CFLAGS+=" -DHAVE_$v"
 885     vv=with
 886   else
 887     vv=without
 888   fi
 889   v=`echo "$v" | tr "A-Z" "a-z"`
 890   echo "  using: $vv-$v"
 891 done
 892
 893 # build extras
 894 if test "x$WANT_CLANG" = "xyes" ; then
 895   FFMPEG_EXTRA_CFG+=' --cc=clang --cxx=clang++'
 896 fi
 897 if test "x$HAVE_tiff" = "xyes"; then
 898   if test "x$HAVE_jbig" = "xyes"; then
 899     EXTRA_LIBS+=' -ljbig'
 900   fi
 901 fi
 902 if test "x$HAVE_NUMA" = "xyes"; then
 903   EXTRA_LIBS+=' -lnuma'
 904 fi
 905
 906 FFMPEG_EXTRA_LDFLAGS=""
 907 if test "x$WANT_VAAPI" != "xno" -a "x$HAVE_VAAPI" = "xyes"; then
 908   FFMPEG_EXTRA_LDFLAGS+=' -lva'
 909   EXTRA_LIBS+=' -lva'
 910   WANT_VAPPI="yes"
 911   if test "x$HAVE_vaapi_x11" = "xyes"; then
 912     FFMPEG_EXTRA_LDFLAGS+=' -lva-x11'
 913     EXTRA_LIBS+=' -lva-x11'
 914   fi
 915   if test "x$HAVE_vaapi_drm" = "xyes"; then
 916     FFMPEG_EXTRA_LDFLAGS+=' -lva-drm'
 917     EXTRA_LIBS+=' -lva-drm'
 918   fi
 919 fi
 920 CFG_WANTS+=" VAAPI"
 921
 922 if test "x$WANT_VDPAU" != "xno" -a "x$HAVE_VDPAU" = "xyes"; then
 923   WANT_VDPAU="yes"
 924 fi
 925 CFG_WANTS+=" VDPAU"
 926
 927 if test "x$WANT_NV" != "xno"; then
 928   WANT_NV="yes"
 929   CFG_WANTS+=" NV"
 930 fi
 931
 932 if test "x$HAVE_DL" = "xyes"; then
 933   EXTRA_LIBS+=' -ldl'
 934   FFMPEG_EXTRA_LDFLAGS+=' -ldl'
 935 fi
 936 if test "x$FFMPEG_EXTRA_LDFLAGS" != "x"; then
 937   FFMPEG_EXTRA_CFG+=' --extra-ldflags="'$FFMPEG_EXTRA_LDFLAGS'"'
 938 fi
 939
 940 if test "x$WANT_BOOBY" != "xno"; then
 941   CFG_CFLAGS+=" -DBOOBY"
 942 fi
 943
 944 # intel lock elision bugs
 945 if test "x$WANT_NOELISION" != "xno"; then
 946   CFG_RPATH=`ls -1fd 2> /dev/null \
 947  /usr/lib/noelision \
 948  /lib/noelision \
 949  /usr/lib64/noelision \
 950  /lib64/noelision \
 951   | tail -1`
 952 fi
 953
 954 echo "  using: with-jobs = $WANT_JOBS"
 955 echo "  using: exec-name = $WANT_CIN"
 956 echo "  using: with-cinlib = $WANT_CINLIB_DIR"
 957 echo "  using: with-cindat = $WANT_CINDAT_DIR"
 958 echo "  using: with-config-dir = $WANT_CONFIG_DIR"
 959 echo "  using: with-browser = $WANT_CIN_BROWSER"
 960 echo "  using: with-plugin-dir = $WANT_PLUGIN_DIR"
 961 echo "  using: with-ladspa-dir = $WANT_LADSPA_DIR"
 962 echo "  using: with-opencv = $WANT_OPENCV"
 963 echo "  using: with-git-ffmpeg = $WANT_GIT_FFMPEG"
 964 echo "  using: with-noelision = $WANT_NOELISION"
 965 echo "  using: with-booby = $WANT_BOOBY"
 966 echo "  using: with-clang = $WANT_CLANG"
 967 echo ""
 968 echo "  using: thirdparty build = $WANT_CIN_3RDPARTY"
 969 echo "  using: single-user  = $WANT_CINBIN_BUILD"
 970 echo "  using: static-build = $WANT_STATIC_BUILD"
 971 echo "  using: ladspa-build = $WANT_LADSPA_BUILD"
 972 echo ""
 973
 974 AC_SUBST(WANT_CIN_3RDPARTY)
 975 AC_SUBST(EXTRA_LIBS)
 976 AC_SUBST(FFMPEG_EXTRA_CFG)
 977 AC_SUBST(WANT_X264_HIDEPTH)
 978 AC_SUBST(WANT_X265_HIDEPTH)
 979
 980 AC_SUBST(CFG_CFLAGS)
 981 AC_SUBST(CFG_CXXFLAGS)
 982
 983 AC_CONFIG_FILES([Makefile])
 984 AC_OUTPUT
 985
 986 exec > global_config
 987
 988 echo "SHELL := /bin/bash"
 989 echo "export SHELL"
 990 echo "WANT_JOBS := $WANT_JOBS"
 991 if test "x$WANT_CLANG" = "xyes" ; then
 992   echo "CC = clang"
 993   echo "CXX = clang++"
 994   echo "export CC CXX"
 995 fi
 996 echo ""
 997 echo "OBJDIR := $OBJDIR"
 998 echo "BINDIR := \$(TOPDIR)/bin"
 999 echo "CINELERRA := \$(TOPDIR)/cinelerra"
1000 echo "GUICAST := \$(TOPDIR)/guicast"
1001 echo "LIBZMPEG3 := \$(TOPDIR)/libzmpeg3"
1002 echo "MPEG2ENC := \$(TOPDIR)/mpeg2enc"
1003 echo "MPLEXLO := \$(TOPDIR)/mplexlo"
1004 echo "PLUGINS := \$(TOPDIR)/plugins"
1005 echo "TDB := \$(TOPDIR)/db"
1006 echo "THIRDPARTY := \$(TOPDIR)/thirdparty"
1007 echo "EXTRA_LIBS := $EXTRA_LIBS"
1008 echo "FFMPEG_EXTRA_CFG := $FFMPEG_EXTRA_CFG"
1009 echo "export OBJDIR BINDIR CINELERRA GUICAST LIBZMPEG3"
1010 echo "export MPEG2ENC MPLEXLO PLUGINS TDB"
1011 echo "export THIRDPARTY EXTRA_LIBS FFMPEG_EXTRA_CFG"
1012 echo ""
1013
1014 echo "WANT_CIN := $WANT_CIN"
1015 CFG_WANTS+=" CIN_3RDPARTY LIBZMPEG COMMERCIAL STATIC_BUILD"
1016 for w in $CFG_WANTS; do ww=WANT_$w; echo "WANT_$w := ${!ww}"; done
1017 echo ""
1018
1019 echo "ifndef CFLAGS_"
1020 echo "ifdef CFLAGS"
1021 echo "CFLAGS_ := \$(CFLAGS)"
1022 echo "else"
1023 echo "CFLAGS_ := ${CFLAGS:--g -O2}"
1024 echo "endif"
1025 echo "endif"
1026 echo "ifndef CXXFLAGS_"
1027 echo "ifdef CXXFLAGS"
1028 echo "CXXFLAGS_ := \$(CXXFLAGS)"
1029 echo "endif"
1030 echo "endif"
1031 echo "ifndef LDFLAGS_"
1032 echo "ifdef LDFLAGS"
1033 echo "LDFLAGS_ := \$(LDFLAGS)"
1034 echo "endif"
1035 echo "endif"
1036
1037 echo "CFLAGS := \$(CFLAGS_)"
1038 echo "CFLAGS += '-DCIN=\"\$(WANT_CIN)\"'"
1039 echo "CFLAGS += '-DCINLIB_DIR=\"$WANT_CINLIB_DIR\"'"
1040 echo "CFLAGS += '-DCINDAT_DIR=\"$WANT_CINDAT_DIR\"'"
1041 echo "CFLAGS += '-DCONFIG_DIR=\"$WANT_CONFIG_DIR\"'"
1042 echo "CFLAGS += '-DPLUGIN_DIR=\"$WANT_PLUGIN_DIR\"'"
1043 echo "CFLAGS += '-DLOCALE_DIR=\"$WANT_LOCALE_DIR\"'"
1044 echo "CFLAGS += '-DLADSPA_DIR=\"$WANT_LADSPA_DIR\"'"
1045 echo "CFLAGS += '-DCIN_BROWSER=\"$WANT_CIN_BROWSER\"'"
1046 for flg in $CFG_CFLAGS; do echo "CFLAGS += $flg"; done
1047 echo ""
1048 if test "x$CFG_CXXFLAGS" != "x"; then
1049   for flg in $CFG_CXXFLAGS; do echo "CXXFLAGS += $flg"; done
1050   echo ""
1051 fi
1052 if test "x$CFG_LDFLAGS" != "x" ; then
1053   echo "LDFLAGS +=$CFG_LDFLAGS"
1054   echo ""
1055 fi
1056
1057 if test "x$WANT_X264_HIDEPTH" = "xyes" ; then
1058   X264_CFG_PARAMS="$X264_CFG_PARAMS --bit-depth=10"
1059 fi
1060 if test "x$WANT_X265_HIDEPTH" = "xyes" ; then
1061   X265_CFG_PARAMS="$X265_CFG_PARAMS -DHIGH_BIT_DEPTH:BOOL=ON" # -DMAIN12:BOOL=ON"
1062 fi
1063
1064 for pkg in $STATIC_PKGS; do
1065   eval pkg_lib="\$PKG_$pkg"
1066   if test "x$pkg_lib" = "xyes"; then
1067     echo "static_pkgs += $pkg"
1068   elif test "x$pkg_lib" = "xshared"; then
1069     echo "shared_pkgs += $pkg"
1070   fi
1071 done
1072 echo ""
1073
1074 for pkg in $STATIC_BLDS; do
1075   echo "static_blds += $pkg"
1076   ver_pkg=ver_$pkg
1077   echo "$ver_pkg := \$(THIRDPARTY)/${!ver_pkg}"
1078   inc_pkg=inc_$pkg
1079   echo "$inc_pkg := \\"
1080   for inc in ${!inc_pkg}; do
1081     echo "  -I\$($ver_pkg)/$inc \\"
1082   done
1083   echo ""
1084   echo "static_incs += \$(inc_$pkg)"
1085   lib_pkg=lib_$pkg
1086   echo "$lib_pkg := \\"
1087   for lib in ${!lib_pkg}; do
1088     echo "  \$($ver_pkg)/$lib \\"
1089   done
1090   echo ""
1091   echo "static_libs += \$($lib_pkg)"
1092   echo ""
1093 done
1094 echo ""
1095
1096 for lib in $SHARED_LIBS; do echo "shared_libs += $lib"; done
1097 echo ""
1098 for lib in $SYSTEM_LIBS; do echo "system_libs += $lib"; done
1099 echo "export static_pkgs shared_pkgs static_blds shared_libs system_libs"
1100 echo ""
1101
1102 echo "thirdparty_libraries := \$(static_libs) \$(shared_libs)"
1103
1104 if test "x$CFG_RPATH" != "x"; then
1105   echo "libraries+= -Wl,-rpath=$CFG_RPATH"
1106 fi
1107
1108 echo "libraries += -Wl,--start-group"
1109 echo "libraries += \$(thirdparty_libraries)"
1110 echo "libraries += \$(shared_libs)"
1111 echo "libraries += \$(system_libs)"
1112 echo "libraries += \$(EXTRA_LIBS)"
1113 echo "libraries += -Wl,--end-group"
1114 # -Wl,--start-group ... -Wl,--end-group does not work on ubuntu
1115 echo "libraries += \$(thirdparty_libraries)"
1116 echo "libraries += \$(shared_libs)"
1117 echo "libraries += \$(system_libs)"
1118 echo "libraries += \$(EXTRA_LIBS)"
1119 echo ""
1120 echo "export thirdparty_libraries libraries"
1121 echo "export CFLAGS_ CXXFLAGS_ LDFLAGS_"
1122 echo "unexport CFLAGS CXXFLAGS LDFLAGS"
1123
1124 if test "x$HAVE_tiff" = "xyes"; then
1125   if test "x$HAVE_jbig" != "xyes"; then
1126     echo "tiff.cfg_params+= --disable-jbig"
1127   fi
1128 fi
1129
1130 if test "x$WANT_GIT_FFMPEG" != "xno"; then
1131   echo "ffmpeg.git := $WANT_GIT_FFMPEG"
1132 fi
1133 if test "x$X264_CFG_PARAMS" != "x" ; then
1134   echo "x264.cfg_params :=$X264_CFG_PARAMS --enable-static --enable-pic"
1135 fi
1136 if test "x$X265_CFG_PARAMS" != "x" ; then
1137   echo "x265.cfg_params :=$X265_CFG_PARAMS -DENABLE_SHARED=no"
1138 fi